Macro - A tip macro for raid healer, helping you set/clear the ETW.

[KingArthur]

Say you are a healer in raid, you need put all your raid tanks who are outside of your own group to your ETW, and every time the raid tank list changed, you need wipe out it..
Manually you get bored, especially if you are boxing multiple healer...

Here is the savior.

| Set your XTarget Window in Raid, By KingArthur.
|V1.1 20190328

Sub Main
/declare dummy int local 0
/declare XSetMove string outer ${Param0}
/call CheckPlugin MQ2XAssist
/call DefineTank
/call DynamicETW
/return

Sub DefineTank
/declare Tank2 string outer TankName1
/declare Tank3 string outer TankName2
/declare Tank4 string outer TankName3
/declare Tank5 string outer TankName4
/declare Tank6 string outer TankName5
/declare Tank7 string outer TankName6
/return

Sub DynamicETW
/declare i int local 2
/declare j int local 2
/declare z int local 1
/if (!${Select[${Me.Class.ShortName},CLR,DRU,SHM]}||!${Select[${XSetMove},Set,Clear]}) {
     /echo You are not a healer, end this.
     /end
} else /if (${XSetMove.Equal[Set]}) {
    /for j 2 to 7
     /if (!${Group.Member[${Tank${j}}].ID}&&${Spawn[pc ${Tank${j}}].ID}) {
        /if (!${Me.XTarget[${i}].ID}) {
           /xtarget set ${i} ${Tank${j}}
           /delay 5
           /varcalc i ${i}+1
        } else {
          /varcalc i ${i}+1
        }        
      }
   /next j
} else /if (${XSetMove.Equal[Clear]}) {
    /cecho \ay Now Clear the ETW.
     /for z 1 to 13
     /xtarget remove
     /delay 3
     /next z
  }
/return

Sub CheckPlugin(string pluginname)
        /if (!${Bool[${Plugin[${pluginname}]}]}) {
            /squelch /plugin ${pluginname}
            /echo ${pluginname} not detected! This macro requires it! Loading ...
        }
/return

How to use it？
Edit the TankName1 to TankName6 to your raid tank name accordingly.
/mac XT set will set those tanks who are outside of your group to ETW, starting from the 2nd XTarget slot.
/mac XT clear will wipe out the ETW, resetting it to all AutoHater mode.

 

[Marnan]

Sweet!

 

[Rooster]

... liked this idea, never got around to it myself. But i updated your macro to suit my needs and if anyone else would like..

same macro usage, but it will automatically add tanks in your raid to a list and add them from bottom up in xtarget ( i like to use bottom up, and keep top auto hater... maybe some ocd?)

| Set your XTarget Window in Raid, By KingArthur.
|V1.1 20190328
| Updated by Rooster to auto set any non grouped raid tanks from bottom xtarget up

Sub Main
/declare XSetMove string outer ${Param0}
/call CheckPlugin MQ2XAssist
/call RaidAutoTankList
/call DynamicETW
/return

Sub RaidAutoTankList
    /echo sorting through raid for tanks..
    /declare rt int local 1
    /declare tt int outer 1
    /for rt 1 to ${Raid.Members}
        /if (${Select[${Raid.Member[${rt}].Class.ShortName},WAR,SHD,PAL]}) {
            /echo ${Raid.Member[${rt}]} is a TANK!
            /declare Tank${tt} string outer ${Raid.Member[${rt}]}
            /varcalc tt ${tt}+1
        }
        /next rt
        /return

Sub DynamicETW
/declare i int local 13
/declare j int local 1
/declare z int local 1
/if (!${Select[${Me.Class.ShortName},CLR,DRU,SHM]}||!${Select[${XSetMove},Set,Clear]}) {
     /echo You are not a healer or you didn't specify 'set' / 'clear' - macro usage '/mac xt set' OR '/max xt clear'
     /end
} else /if (${XSetMove.Equal[Set]}) {
    /for j 1 to ${Math.Calc[${tt}-1]}
     /if (!${Group.Member[${Tank${j}}].ID} && ${Spawn[pc ${Tank${j}}].ID}) {
        /if (!${Me.XTarget[${i}].ID}) {
            /echo Setting XT ${i} - ${Tank${j}}
           /xtarget set ${i} ${Tank${j}}
           /delay 5
           /varcalc i ${i}-1
        }
               
      }
       /next j
} else /if (${XSetMove.Equal[Clear]}) {
    /echo Now Clear the ETW.
     /for z 1 to 13
     /xtarget remove
     /delay 3
     /next z
  }
/return

Sub CheckPlugin(string pluginname)
        /if (!${Bool[${Plugin[${pluginname}]}]}) {
            /squelch /plugin ${pluginname}
            /echo ${pluginname} not detected! This macro requires it! Loading ...
        }
        /echo Checked plugin ok
/return

 

[bb4]

I just want to bring attention back to this amazing macro and the work done by KingArthur and Rooster. I made a quick edit to Rooster's to start at top and changed it to an include for modbot. Now when my clerics start up in raids, they auto populate their extended target window with all the tanks in the raid. Very helpful when raiding with others.

 

[MrPatate]

only working for modbot? or working for other macro like kiss or ihc?

 

[bb4]

only working for modbot? or working for other macro like kiss or ihc?

Just gotta edit the code really quick to add it to kiss or ihc. At the beginning of the code you'll see a section with #include, add
#include xt.inc

Further down in the start up section you'll want to add
/call xt

For Modbot, I've got it within the INI, but modbot INIs are very different from KISS because you can write scripts into the INI.