Raz's AFNuke2 for 105 Fire Wizies

Razkle · Mar 29, 2016

The movement has NOTHING to do with afnuke, its mq2cast that is causing it and I did not write that...

EQStreamz · Mar 29, 2016

LOL All I did was quote your post about half way down the first page lol...

eqgeek · Mar 30, 2016

3ricwhite said:
Thanks! Supernoob here, can I complete those commands within EQ client or do I have to edit the general.inc file? If the latter I'm unsure where to place the modified code.

Edit the servername_yourtoon.ini file and find those lines.

Razkle · Mar 30, 2016

HELLO REDGUIDES! Guess what time it is!

AFNUKE2 ver 1.1 Time!

Yup fixed some spell casting issues and made it even faster! Enjoy!

Download link on 1st page is accurate for afnuke2 1.1
At this point just afnuke2 and not the 85 or 100 versions are updated, those are next....

- - - Updated - - -

And if you use afnuke2 you should really donate, I mean really....

tampa03cobra · Apr 12, 2016

Nevermind, great macro, don't use tank mercs. I got lazy didn't want to load my real tank so I used a merc.. Macro didnt work. Brought my normal tank back, works perfectly.

The moral of the story is, don't be lazy, use a real tank!

Sum1 · Apr 13, 2016

This makes me want to roll a Wizard ASAP. In fact, it needs to happen this weekend (SK, Cleric, Bard, Ranger, Zerker ... adding a wizzy to that setup makes me happy in the pants).

tampa03cobra · Apr 13, 2016

Sum1 said:
This makes me want to roll a Wizard ASAP. In fact, it needs to happen this weekend (SK, Cleric, Bard, Ranger, Zerker ... adding a wizzy to that setup makes me happy in the pants).

I do SK, Bard, Wiz, Zerker, and am leveling a chanter/cleric now. This macro is amazing!

Sum1 · Apr 14, 2016

tampa03cobra said:
I do SK, Bard, Wiz, Zerker, and am leveling a chanter/cleric now. This macro is amazing!

Nice! I'm planning on PL'ing a few toons this weekend with the wizzy. I'm going to add a Shaman and Chanter to my PL group this weekend to be buff bots (for now). The wizzy will replace my cleric merc (hopefully). I need to modify my MQ2Bot healer settings to prioritize heals better, but those tweaks shouldn't be too difficult.

jimbob · Apr 14, 2016

Wizards are awesome. I need to convince Raz to make me a few...

dorimor · Apr 15, 2016

hiya guys i'm getting a cant open macro file error on afnukegem.mac but its in the correct file path ?!?!

FML instructions spell it as AFNuke2Gem.mac no need for capitals or .mac

whiteviper · May 3, 2016

Does this use the new Dicromatic Spell? Or however you spell that?

Razkle · May 4, 2016

dorimor said:
hiya guys i'm getting a cant open macro file error on afnukegem.mac but its in the correct file path ?!?!

FML instructions spell it as AFNuke2Gem.mac no need for capitals or .mac

nope. just

Rich (BB code):

 /mac afnuke2gem

Dretski · May 4, 2016

Having a huge problem with this atm. If you have your wizard following your main assist and the MA dies, the wizard starts death rushing straight forward. Not so funny in CoDecay.

psimoon · May 4, 2016

That is why I have my wizzies follow the enchanter. That way the warrior can tank and pull. yeah yeah I know, should have a different puller than the tank, but it works for me. =)

Razkle · May 4, 2016

I always follow the cleric but the mezzer would work too

Pugs · May 5, 2016

spell_routines.inc Was driving me bats with all the movement so I updated it to replace it and use /interrupt from MQ2Cast.

The new spell_routines.inc

Rich (BB code):

| spell_routines.inc v2.42
| Originally Written by Rusty~
| Upkeep performed by A_Druid_00
| Movement Replaced by use of /interrupt By Pugs
| Requres MQ2Cast to be loaded
| Includes MQ2Exchange integration for item swapping by BrainDeath
| Also includes FD fix that would cause an endless loop if you were hit by FD mid-cast by A_Druid_00
| 
| Features:
| - Casts spells, clicks items, or uses AA abilities for you
| - Allows back to back casting without waiting on spell gems to pop all the way up
| - Will interrupt spell if target dies while casting. If on a mount, it will dismount and duck if the time left
|   is greater than 7 seconds, else it will move forward a bit to interrupt, then move you back
|
|    ** IMPORTANT: if you don't want to interrupt a spell while mounted, put this at the top of your macro: **
|    **   /declare noInterrupt int outer 1                                                                  **
|
| - Allows you to use items in bags. Equips item, clicks it, then returns it to its previous location
| - Lets you set how long you want to keep trying to cast the spell (defaults to 0)
|   If the spell is interrupted before the given time, it will recast, else it will return CAST_INTERRUPTED
| - Lets you call a custom subroutine while waiting for spell to finish casting
|   Try to keep custom subroutines very small. A common use would be to interrupt the spell if a certain condition is true
| - This file also includes a sub named Interrupt. You can call this to interrupt any spell you're casting instantly.
| - You can also use the SwapItem sub included in this to swap items to certain slots
| - Added EquipItem sub to easily equip items in your main Inventory slots.
|
| - Note: if you don't want this to cast spells while you're invis, in your main macro have this at the top:
|      /declare noInvis int outer 1
|   This will make it return CAST_INVIS if you're invis
| 
|  Below is a list of outer scope variables you can access in your macros:
|      refreshTime        - How much time is left till you're done recovering from casting
|      castEndTime        - How much time left till you're done casting the current spell... usable in custom spell Subs
|      spellNotHold       - 1 if your last spell didn't take hold, 0 otherwise
|      spellRecastTime1-9 - How much time left till that spell is back up
| 
|======================================================================================================================
|  EquipItem:  An easier way to equip items you have in bags ( useful for weapons or focus items )
|              slot name is optional. If not given, it will equip it in the first possible spot
| 
|    Usage:
|        /call EquipItem "item name|slotname"
| 
|        Returns: "old item name|slotname"
|    Examples:
|    
|    To Equip Sharp Ended Broken Lever when you have Serpent of Vindication equiped:
|        /call EquipItem "Sharp Ended Broken Lever"
|    It will return "Staff of Vindication|mainhand"
|    To reequip the original item, you can save the return in a variable, and then use it later like this:
|       /varset oldPrimary ${Macro.Return}
|       | ... do stuff here with your new item equiped
|       /call EquipItem ${oldPrimary}
| 
|======================================================================================================================
|  SwapItem:  a subroutine which is used in the Cast sub itself. You don't need to do this to cast an item in a bag
|             but you can call it in your macro to SwapItems (such as weapons or focus items)
|    Usage:
|        /call SwapItem "item name" slotname|slotID 
|    Examples:
|    
|    To swap Darkblade of the Warlord to your main hand:
|        /call SwapItem "Darkblade of the Warlord" mainhand
| 
|    To swap stat food in one bag with other food in another bag:
|        /call SwapItem "Bristlebanes Party Platter" ${FindItem[halas 10lb meat pie].InvSlot}
| 
|======================================================================================================================
|  Cast: the main subroutine that casts spells or items for you
|     Usage:
|        /call Cast "spellname|itemname|AAname|AA#" [item|alt|gem#] [give up time][s|m] [custom subroutine name] [Number of resist recasts]
|     Examples:
| 
|     To cast Howl of Tashan and mem it in slot 3 if not memmed:
|       /call Cast "Howl of Tashan" gem3
| 
|     To cast Arcane Rune and keep trying for 7 seconds, in case of interrupts.
|       /call Cast "Arcane Rune" gem5 7s
| 
|     To click Grim Aura earring that's in a bag:
|       /call Cast "Shrunken Goblin Skull Earring" item
| 
|     To use AA ability Eldritch Rune:
|       /call Cast "Eldritch Rune" alt
|         or
|       /call Cast "173" alt
| 
|     To call a subroutine that interrupts CH if target gets healed before it lands:
|       /call Cast "Complete Healing" gem1 0 CheckHP
|     Then in your macro have somewhere:
|       Sub CheckHP
|          /if ( ${Target.PctHPs}>=80 ) /call Interrupt
|       /return
| 
| Returns these values:
|----------------------+----------------------------------------------------------------------+
| CAST_CANCELLED       | Spell was cancelled by ducking (either manually or because mob died) |
| CAST_CANNOTSEE       | You can't see your target                                            |
| CAST_IMMUNE          | Target is immune to this spell                                       |
| CAST_INTERRUPTED     | Casting was interrupted and exceeded the given time limit            |
| CAST_INVIS           | You were invis, and noInvis is set to true                           |
| CAST_NOTARGET        | You don't have a target selected for this spell                      |
| CAST_NOTMEMMED       | Spell is not memmed and you gem to mem was not specified             |
| CAST_NOTREADY        | AA ability or spell is not ready yet                                 |
| CAST_OUTOFMANA       | You don't have enough mana for this spell!                           |
| CAST_OUTOFRANGE      | Target is out of range                                               |
| CAST_RESISTED        | Your spell was resisted!                                             |
| CAST_SUCCESS         | Your spell was cast successfully! (yay)                              |
| CAST_UNKNOWNSPELL    | Spell/Item/Ability was not found                                     |
| CAST_NOTHOLD         | Spell woundn't take hold on target                                   | 
|----------------------+----------------------------------------------------------------------+
#Event BeginCast "You begin casting#*#" 
#Event Collapse "Your gate is too unstable, and collapses.#*#" 
#Event FDFail "#1# has fallen to the ground.#*#" 
#Event Fizzle "Your spell fizzles#*#" 
#Event Immune "Your target is immune to changes in its attack speed#*#" 
#Event Immune "Your target is immune to changes in its run speed#*#" 
#Event Immune "Your target cannot be mesmerized#*#" 
#Event Interrupt "Your casting has been interrupted#*#" 
#Event Interrupt "Your spell is interrupted#*#" 
#Event NoHold "Your spell did not take hold#*#" 
#Event NoHold "Your spell would not have taken hold#*#" 
#Event NoHold "You must first target a group member#*#" 
#Event NoHold "Your spell is too powerful for your intended target#*#" 
#Event NoLOS "You cannot see your target.#*#" 
#Event NoMount "#*#You can not summon a mount here.#*#" 
#Event NoTarget "You must first select a target for this spell!#*#" 
#Event NotReady "Spell recast time not yet met.#*#" 
#Event OutOfMana "Insufficient Mana to cast this spell!#*#" 
#Event OutOfRange "Your target is out of range, get closer!#*#" 
#Event Recover "You haven't recovered yet...#*#" 
#Event Recover "Spell recovery time not yet met#*#" 
#Event Resisted "Your target resisted the #1# spell#*#" 
#Event Resisted2 "You resist the #1# spell#*#" 
#Event Standing "You must be standing to cast a spell#*#" 
#Event Stunned "You are stunned#*#" 
#Event Stunned "You can't cast spells while stunned!#*#" 
#Event Stunned "You *CANNOT* cast spells, you have been silenced!#*#"

Sub Cast(spellName,spellType,giveUpValue,mySub,int ResistTotal)
/declare castTime float local
/if (!${Defined[castReturn]}) /declare castReturn string outer CAST_CANCELLED
/call DoCastingEvents
/varset castReturn X
/if (${Me.Invis} && ${noInvis}) /return
/if (${spellType.Equal[item]}) {
  /if (!${FindItem[${spellName}].ID}) /return CAST_UNKNOWNSPELL
  /varset castTime ${FindItem[${spellName}].CastTime}
} else /if (${spellType.Equal[alt]}) {
  /if (!${Me.AltAbilityReady[${spellName}]}) /return CAST_NOTREADY
  /varset castTime ${Me.AltAbility[${spellName}].Spell.CastTime}
} else {
  /if (!${Me.Book[${spellName}]}) /return CAST_UNKNOWNSPELL
  /declare spellID int local ${Me.Book[${Me.Book[${spellName}]}].ID}
  /varset castTime ${Spell[${spellName}].CastTime}
  /if (${Me.CurrentMana}<${Spell[${spellID}].Mana}) /return CAST_OUTOFMANA
}
/if (${castTime}>0.1) {
  /if (${Stick.Status.Equal[ON]}) /stick pause
  /if (${FollowFlag}) /call PauseFunction
  /if (${Me.Moving}) /Interrupt
}
/if (!${Defined[spellType]}) /declare spellType string local spell
/if (!${Defined[spellRecastTime1]}) {
  /if (!${Defined[noInterrupt]}) /declare noInterrupt int outer 0
  /declare ResistCounter int outer
  /declare moveBack bool outer false
  /declare selfResist int outer
  /declare selfResistSpell string outer
  /declare giveUpTimer timer outer
  /declare castEndTime timer outer
  /declare refreshTime timer outer
  /declare itemRefreshTime float outer
  /declare i int local
  /declare spellNotHold int outer
  /delay 5
  |---- Spell Gem Slots
  /for i 1 to 12
  /declare spellRecastTime${i} timer outer
  /if (${Me.SpellReady[${i}]}) {
    /varset spellRecastTime${i} 0
  } else {
    /varcalc spellRecastTime${i} 10*${Me.Gem[${i}].RecastTime}
  }
  /next i
  |---- Spell Gem Slots
}
/if (${Defined[giveUpValue]}) /varset giveUpTimer ${giveUpValue}
/if (${Defined[ResistTotal]}) /varset ResistCounter ${ResistTotal}
/varset spellNotHold 0
/varset selfResist 0
:wait_for_stop
/if (${Me.Casting.ID} || ((!${Me.Class.ShortName.Equal[BRD]} && ${Me.Moving}) && ${castTime}>0.1)) {
  /if (${Bool[${mySub}]}) /call ${mySub} ${spellID}
  /goto :wait_for_stop
}
/if (${Window[SpellBookWnd].Open}) /keypress spellbook
/if (${Me.Ducking}) /keypress duck
/if (${spellType.Equal[item]}) /call ItemCast "${spellName}" "${mySub}"
/if (${spellType.Equal[alt]}) /call AltCast "${spellName}" "${mySub}"
/if (${spellType.NotEqual[item]} && ${spellType.NotEqual[alt]}) /call SpellCast "${spellType}" "${spellName}" "${mySub}" "${spellID}" "${giveUpValue}"
/if (${Stick.Status.Equal[PAUSED]}) /squelch /stick unpause
/if (${PauseFlag}) /call PauseFunction
/varset giveUpTimer 0
/varset ResistCounter 0
/return ${castReturn}

Sub SpellCast(spellType,spellName,mySub,int spellID,giveUpValue)
:cast_spell
/if (!${Me.Gem[${spellName}]}) {
  /if (${Cursor.ID}) /call ClearCursor
  /if (${spellType.Left[3].Equal[gem]}) {
    /if (${spellType.Length}==4) /memspell ${spellType.Right[1]} "${spellName}"
    /if (${spellType.Length}==5) /memspell ${spellType.Right[2]} "${spellName}"
  } else {
    /return CAST_NOTMEMMED
  }
  /if (${Bool[${mySub}]}) /call ${mySub} ${spellID}
  /delay 6s ${Me.Gem[${spellName}]}
  /if (${Me.Gem[${spellName}]}) /varcalc spellRecastTime${Me.Gem[${spellName}]} 10*${Spell[${spellID}].RecastTime}
  /if (!${Me.Gem[${spellName}]}) /return CAST_INTERRUPTED
  :wait_for_mem
  /if (${Bool[${mySub}]}) /call ${mySub} ${spellID}
  /delay 21s ${Me.SpellReady[${spellName}]}
  /if (!${Me.SpellReady[${spellName}]}) {
    /if (${giveUpTimer}) /goto :wait_for_mem
    /return CAST_NOTREADY
  }
}
/varset spellType spell
/if (${spellName.Find[illusion: ]} && ${Me.AltAbilityReady[project illusion]}) /call Cast "project illusion" alt
/varset giveUpTimer ${giveUpValue}
/declare recoverWaitTime timer local 30
:cast_spell_loop
/if (!${Me.SpellReady[${spellName}]} && (${spellRecastTime${Me.Gem[${spellName}]}}<${giveUpTimer} || ${refreshTime}>0 || ${castReturn.Equal[CAST_RESISTED]})) {
  /if (${Bool[${mySub}]}) /call ${mySub} ${spellID}
  /goto :cast_spell_loop
} else {
  /if (!${Me.SpellReady[${spellName}]} && !${castReturn.Equal[CAST_RESISTED]}) /return CAST_NOTREADY
}
/cast "${spellName}"
/if (${Me.Casting.ID}) {
  /varset spellID ${Me.Casting.ID}
  /varcalc castEndTime ${Me.Casting.CastTime}*10
  /if (${castEndTime}<${Math.Calc[${Me.Casting.CastTime}*5]}) /varcalc castEndTime ${Me.Casting.CastTime}*5
}
/varset moveBack false
/call WaitCast ${mySub} ${spellID}
/if (${moveBack}) {
  /delay 15 !${Me.Moving}
}
/if (${castReturn.Equal[CAST_CANCELLED]}) /return CAST_CANCELLED
/call DoCastingEvents
/if (!${castReturn.Equal[CAST_SUCCESS]}) {
  /if (${castReturn.Equal[CAST_RECOVER]}) {
    /if (!${recoverWaitTime}) {
      /varcalc spellRecastTime${Me.Gem[${spellName}]} 10*${Spell[${spellID}].RecastTime}
      /if (!${giveUpTimer}) /return CAST_NOTREADY
    }
    /goto :cast_spell_loop
  }
  /if (${castReturn.Equal[CAST_RESTART]} || ${castReturn.Equal[CAST_STUNNED]} || ${castReturn.Equal[CAST_FIZZLE]} || ${castReturn.Equal[CAST_COLLAPSE]} || (${castReturn.Equal[CAST_INTERRUPTED]} && ${giveUpTimer}) || (${castReturn.Equal[CAST_RESISTED]} && ${ResistCounter})) /goto :cast_spell_loop
}
/if (!${castReturn.Equal[CAST_CANNOTSEE]} && !${castReturn.Equal[CAST_OUTOFRANGE]} && !${castReturn.Equal[CAST_OUTOFMANA]} && !${castReturn.Equal[CAST_NOTARGET]} && !${castReturn.Equal[CAST_INTERRUPTED]}) {
  /varcalc refreshTime 10*${Spell[${spellID}].RecoveryTime}
  /varcalc spellRecastTime${Me.Gem[${spellName}]} 10*${Spell[${spellID}].RecastTime}
}
/return

Sub ItemCast(spellName,mySub)
/declare charges int local
/declare oldItemName string local
/declare slotName string local
/declare swapItemBack 		bool 	local 	FALSE
/declare needSwap		bool 	local 	FALSE
/declare itemInBag		bool 	local 	FALSE
/declare eqLoop			int 	local 	0
/declare equippedArray[33]	string 	local

	/varset equippedArray[1] head
	/varset equippedArray[2] face
	/varset equippedArray[3] neck
	/varset equippedArray[4] rightear
	/varset equippedArray[5] leftear
	/varset equippedArray[6] arms
	/varset equippedArray[7] hands
	/varset equippedArray[8] rightwrist
	/varset equippedArray[9] leftwrist
	/varset equippedArray[10] rightfinger
	/varset equippedArray[11] leftfinger
	/varset equippedArray[12] shoulder
	/varset equippedArray[13] back
	/varset equippedArray[14] chest
	/varset equippedArray[15] waist
	/varset equippedArray[16] legs
	/varset equippedArray[17] feet
	/varset equippedArray[18] mainhand
	/varset equippedArray[19] offhand
	/varset equippedArray[20] ranged
	/varset equippedArray[21] ammo
	/varset equippedArray[22] charm
	/varset equippedArray[23] powersource
	/varset equippedArray[24] pack1
	/varset equippedArray[25] pack2
	/varset equippedArray[26] pack3
	/varset equippedArray[27] pack4
	/varset equippedArray[28] pack5
	/varset equippedArray[29] pack6
	/varset equippedArray[30] pack7
	/varset equippedArray[31] pack8
	/varset equippedArray[32] pack9
	/varset equippedArray[33] pack10
	
:cast_item
/varset itemInBag TRUE
/varset needSwap FALSE
/varset swapItemBack FALSE

/for eqLoop 1 to 33
     /if (${Me.Inventory[${equippedArray[${eqLoop}]}].ID}==${FindItem[${spellName}].ID} && !${Me.Inventory[${equippedArray[${eqLoop}]}].Container}) {
	 /varset itemInBag FALSE
	 /varset slotName ${equippedArray[${eqLoop}]}
	 /if (${eqLoop}>23 && ${FindItem[${spellName}].WornSlot[1]} && ${FindItem[${spellName}].EffectType.Find[worn]}) {
             /varset slotName ${FindItem[${spellName}].WornSlot[1].Name}
             /varset swapItemBack TRUE
	     /varset needSwap TRUE
         }
     }
/next eqLoop

/if (${itemInBag}) {
  /if (${FindItem[${spellName}].WornSlot[1]} && ${FindItem[${spellName}].EffectType.Find[worn]}) {
    /varset slotName ${FindItem[${spellName}].WornSlot[1].Name}
    } else {
	/varset slotName pack8
    }
	/varset swapItemBack TRUE
	/varset needSwap TRUE
}

/if (${needSwap}) {
	/varset oldItemName ${Me.Inventory[${slotName}].Name}
  /call SwapItem "${spellName}" ${slotName}
}
:wait_item_loop
/if (${itemRefreshTime}>${MacroQuest.Running}) /goto :wait_item_loop
/varset itemRefreshTime ${Math.Calc[${MacroQuest.Running}+000]}
/varset charges ${FindItem[${spellName}].Charges}
/nomodkey /cast item "${spellName}"
/if (${Me.Casting.ID}) /varcalc castEndTime ${FindItem[${spellName}].CastTime}*10
/delay 1s ${FindItem[${spellName}].Charges}!=${charges}
/call WaitCast ${mySub}
/if (${FindItem[${spellName}].CastTime}<0.5) /delay 5
/if (${swapItemBack} && ${FindItem[${oldItemName}].ID}) /call SwapItem "${oldItemName}" ${slotName}
/if (${castReturn.Equal[CAST_CANCELLED]}) /return CAST_CANCELLED
/call DoCastingEvents
/if (${castReturn.Equal[CAST_RESTART]} || ${castReturn.Equal[CAST_STUNNED]} || (${castReturn.Equal[CAST_INTERRUPTED]} && ${giveUpTimer}) || ${castReturn.Equal[CAST_COLLAPSE]} || (${castReturn.Equal[CAST_RESISTED]} && ${ResistCounter})) /goto :cast_item
/return

Sub AltCast(spellName,mySub)
:cast_alt
/varset castReturn X
/nomodkey /alt activate ${Me.AltAbility[${spellName}].ID}
/delay 5 ${Me.Casting.ID}
/call WaitCast ${mySub}
/if (${castReturn.Equal[CAST_CANCELLED]}) /return CAST_CANCELLED
/call DoCastingEvents
/if (${castReturn.Equal[CAST_RESTART]} || ${castReturn.Equal[CAST_STUNNED]} || (${castReturn.Equal[CAST_INTERRUPTED]} && ${giveUpTimer}) || (${castReturn.Equal[CAST_RESISTED]} && ${ResistCounter})) /goto :cast_alt
/return

Sub ClearCursor
/declare i int local
:auto_inv
/if (${Cursor.ID}) {
  /if (${Cursor.Container}) {
    |---- Inventory Bag Slots
    /for i 1 to 10    
    /if (!${InvSlot[pack${i}].Item.Container}) /nomodkey /itemnotify pack${i} leftmouseup
    /next i
    |---- Inventory Bag Slots    
  } else {
    /timed 5 /autoinventory
  }
  /goto :auto_inv
}
/return

Sub DoCastingEvents
/doevents Recover
/doevents BeginCast
/doevents Fizzle
/doevents Interrupt
/doevents Standing
/doevents FDFail
/doevents OutOfRange
/doevents OutOfMana
/doevents NoLOS
/doevents Resisted2
/doevents Resisted
/doevents Immune
/doevents Stunned
/doevents Collapse
/doevents NoTarget
/doevents NotReady
/doevents NoHold
/return

Sub EquipItem(WhatWhere)
/declare DestName string local
/declare ItemName string local ${WhatWhere.Arg[1,|]}
/declare SlotName string local ${WhatWhere.Arg[2,|]}
/if (${SlotName.Equal[NULL]}) /varset SlotName ${InvSlot[${FindItem[=${ItemName}].WornSlot[1]}].Name}
/if (${FindItem[=${ItemName}].InvSlot}<23 || !${FindItem[=${ItemName}].WornSlot[${SlotName}]}) /return
/if (!${InvSlot[${SlotName}].Item.Name.Equal[NULL]}) /varset DestName "${InvSlot[${SlotName}].Item.Name}|${SlotName}"
/call SwapItem "${ItemName}" "${SlotName}"
/return ${DestName}

Sub Interrupt
/if (${Me.Mount.ID}) /dismount
/stopcast
/if (${Defined[castReturn]}) /varset castReturn CAST_CANCELLED
/return ${castReturn}

Sub SwapItem(itemName,slotName)
/declare i int local
/if (${Cursor.ID}) /call ClearCursor
/exchange "${itemName}" ${slotName}
|/delay 5s ${InvSlot[${slotName}].Item.Name.Equal[${itemName}]}
/delay 5s ${Me.Inventory[${slotName}].Name.Equal[${itemName}]}
/if (${Cursor.ID}) /call ClearCursor
/return

Sub WaitCast(mySub,int spellID)
/declare currentTarget int local ${Target.ID}
/declare currentTargetType string local ${Target.Type}
:wait_cast_loop
/if (${Bool[${mySub}]}) /call ${mySub} ${spellID}
/if (${Me.Casting.ID}) {
  /if (${currentTarget} && !${Spawn[${currentTarget}].Type.Equal[${currentTargetType}]}) {
    /if (!${Me.Casting.TargetType.Equal[PB AE]} && !${Me.Casting.TargetType.Equal[self]} && !${moveBack} && (!${Me.Mount.ID} || !${noInterrupt})) {
      /if (!${Me.Mount.ID} || ${castEndTime}>70) {
        /call Interrupt
      } else /if (${Me.Casting.RecastTime}>3) {
        /varset castReturn CAST_CANCELLED
        |/keypress forward hold
        |/delay 6
        |/keypress forward
	/interrupt
        /varset moveBack true
      }
    }
  }
  /if (${Me.State.Equal[DUCK]}) /varset castReturn CAST_CANCELLED
  /goto :wait_cast_loop
}
/return

Sub Event_BeginCast
/if (${Defined[castReturn]}) /varset castReturn CAST_SUCCESS
/return

Sub Event_Collapse
/if (${Defined[castReturn]}) /varset castReturn CAST_COLLAPSE
/varset giveUpTimer 200
/return

Sub Event_FDFail(line,name)
/if (${name.Equal[${Me.Name}]} && ${Defined[castReturn]}) {
  /if (!${Me.Standing}) /stand
  /varset castReturn CAST_RESTART
}
/return

Sub Event_Fizzle
/if (${Defined[castReturn]}) /varset castReturn CAST_FIZZLE
/return

Sub Event_Immune
/if (${Defined[castReturn]}) /varset castReturn CAST_IMMUNE
/return

Sub Event_Interrupt
/if (${Defined[castReturn]}) /varset castReturn CAST_INTERRUPTED
/return

Sub Event_NoHold
/if (${Defined[spellNotHold]}) /varset spellNotHold 1
/if (${Defined[castReturn]}) /varset castReturn CAST_NOTHOLD
/return

Sub Event_NoLOS
/if (${Defined[castReturn]}) /varset castReturn CAST_CANNOTSEE
/return

Sub Event_NoMount 
/if (${Defined[castReturn]}) /varset castReturn CAST_NOMOUNT 
/return 

Sub Event_NoTarget
/if (${Defined[castReturn]}) /varset castReturn CAST_NOTARGET
/return

Sub Event_NotReady
/if (${Defined[castReturn]}) /varset castReturn CAST_NOTREADY
/return

Sub Event_OutOfMana
/if (${Defined[castReturn]}) /varset castReturn CAST_OUTOFMANA
/return

Sub Event_OutOfRange
/if (${Defined[castReturn]}) /varset castReturn CAST_OUTOFRANGE
/return

Sub Event_Recover
/if (${Defined[castReturn]}) /varset castReturn CAST_RECOVER
/return

Sub Event_Resisted(line,name)
/if (${selfResist} && ${name.Equal[${selfResistSpell}]}) /varset selfResist 0
/if (${ResistCounter}) /varcalc ResistCounter ${ResistCounter}-1
/if (${Defined[castReturn]}) /varset castReturn CAST_RESISTED
/return

Sub Event_Resisted2(line,name)
/if (${Defined[selfResist]}) {
  /varset selfResist 1
  /varset selfResistSpell ${name}
}
/return

Sub Event_Standing
/stand
/if (${Defined[castReturn]}) /varset castReturn CAST_RESTART
/return

Sub Event_Stunned
/if (${Me.Stunned}) {
  /delay 3s !${Me.Stunned}
} else {
  /delay 7
}
/if (${Defined[castReturn]}) /varset castReturn CAST_STUNNED
/return

Incognito · May 5, 2016

Thx Pugs, will try it. Did a file compare and it's an elegant and unobtrusive mod (wont break any mac that includes it).

Roy Donk · May 25, 2016

I have mq2cast loaded and everything for the life of me i cant seem to get my wizard to fire. Any other obvious issues that might cause this?

toots · May 25, 2016

Did you camp out and back in? Sometimes my wizzies just freeze up spell casting with this Mac. A camp usually fixes it.

Sum1 · May 26, 2016

huffyhenry said:
I have mq2cast loaded and everything for the life of me i cant seem to get my wizard to fire. Any other obvious issues that might cause this?

Did you start the macro with the toon you're assisting targeted?

Also, please ensure you aren't targeting a merc as group assist. It doesn't seem to like assisting a merc. I had to add a real tank to my group, and after that the 85 level macro worked fantastically. I imagine the higher level ones will, as well.

Roy Donk · May 28, 2016

yeah i've used afnukes forever, for some reason it wasnt firing. It's running now though, was just a needing a hard reset I reckon.

Sum1 · Jun 2, 2016

What do you guys do when your toon out-levels the 81-85 spells, but isn't high enough for the lvl 100 version?

I've gone through the mac and I believe I found where I could edit the names of the lvl 81-85 spells into the 86-92-ish level ones I'd need to use. I think its as simple as changing the names there, right? What will I break if I change the spells inside the mac?

Dretski · Jun 2, 2016

I level them to 100 within 24 hours, so I really don't care for running the 85 version. :P

Sum1 · Jun 2, 2016

Dretski said:
I level them to 100 within 24 hours, so I really don't care for running the 85 version. :P

lol, well after your method in the other thread that doesn't surprise me. Unfortunately, I'm taking a slightly more ... lengthy ... approach

Hambam · Jun 2, 2016

There are some KA ini's I normally use until 100+. Leveling goes so quick now easier to just plop those in until they can use the good stuff!

nyghteyes · Jun 2, 2016

Sum1 said:
This makes me want to roll a Wizard ASAP. In fact, it needs to happen this weekend (SK, Cleric, Bard, Ranger, Zerker ... adding a wizzy to that setup makes me happy in the pants).

Swapped my Druid out of my main group to a Wiz for PL ing and holy hell, hope I dont need the spam heals anymore because wizards are pretty amazing, pending the mana pool. I actually had to gear him....

Razkle · Jun 2, 2016

Sum1 said:
What do you guys do when your toon out-levels the 81-85 spells, but isn't high enough for the lvl 100 version?

I've gone through the mac and I believe I found where I could edit the names of the lvl 81-85 spells into the 86-92-ish level ones I'd need to use. I think its as simple as changing the names there, right? What will I break if I change the spells inside the mac?

Change them at your own peril, just make sure you put your nukes where the nukes go and the cold where the cold goes and stuff or they wont fire the right way. Or just powerlevel through from 85 to 100 in a day (ok in 3)

- - - Updated - - -

your 85 spells are FINE until you hit 100 BTW, even at 100 those are ok but no where near what you can expect at 105!

Panda · Jun 2, 2016

I used the 85 spells until my wizard hit 100. Big jump in damage, but he was still keeping up with a 105 bard in TDS gear. 105 though is a massive jump, especially when you give them appropriate gear.

Does anyone have any issues with the macro using the TBM chest piece? I edited the configuration file with the proper name, but have yet to ever see my wizard use it.

Sum1 · Jun 2, 2016

Razkle said:
Change them at your own peril, just make sure you put your nukes where the nukes go and the cold where the cold goes and stuff or they wont fire the right way. Or just powerlevel through from 85 to 100 in a day (ok in 3)

- - - Updated - - -

your 85 spells are FINE until you hit 100 BTW, even at 100 those are ok but no where near what you can expect at 105!

Thanks, man. I had planned on upgrading the spells with the upgraded versions of spells from the same lines for precisely the reasons you stated. I presumed that someone so over-the-top anal about their wizards had a reason for everything ;-) (that's a compliment, btw)

I might just stick with the 85 spells until 100, then. My little guy held his own with a bard in a few lvl 105 TBM missions the other day... I dropped a healer merc to add the wiz in and he did great.

Darkmax · Jun 9, 2016

Finally had a chance to play with this and a great wizard.. Wow -- Very enjoyable! I have some tinkering to do with rest of the group but the wizards definitely lay down some fire.

Thanks for sharing your talents!

Razkle · Jun 9, 2016

Panda said:
I used the 85 spells until my wizard hit 100. Big jump in damage, but he was still keeping up with a 105 bard in TDS gear. 105 though is a massive jump, especially when you give them appropriate gear.

Does anyone have any issues with the macro using the TBM chest piece? I edited the configuration file with the proper name, but have yet to ever see my wizard use it.

Have not tested it with the TBM piece, will add that to my plate thanks!

Sum1 · Jun 10, 2016

Just hit 100 on my wizzy.... time to stick him in some castaway gear and get new spells

.... really interested in seeing the upgrade from the lvl 85 heroic gear and spells.

JackDaniels · Jun 12, 2016

Considering this mac to get more dps out of my 105 silver wiz. He's not max as but around 9k. But I do not have a tank in group. I use a merc tank. Will the macro really not work without a PC tank?

psimoon · Jun 12, 2016

What I did with my wizzies in leveling them from 85 HC to 105 was to change the INI every couple of levels or so. If you look at the name of the spells in the initial 85 HC INI you will see that spells follow spell lines. usually a couple of spells are replaced at say 86 87 then later on more are replaced going up to 90. Follow the spell lines, you will be able to see that within 5 levels a spell that has the same spell icon as the one you want to replace and have pretty much the same discription as the previous spell only the numbers have changed. Just replace like with like.

For 100 and 105 I used the Gems mac and that level macro.

Hope this helps.

- - - Updated - - -

also, you will notice that if a new spell is replaced at say lvl 86, then there is a 99% chance that the next in the line will be replaced at same place in the next 5 levels, ie 91, 96, 101, or if it is replaced at the end of the 5 levels it will usually follow that progression.

JackDaniels · Jun 13, 2016

Ok, i went thru and read this front to back. Several people have had the same issue i am. Macro fires up, Wizard recogonizes a mob in camp with is distance. It fires off any available AA clicks and it will do one cast of Claw. Then it just sits there period.

i have downloaded off the main page, I have used the af2nukegem to load the spells. The only oddity is the macro tries to load concussive storm Rk3 which i obviously as a casual do not have. i have made sure mq2cast plugin is loaded. i have made sure the downshits are copied over and turned on in melee. The only thing i dont have is an actual PC tank. I don't want to box 4/5/6 characters, i would like to just get more then 20k out of my available toons. I have tried to start the macro with either using my beast or my tank merc and i get the above, 1 nuke and stall out.

jimbob · Jun 13, 2016

Interesting. Do you have a MT/MA group roles set? I know the plugin version requires a MA/MT to be set in group, and invis to be off to cast...

Razkle · Jun 13, 2016

It does NOT work with a merc tank, you have to TARGET the tank and type /mac afnuke2

I use this thing on 22 wizards all damn day every day

I setup a SOCIAL

Rich (BB code):

line 1 : /end
line 2 : /target nameoftank
line 3 : /mac afnuke2

works perfect everytime.....

RedQueen · Jun 13, 2016

/bcg //tar tankname
/bct cleric //mac autocleric
/bct bard //mac kissassist
/bct wizzie1 //mac afnuke2
/bct wizzie2 //mac afnuke2
/bct wizzie3 //mac afnuke2

My usual macros

sabby · Jun 14, 2016

/bcg //target ''tankname''
/bcg //startmacro

I use mq2startmacro to automate all my boxes macro's. it's easier just because they all somewhat use different macro's.

macroquester · Jun 14, 2016

sabby said:
/bcg //target ''tankname''
/bcg //startmacro

I use mq2startmacro to automate all my boxes macro's. it's easier just because they all somewhat use different macro's.

How do they know what macros to use?

Raz's AFNuke2 for 105 Fire Wizies

Single-handedly keeping Daybreak in business

Spends too much on EQ

Single-handedly keeping Daybreak in business

Member

Warriors are inferior (read: crybaby) tanks

Member

Warriors are inferior (read: crybaby) tanks

New member

New member

Single-handedly keeping Daybreak in business

Active member

Member

Single-handedly keeping Daybreak in business

Member

Member

Warriors are inferior (read: crybaby) tanks

Member

Warriors are inferior (read: crybaby) tanks

Active member

Warriors are inferior (read: crybaby) tanks

What is a macro??

Single-handedly keeping Daybreak in business

Member

Warriors are inferior (read: crybaby) tanks

Member

Single-handedly keeping Daybreak in business

Warriors are inferior (read: crybaby) tanks

Active member

Member

Active member

Single-handedly keeping Daybreak in business

New member

New member

Users who are viewing this thread

Cart