Fabulous - Free Pet Illusion/Familiar

[Lemons]

I almost missed this, so figured others could benefit as well:

 

[Sic]

There was a thread, but got moved to fippys because we can't have things.

 

[Lemons]

I realized I would have to buy them manually on all my toons, which was unacceptable.

The below mac will buy all 9 of the bunnies for you. It has some safeguards, but it's also interacting with the DB store, so use at your own risk. I've purchased a few dozen at this point without issue. Enjoy!

[CODE lang="ini" title="PridePurchase"]Sub Main
/declare bunnyCount int outer 0
/declare bunnyArray[9,2] string outer
/declare i int local

/echo Purchasing all of the Erollisi's Pride Pet Illusions
/echo \agP \ayR \amI \apD \arE \agP \ayR \amI \apD \arE \agP \ayR \amI \apD \arE \agP \ayR \amI \apD \arE

|Fill the bunny array
/call fillBunnyArray

|Open the DB Store window
/if (!${Window[MarketplaceWnd]}) /notify EQMainWnd EQM_SCButton leftmouseup
/delay 10m ${Window[MarketplaceWnd]}

|Click on Trinkets
/while (${Window[MarketplaceWnd].Child[MKPW_CategoriesTree].GetCurSel} != 16) {
/notify MarketplaceWnd MKPW_CategoriesTree listselect ${Window[MarketplaceWnd].Child[MKPW_CategoriesTree].List[Trinket]}
/delay 10m ${Window[MarketplaceWnd].Child[MKPW_CategoriesTree].GetCurSel} == 16
}

|Buy the bunbuns
/for i 1 to 9
/echo call with i ${i}
/call selectBunBun ${i}
/delay 5
/call buyBunBun
/echo I've purchased ${bunnyCount} bunbuns!
/next i
/echo \agP \ayR \amI \apD \arE \agP \ayR \amI \apD \arE \agP \ayR \amI \apD \arE \agP \ayR \amI \apD \arE \agP \ayR \amI \apD \arE
/return

Sub selectBunBun(num)
/while (${Window[MarketplaceWnd].Child[MKPW_ItemList].GetCurSel} != ${Window[MarketplaceWnd].Child[MKPW_ItemList].List[${bunnyArray[${num},2]},3]}) {
/notify MarketplaceWnd MKPW_ItemList listselect ${Window[MarketplaceWnd].Child[MKPW_ItemList].List[${bunnyArray[${num},2]},3]}
/delay 5
}
/return


Sub buyBunBun()
/if (${Window[MarketplaceWnd].Child[MKPW_BuyTotal].Text.NotEqual[0]}) {
/beep
/echo Well shit! The cost isn't 0. Something must have gone wrong. Not gonna buy ${Window[MarketplaceWnd].Child[MKPW_DetailsName].Text}
/end
}

/notify MarketplaceWnd MKPW_BuyBtn leftmouseup ${Window[MarketplaceWnd].Child[MKPW_BuyBtn]}
/delay 10m ${Window[MarketplaceWnd].Child[MKPW_ConfirmPage]}
/notify MarketplaceWnd MKPW_ConfirmPurchase_ConfirmBtn leftmouseup
/varcalc bunnyCount ${bunnyCount}+1
/delay 10m ${Window[ConfirmationDialogBox].Child[CD_TextOutput].Text.Find[You have successfully purchased]} && ${Window[ConfirmationDialogBox]}
/notify ConfirmationDialogBox CD_OK_Button leftmouseup
/delay 10m !${Window[ConfirmationDialogBox]}

/return

Sub fillBunnyArray
/varset bunnyArray[1,2] Boundless
/varset bunnyArray[2,2] Trueheart
/varset bunnyArray[3,2] Proudheart
/varset bunnyArray[4,2] Openheart
/varset bunnyArray[5,2] Aceheart
/varset bunnyArray[6,2] Freeheart
/varset bunnyArray[7,2] Boldheart
/varset bunnyArray[8,2] Flawless
/varset bunnyArray[9,2] Sisterheart
/return [/CODE]

 

[Lemons]

If you downloaded it in the last 4 minutes, please download again. There's an issue if you don't have the Trinkets category expanded first (Fixed now).

 

[AmericanNero]

That's awesome