Release RoTs.mac 1.03

[gSe7eN]

gSe7eN submitted a new resource:

RoTs.mac - A very simple Remnant of Tranquility management tool.

RoTs.mac is a very basic Remnant of Tranquility management tool. It has two functions: RoTs.mac will take all your RoTs out of your alternate currency tab and inventory them for you; RoTs.mac will take your RoTs from alt currency and trade them to your in range target until there are no more RoTs left to grab.

I have millions of RoTs and frankly managing them all is a time sink that I can't be arsed with. This macro doesn't do any fancy tricks or flips or shit, it just does the above.

I...

Read more about this resource...

 

[gSe7eN]

|--------------------------------------------------
| RoTs.mac
|     Written by gSe7eN 15 Nov 2018
|        Changes: [ .01 Initial release 15 Nov 2018] [08 Feb 2019: Added Debugs code, added ClaimAll] [14 Feb 2019: UPdated Tab Number for EQ Patch]
|
|    Usage: This macro will remove all your Remnants of Tranquility from your Alt Currency tab
|                  and will put it into inventory or trade them all to your target if in close range.
|---------------------------------------------------

#define INVWND InventoryWindow
#define INVTAB IW_AltCurr_PointList
#define CREATEBUTT IW_AltCurr_CreateItemButton
#define DEBUG "/if (${DebugOn}) /echo \aw${Macro.CurLine}\ar"

Sub Main
/declare DebugOn bool outer FALSE
DEBUG clearing target if too far away ${Target.Distance}
/if (${Target.ID}==${Me.ID} || ${Target.Type.NotEqual[PC]} || ${Target.Distance}>24) /squelch /target clear
/invoke ${Window[INVWND].DoOpen}
DEBUG Selecting tab 4.
/notify INVWND IW_Subwindows tabselect 4
/delay 1s
DEBUG Reclaiming all currency
/nomodkey /notify INVWND IW_AltCurr_ReclaimAllButton LeftMouseUp
/delay 1s
DEBUG Selecting RoTs
/nomodkey /notify INVWND INVTAB listselect ${Window[INVWND].Child[IW_AltCurrPage].Child[INVTAB].List[=Remnants of Tranquility,2]}
DEBUG Picking up RoTs and autoinv loop.
/delay 1s
/while (${Window[INVWND].Child[CREATEBUTT].Enabled}) {
    /delay 1s
    /autoinv
    /delay 4s !${Cursor.ID}
    /autoinv
    /shift /notify INVWND CREATEBUTT leftmouseup
    /if (${Target.ID}) /call Give
    DEBUG out of Sub Give.
    /autoinv
}
/invoke ${Window[INVWND].DoClose}
/return

Sub Give
DEBUG In SuB Give
/delay 4s ${Cursor.ID}
/if (${Target.Type.NotEqual[PC]} || ${Target.Distance} > 24) {
    DEBUG target further than 24 distance. Getting out.
    /return
}
/if (${Cursor.ID}) {
    DEBUG giving RoT to target.
    /nomodkey /click left target
    /delay 2s !${Cursor.ID}
    /delay 1s
    DEBUG TradeWnd loop incoming.
    /while (${Window[TradeWnd].Open}) {
        /delay 1s
        /if (${Window[TradeWnd].Child[TRDW_TradeSlot7].Tooltip.Length}) {
            /notify TradeWnd TRDW_Trade_Button LeftMouseUp
        } else /if (!${Window[INVWND].Child[CREATEBUTT].Enabled}) {
            /notify TradeWnd TRDW_Trade_Button LeftMouseUp
        } else {
            /return
        }
    }           
}
/return

 

[Mongo]

What a life saver this will be, transferring hundreds of thousands of these has been a horrible experience, can’t waut to test this!!!