Question - Mass enchanting

[ToeJamSamy]

Is there a simple command to use with a built-in macro or plugin to just cast the same spell over and over for enchanting stuff? Or do I have to install something else like a skillup macro and modify it?

 

[jande]

Not facy checking for mana/buffs whatever, does get the job done.

Mem enchant spell in first gemslot.

#Event Missing "You are missing #1#."
#turbo 80


Sub Main

    /plugin mq2cast load noauto
|---Main Loop---|
:mainloop

    /doevents
    /delay 90s ${Me.SpellReady[${Me.Gem[1].Name}]}
    /cast ${Me.Gem[1].Name}
    /delay 90s ${Me.Casting.ID}
    /doevents

    /if (${Cursor.ID}) {
        /echo Sending \ag${Cursor.Name}\ax to a Bag
        /delay 1s
        /autoinventory
    }
/goto :mainloop
/return

|---Events---|

Sub Event_Missing(string line, string itemname)
    /if (${line.Find[some required]}) /return
    /echo Missing: \ag${itemname}
    /beep
    /stopcast
    /docommand /end
/return

or lmao you could do (random thought)

/plugin mq2twist load
/twist 1

Just have something like autoforage/autoloot drop cursor items to your bag.

 

[Robban]

Is there a simple command to use with a built-in macro or plugin to just cast the same spell over and over for enchanting stuff? Or do I have to install something else like a skillup macro and modify it?

https://www.redguides.com/community/threads/massenchant-mac.75541/

 

[ToeJamSamy]

Not sure how I missed that only things came up in my search we're enchanter inis lol

 

[Magnuss]

Save this code as "Enchant.mac", if you do not yet have this file in your macro folder.
Load the spell for enchant in gem 12 (or change line 20).
Then edit the line 21 "/delay 18s" to fit with your casting time spell.

|
| File name : Enchant.mac
| Command : /mac Enchant
| Load Enchanting spell on Gem 12 (Line 20)
| Check casting time of your spell and add 2 or 3 seconds.
|       Line 21 => "/delay 18s"
|

#event OutOfStuff "You are missing some required components."
#include spell_routines.inc

Sub Main
:Loop
  /doevents
  :ClearCursor
   /if (${Cursor.ID}) {
   /autoinventory
  /goto :ClearCursor
  }
  /cast 12
  /delay 18s
/goto :Loop

Sub Event_OutOfStuff
/endmacro
/return

 

[philreynolds]

Here's a simple one that I wrote while working up my TS's for the ToV earring. Wanted something that would run in the background while I did my combines on a different toon, without worrying about it until it finished enchanting what i wanted.

| File name : enchant.mac
| Command : /mac Enchant
| Load Enchanting spell on Gem 1

#event outofitems "You are missing#*#"

Sub Main

    /declare SpellDelay int outer
    
    /varset SpellDelay ${Math.Calc[${Int[${Math.Calc[${Me.Gem[1].MyCastTime} / 1000]}]} + 2]}
    
    :mainloop
    
    /doevents
    /if (${Me.CurrentMana} < ${Me.Gem[1].Mana}) /call med
    /cast 1
    /delay ${SpellDelay}s
    /if (${Cursor.ID}) /autoinv
    /delay 1s
    /goto :mainloop

/return

Sub Event_outofitems
    /bc Ending Macro .... ${Me.Name}
    /endm
/return

Sub med

    /if (!${Me.Sitting}) /sit on
    :medloop
    /if (${Me.PctMana} < 100) /goto :medloop
    
/return

 

[ChatWithThisName]

Smashed this together to enchant with AA's. Obv need to change component needed, name of AA to use, and the Quantity to match your needs.
IE: 1 can be changed to 10 as needed based on the number you're wanting to enchant and the AA available to you.

Sub Main
    /declare Qty int local 10
    /declare component string local Refined Restless Velium
    /declare EnchantAA string local Enchant Refined Velium
    /while (${FindItemCount[=${component}]} >= ${Qty}) {
        /if (${Me.AltAbility[${EnchantAA} (x${Qty})]} && ${Me.AltAbilityReady[${EnchantAA} (x${Qty})]}) {
            /alt act ${Me.AltAbility[${EnchantAA} (x${Qty})].ID}
        }
       
        /if (${Cursor.ID}) {
            /autoinv
        }
       
        /delay 1
    }
/return

Happy hunting.

 

[Hylander]

While condition, should it be < ?

 

[ChatWithThisName]

While I have more than or exactly Qty.
If I had less than I wouldn't have enough.

 

[deathlock]

I am confused how I can combine all this thread to make a working macro that will do gem or aa? Any help out there?

 

[deathlock]

https://www.redguides.com/community/threads/massenchant-mac.75541/#post-464561 is the solution.

#Event Missing "You are missing #1#."
#Event Med "Insufficient Mana#*#"
#turbo 80

#warning
Sub Main(int AA)

    /plugin mq2cast load noauto
|---Main Loop---|
:mainloop

    /doevents
    
    /if (!${AA}) {
        /delay 90s ${Me.SpellReady[${Me.Gem[1].Name}]}
        /cast ${Me.Gem[1].Name}
    } else {
        /delay 90s ${Me.AltAbilityReady[${AA}]}
        /alt act ${AA}
    }
    /delay 2s
    /delay 90s !${Me.Casting.ID}   
    /autoinventory
    /doevents
    
    /while (${Cursor.ID}) {
        /echo Sending \ag${Cursor.Name}\ax to a Bag
        /delay 1s
        /autoinventory
    }
/goto :mainloop
    /autoinventory
/return

|---Events---|

Sub Event_Missing(string line, string itemname)
    /if (${line.Find[some required]}) /return
    /echo Missing: \ag${itemname}
    /bc Missing: [+g+]${itemname}
    /beep
    /stopcast
    /docommand /endmacro
/return

Sub Event_Med(string line)
    /echo Medding 60s
    /delay 60s
/return