Problem - Zerker issues summoning things

[Cupcake]

This'll seem kinda dumb, but it's irritating all the same...

My Zerker will summon axes no problem... but....

when I set him up to summon cookies and milk, they just scroll by in mq2 window and he doesn't summon anything.

I have the same summon set up on 3 other toons and none of them have issues. I've went as far as unloading mq2, making a whole new mq2 compile and running it from fresh fresh fresh and it's still not working.

Is there something goofy with zerkers summoning food? Special condition? something?


[Buffs]
BuffsOn=1
BuffsCOn=0
BuffsSize=20
Buffs1=Warm Milk Dispenser|Summon|Warm Milk|10
Buffs2=Fresh Cookie Dispenser|Summon|Fresh Cookie|10
Buffs3=Spiced Iced Tea Dispenser|Summon|Spiced Iced Tea|10

 

[eqholic]

I don't know why you would want 2 different drinks. But otherwise it looks ok to me. I do the same but summon only 2 or 3. The char will eat or drink one and in the next buffcycle will summon one more. So you could save a bit of time. What do you mean with "they just scroll by in the mq2 window" ?

 

[Cupcake]

in the MQ2 window.. it shows the text that I have it, but it spams by because it's actually not doing the summoning. And it doesn't actually include the actual summoning type text.

This is the correct text..

Summoned >> Fresh Cookie <<
I now have 10 of >>Fresh Cookie<<

What I get on my Zerker is

I now have 10 >>Fresh Cookie<<
I now have 10 >>Spiced Iced Tea<<
I now have 10 >>Warm Milk<<

It doesn't have the Summoned text... not sure why. Like you said, it looks correct. I've done just about every thing I can. It works on every toon I have but the Zerker. AND, the Zerker summons it's axes correctly.... ANd yes, I've taken the summon axes out and just had the tea, milk, cookies by there selves.. notta. spams by wtih no summon text.

- - - Updated - - -

Anyone?

 

[ctaylor22]

You sure you don't have the items in your inventory somewhere? See what /echo ${FindItemCount[=Warm Milk]} returns for you.

 

[Cupcake]

They are temporary items, so they poof when you log.

 

[ctaylor22]

I found the issue. I just went and looked at the code and I see where the problem is.

In the summonstuff routine. You need to change This:

                | Summon axes for zerkers had to be hard coded because spell is same name as tm item summoned.
                /if (${Select[${Me.Class.ShortName},BER]} && ${SSpell.Find[axe]}) {
                    /docommand /disc ${SSpell}
                    /delay 80 ${Cursor.ID}
                    /varcalc SummonAttempts ${SummonAttempts}+1
                    /goto :inventory
                }
                | Summon stuff
                /if (!${Select[${Me.Class.ShortName},BER]} && !${SSpell.Find[axe]}) {
                    | Check if isummoning from an item
                    /if (${FindItemCount[=${SSpell}]} > 0) {
                        | Check if item is ready to cast
                        /if (${FindItem[=${SSpell}].Timer}!=0) {
                            /if (${DebugBuffs}) /echo \atDEBUGBUFFS ${SSpell} not ready yet skipping \agLine#: ${Macro.CurLine}
                            /varset SumResult FALSE
                            /return ${SumResult}
                        }
                    }
                    /if (${Cursor.ID}) /call CheckCursor
                    /call CastWhat "${SSpell}" ${Me.ID} SummonStuff-nomem
                }

To This:

                | Summon axes for zerkers had to be hard coded because spell is same name as tm item summoned.
                /if (${Select[${Me.Class.ShortName},BER]} && ${SSpell.Find[axe]}) {
                    /docommand /disc ${SSpell}
                    /delay 80 ${Cursor.ID}
                    /varcalc SummonAttempts ${SummonAttempts}+1
                    /goto :inventory
                } else {
                | Summon stuff
                    | Check if isummoning from an item
                    /if (${FindItemCount[=${SSpell}]} > 0) {
                        | Check if item is ready to cast
                        /if (${FindItem[=${SSpell}].Timer}!=0) {
                            /if (${DebugBuffs}) /echo \atDEBUGBUFFS ${SSpell} not ready yet skipping \agLine#: ${Macro.CurLine}
                            /varset SumResult FALSE
                            /return ${SumResult}
                        }
                    }
                    /if (${Cursor.ID}) /call CheckCursor
                    /call CastWhat "${SSpell}" ${Me.ID} SummonStuff-nomem
                }