• You've discovered RedGuides 📕 an EverQuest multi-boxing community 🛡️🧙🗡️. We want you to play several EQ characters at once, come join us and say hello! 👋
  • IS THIS SITE UGLY? Change the look. To dismiss this notice, click the X --->

Question - Single item from a stack (1 Viewer)

Sevenmoons

Member
Joined
Aug 19, 2020
RedCents
181¢
I wonder if anyone can help, and I apologies if this has already been answered, but I could not find anything.
i am trying to write a macro to make Dark Green Dye
I have the first inventory slot empty
I can find the Medium Jar container in my inventory and then drop it into the first slot
But when I try to select the Evergreen extract, it picks up the whole stack, rather than a single.
An example of what i have is below:

/itemnotify ${FindItem[=Medium Clay Jar].InvSlot} leftmouseup
/pause 10, /autoinventory
/itemnotify ${FindItem[=Evergreen Extract].InvSlot} leftmouseup
/pause 10, /autoinventory

What syntax should I be using to select a single item from the stack?

thanks

Sevenmoons
 
I wonder if anyone can help, and I apologies if this has already been answered, but I could not find anything.
i am trying to write a macro to make Dark Green Dye
I have the first inventory slot empty
I can find the Medium Jar container in my inventory and then drop it into the first slot
But when I try to select the Evergreen extract, it picks up the whole stack, rather than a single.
An example of what i have is below:

/itemnotify ${FindItem[=Medium Clay Jar].InvSlot} leftmouseup
/pause 10, /autoinventory
/itemnotify ${FindItem[=Evergreen Extract].InvSlot} leftmouseup
/pause 10, /autoinventory

What syntax should I be using to select a single item from the stack?

thanks

Sevenmoons
you can use /nomodkey /ctrlkey /itemnotify ${FindItem[=Medium Clay Jar].InvSlot} leftmouseup
 
Thanks SIC, that worked a treat
Managed to scrape together a basic macro now that save me a whole lot of clicking!
Just ned to expand it a little now to include the manufacture of the Clay Jars as they become no-stack once fired and eat inventory space
 
Here is my Macro if anyone is interested.it does require the bags t be open to work and the first bag slot to be free:
The delay lines might be a bit much, but my machine was lagging, and that help make sure

Sub Main

:Loop
/if (${FindItemCount[=Medium Clay Jar]}<1) /goto :Jars
/if (${FindItemCount[=Evergreen Extract]}<1) /goto :Extract
/if (${FindItemCount[=Resin]}<1) /goto :Resin

|Close any open trade containers
/if (${Window[TradeskillWnd].Open}) /notify TradeskillWnd CloseButton Leftmouseup
/delay 10
|Find the Clay Jar and put it in bag slot 1
/nomodkey /ctrlkey /itemnotify ${FindItem[=Medium Clay Jar].InvSlot} leftmouseup
/delay 10
/Autoinventory
/delay 10
|Open the jar
/itemnotify Pack1 rightmouseup
/delay 10
|Put in the Dye and resin
/nomodkey /ctrlkey /itemnotify ${FindItem[=Evergreen Extract].InvSlot} leftmouseup
/delay 5
/if (${Cursor.ID}) /itemnotify in Pack1 1 leftmouseup
/delay 5
/nomodkey /ctrlkey /itemnotify ${FindItem[=Resin].InvSlot} leftmouseup
/delay 5
/if (${Cursor.ID}) /itemnotify in Pack1 2 leftmouseup
/delay 5
|Combine and autoinventory
/notify ContainerCombine_Items Container_Combine leftmouseup
/delay 10
/if (${Cursor.ID}) /autoinv
/goto :Loop

:Jars
/Echo You are out of Medium Clay Jars
/Goto :Finish

:Extract
/Echo You are out of Evergreen Extract
/Goto :Finish

:Resin
/Echo You are out of Resin
/Goto :Finish

:Finish
/return
 
Has something changed recently with this? I get the message that "SLOT IS NULL: Could not send notification to 411 leftmouseup"

I have tried having bags open, closed, jar in the first slot, jar in any slot, jar open, jar closed, etc.

When I run /nomodkey /ctrlkey /itemnotify ${FindItem[=Medium Clay Jar].InvSlot} leftmouseup by itself it picks up the next bag if I have a jar in the first slot and does nothing except tell me the invalid item slot message if I have nothing in the first bag slot.
 
Has something changed recently with this? I get the message that "SLOT IS NULL: Could not send notification to 411 leftmouseup"

I have tried having bags open, closed, jar in the first slot, jar in any slot, jar open, jar closed, etc.

When I run /nomodkey /ctrlkey /itemnotify ${FindItem[=Medium Clay Jar].InvSlot} leftmouseup by itself it picks up the next bag if I have a jar in the first slot and does nothing except tell me the invalid item slot message if I have nothing in the first bag slot.
yes, there is an itemnotify issue that @brainiac is looking into never mind I was wrong. - brain isn't doing anything. @eqmule is looking into it.- which is likely the issue with the NULL in slots.
 
While we are waiting for eqmule to figure out the itemnotify issue is there a work around at all for this? I am staring at 500+ of these medium jar combines and really not wanting to do it manually.
 
i don't suppose anyone has found a fix to this?
well itemnotify was fixed - but any old macro that uses invslot will need to be updated to use itemslot as invslot is still not working correctly. and since you're just trying to pick up an item you can just call it directly like this:

/nomodkey /ctrlkey /itemnotify "Medium Clay Jar" leftmouseup
 
Here is my completed script, works great as long as Slot 1 is the empty slot, I have no idea how to force it to drop the items into the bag no matter what slot its in ;)

Sub Main

:Loop
/if (${FindItemCount[=Medium Clay Jar]}<1) /goto :Jars
/if (${FindItemCount[=Evergreen Extract]}<1) /goto :Extract
/if (${FindItemCount[=Resin]}<1) /goto :Resin

|Close any open trade containers
/if (${Window[TradeskillWnd].Open}) /notify TradeskillWnd CloseButton Leftmouseup
/delay 10
|Find the Clay Jar and put it in bag slot 1
/nomodkey /ctrlkey /itemnotify "Medium Clay Jar" leftmouseup
/delay 10
/Autoinventory
/delay 10
|Open the jar
/itemnotify Pack1 rightmouseup
/delay 10
|Put in the Dye and resin
/nomodkey /ctrlkey /itemnotify "evergreen extract" leftmouseup
/delay 5
/if (${Cursor.ID}) /itemnotify in Pack1 1 leftmouseup
/delay 5
/nomodkey /ctrlkey /itemnotify "Resin" leftmouseup
/delay 5
/if (${Cursor.ID}) /itemnotify in Pack1 2 leftmouseup
/delay 5
|Combine and autoinventory
/notify ContainerCombine_Items Container_Combine leftmouseup
/delay 10
/if (${Cursor.ID}) /autoinv
/goto :Loop

:Jars
/Echo You are out of Medium Clay Jars
/Goto :Finish

:Extract
/Echo You are out of Evergreen Extract
/Goto :Finish

:Resin
/Echo You are out of Resin
/Goto :Finish

:Finish
/return
 
I always work out of my 10th bag slot, which tends to be my smallest bag.

I modified this to make Blue Dye, which uses 2 resins. Will make Red by changing the name from Permafrost to Sarcoscypha, other other dyes if you comment out one of the Resin lines (for example, dark blue is 1 permafrost extract + 1 resin, not 2)

Jars.mac:
Sub Main

:Loop
/if (${FindItemCount[=Medium Clay Jar]}<1) /goto :Jars
/if (${FindItemCount[=Permafrost Extract]}<1) /goto :Extract
/if (${FindItemCount[=Resin]}<1) /goto :Resin

|Close any open trade containers
/if (${Window[TradeskillWnd].Open}) /notify TradeskillWnd CloseButton Leftmouseup
/delay 11


|Find the Clay Jar and put it in bag slot 10
/nomodkey /ctrlkey /itemnotify "Medium Clay Jar" leftmouseup
/delay 10
/Autoinventory
/delay 10
|Open the jar
/itemnotify Pack10 rightmouseup
/delay 10


|Put in the Dye and resin
/nomodkey /ctrlkey /itemnotify "Permafrost Extract" leftmouseup
/delay 5
/if (${Cursor.ID}) /itemnotify in Pack10 1 leftmouseup
/delay 5

/nomodkey /ctrlkey /itemnotify "Resin" leftmouseup
/delay 5
/if (${Cursor.ID}) /itemnotify in Pack10 2 leftmouseup
/delay 5
/nomodkey /ctrlkey /itemnotify "Resin" leftmouseup
/delay 5
/if (${Cursor.ID}) /itemnotify in Pack10 3 leftmouseup
/delay 5


|Combine and autoinventory
/notify ContainerCombine_Items Container_Combine leftmouseup
/delay 10
/if (${Cursor.ID}) /autoinv
/goto :Loop



:Jars
/Echo You are out of Medium Clay Jars
/Goto :Finish

:Extract
/Echo You are out of Extract
/Goto :Finish

:Resin
/Echo You are out of Resin
/Goto :Finish

:Finish
/return

1634067913156.png
Seems to work pretty well. Thanks to the folks who contributed to this. ;)
 
Thank you for the script, it works great. Made a slight modification to it to use Bag Slot 2. DId this to keep my food and drink in the first bag slot so as to not accidently eat or drink something that was not intended to be.
 
Question - Single item from a stack

Users who are viewing this thread

Back
Top