QueenNok.mac -- Afk Exp Macro via Monster Mission

[zippzipp]

This macro runs the Queen Nok Monster mission in Nektulos forrest. You will need at least 3 characters with at Depths of Darkhollow expansion.

The exp is around 1 yellow bubble of AA per go around at 70. A little slow but still effective. It finishes in about 20 mins and waits in the mission for another 20, for lockout timer, before zoning out to get another mission.

Start the macros at the entrance to the zone, which is in in the very southwest corner of the zone, around loc -1900 1180 27.

*WARNING* This macro does use warp use it at your own risk. It only warps inside the instance though. *WARNING*

1. Run QueenNok.Mac on one character
2. Run QueenNoklooter.mac on the remaining 2-5 characters

The first time you run it, on the character running QueenNok.mac you need to spend your monster points and save them. You also MUST get the ability Fairy Fire. Do this the first time and hit save, and it will load the ability after that automatically.

QueenNok.Mac

|--------------------------------------------------|
|  Macro:	QueenNok.mac			   |
|  Author:	ZippZipp			   |
| Written:	12/07/2006			   |
| 						   |
| Description:  This macro gets an instance of the |
| Queen Nok Nok's Monster Mission in Nektulos,     |
| finishes, it then gets another.                  |
| 						   |
|--------------------------------------------------|

#event CantLoot "#*#cannot loot while a hostile creature#*#"
#event Hit "#*#YOU for#*#"
#event Recast "Your Fairy Fire spell has worn off of a Fairy Shrine."
#event Recast "Your ability failed. Timer has been reset."
#event Recast "Your target resisted the Fairy Fire spell."
#event Died "Returning to Shadowed Grove, please wait..."


#turbo

Sub Main

   /echo ***********************************
   /echo        QueenNok.mac   v1.0          
   /echo       Written by:  ZippZipp            
   /echo        Enjoy the Free EXP!!            
   /echo ***********************************    
   /declare castflag int outer

:mainloop

   /call GMCheck
   /call GetMission
   /call LootChest
   /g go ahead and loot
   /varset castflag 1
   /call KillShrine1
   /varset castflag 1
   /call KillShrine2
   /varset castflag 1
   /call KillShrine3
   /delay 22m
   /g lets get out of here
   /warp loc -175 -102 -16
   /delay 2m
   /call NewMission

/goto :mainloop

/return

|-------------------------------------------------
|   Gets a new mission then zones into it        |
|-------------------------------------------------
Sub GetMission

   /doevents flush
   /target a dark spirit of Nektulos
   /delay 10
   /face
   /stick

:stickloop
   /if (${Target.Distance.Int} <= 25) /goto :stickdone
/goto :stickloop

   :stickdone
   /stick off
   /hail
   /delay 3s
   /say What forgotten things?
   /delay 5s
   /notify TaskSelectWnd TSEL_AcceptButton leftmouseup
   /delay 5s
   /notify TaskTemplateSelectWnd TaskTemplateSelectAcceptButton leftmouseup
   /delay 5s
   /if (${Window[TaskWnd].Open}) {
      /cleanup
   }
   /delay 1s
   /moveto loc -1950 1210
   /delay 2m
   /notify AAWindow AAW_LoadButton leftmouseup
   /delay 5s

/return

|----------------------------------------------
| Loots the dust and shard thing
|----------------------------------------------
Sub LootChest

   /doevents flush
   /target Queen Noknok
   /delay 1s
   /warp target
   /delay 1s
   /open
   /delay 4s
   /target Queen Noknok
   /delay 1s
   /loot
   /delay 3s
   /itemnotify loot3 rightmouseup
   /delay 2s
   /itemnotify loot1 rightmouseup
   /delay 3s
   /notify LootWnd DoneButton leftmouseup
   /cleanup
   /doevents
   /doevents flush
   /delay 4s
   /warp succor
   /delay 2s
   /fade
   /delay 10s

/return

|-------------------------------------
| Kills the first fairy shrine
|-------------------------------------
Sub KillShrine1

   /doevents flush
   /declare counter1 int local
   /varset counter1 0

:killloop1

   /if (${counter1}==8000) /varset castflag 1
   
   /if (${castflag}==1) {
      /stand on
      /keypress esc
   :waitfornpc1
      /doevents
      /delay 1s
      /keypress esc
      /target npc undead loc 89 -3 radius 50
      /target npc reanimated loc 89 -3 radius 50
      /if (${Target.ID}!=NULL) /goto :waitfornpc1
      
      /target npc Shrine loc 89 -3 radius 40
      /if (${Target.ID}==NULL) /return
      /delay 1s
      /warp target
      /delay 1s
      /aa act Fairy Fire
      /delay 3s
      /warp succor
      /sit on
      /varset castflag 0
      /varset counter1 0
   }
   /doevents
   /call GMCheck
   /varcalc counter1 ${counter1}+1

/goto :killloop1

/return

|-------------------------------------
| Kills the second fairy shrine
|-------------------------------------
Sub KillShrine2

   /doevents flush
   /declare counter2 int local
   /varset counter2 0

:killloop2

   /if (${counter2}==8000) /varset castflag 1

   /if (${castflag}==1) {
      /stand on
      /keypress esc
   :waitfornpc2
      /doevents
      /delay 1s
      /keypress esc
      /target npc undead loc -159 79 radius 50
      /target npc reanimated loc -159 79 radius 50
      /if (${Target.ID}!=NULL) /goto :waitfornpc2
      
      /target npc Shrine loc -159 79 radius 40
      /if (${Target.ID}==NULL) /return
      /delay 1s
      /warp target
      /delay 1s
      /aa act Fairy Fire
      /delay 3s
      /warp succor
      /sit on
      /varset castflag 0
      /varset counter2 0
   }
   /doevents
   /call GMCheck
   /varcalc counter2 ${counter2}+1

/goto :killloop2

/return

|-------------------------------------
| Kills the third fairy shrine
|-------------------------------------
Sub KillShrine3

   /doevents flush
   /declare counter3 int local
   /varset counter3 0

:killloop3
   
   /if (${counter3}==8000) /varset castflag 1

   /if (${castflag}==1) {
      /stand on
      /keypress esc
   :waitfornpc3
      /doevents
      /delay 1s
      /keypress esc
      /target npc undead loc 34 175 radius 50
      /target npc reanimated loc 34 175 radius 50
      /if (${Target.ID}!=NULL) /goto :waitfornpc3
      
      /target npc Shrine loc 34 175 radius 40
      /if (${Target.ID}==NULL) /return

      /delay 1s
      /warp target
      /delay 1s
      /aa act Fairy Fire
      /delay 3s
      /warp succor
      /sit on
      /varset castflag 0
      /varset counter3 0
   }
   /doevents
   /call GMCheck
   /varcalc counter3 ${counter3}+1

/goto :killloop3

/return
|----------------------------------------------
|  Heals up and meds some
|----------------------------------------------
Sub Healup
   
   /doevents flush
   /delay 1s
   /warp succor
   /delay 1s
   /fade
   /delay 10s
   /target
   /delay 1s
   /aa act Faith of the Fay
   /delay 4s
   /sit on

   :medloop
      /if (${Me.PctMana} > 75) /return
   /goto :medloop

/return

|------------------------------------------
|  removes from old mission and gets a new one
|-----------------------------------------
Sub NewMission
   
   /doevents flush
   /declare ix int local

   /for ix 2 to 6   |--removes groupmates
      /keypress F${ix}
      /delay 1s
      /taskremove ${Target}
   /next ix

   /keypress F1
   /delay 1s
   /taskremove ${Target}
   /delay 1s

/return

|----------------------------------------------
| Re calls Loot in the event that aggro is drawn
|----------------------------------------------
Sub event_CantLoot

   /doevents flush
   /warp succor
   /delay 2s
   /fade
   /delay 30s
   /call LootChest

/return

|----------------------------------------------
| if hit succors and fades
|----------------------------------------------
Sub event_Hit

   /warp succor
   /delay 2s
   /fade
   /delay 3s
   /doevents flush
   /varset castflag 1
   /if (${Me.PctHPs} < 50) /call Healup

/return

|----------------------------------------------
| If you need to recast for any reason
|----------------------------------------------
Sub event_Recast

   /doevents flush
   /varset castflag 1
   /delay 5s

/return

|----------------------------------------------
| Died
|----------------------------------------------
Sub event_Died

   /doevents flush
   /delay 3m
   
/return

|----------------------------------------------
| Check for GM
|----------------------------------------------
Sub GMCheck

   /if (${Spawn[gm].ID}) {
      /beep
      /echo GM Alert Ending macro
      /endm
   }

/return

QueenNoklooter.mac

|--------------------------------------------------|
|  Macro:	QueenNoklooter.mac		   |
|  Author:	ZippZipp			   |
| Written:	12/07/2006			   |
| 						   |
| Description:  This macro gets an instance of the |
| Queen Nok Nok's Monster Mission in Nektulos,     |
| finishes, it then gets another.                  |
| 						   |
|--------------------------------------------------|

#event CantLoot "#*#cannot loot while a hostile creature#*#"
#event Hit "#*#YOU for#*#"
#event CantLoot "#*#already looting that corpse#*#"
#event Died "Returning to Shadowed Grove, please wait..."
#event LootIt "#*#go ahead and loot#*#"
#event TimeToGo "#*#lets get out of here#*#"

#turbo

Sub Main

   /echo ***********************************
   /echo        QueenNoklooter.mac   v1.0          
   /echo       Written by:  ZippZipp            
   /echo        Enjoy the Free EXP!!            
   /echo ***********************************
   /declare returnflag int global
     

:mainloop
   /varset returnflag 0 
   /if (${Window[TaskTemplateSelectWnd].Open}) {
      /delay 5s
      /notify TaskTemplateSelectWnd TaskTemplateSelectAcceptButton leftmouseup
      /delay 2s
      /cleanup
      /delay 30s
      /moveto loc -1950 1210
      /delay 2m
      /warp loc -226 3 -13
      /delay 3s
      /call Wait
   }   
   /call GMCheck
/goto :mainloop

/return

|----------------------------------------------
| waits for events
|----------------------------------------------
Sub Wait

:waitloop

   /if (${returnflag}==1) /return
   /doevents
   /call GMCheck

/goto :waitloop

/return

|----------------------------------------------
| Loots the dust and shard thing
|----------------------------------------------
Sub LootChest

   /doevents flush
   /call GMCheck
   /target Queen Noknok
   /delay 1s
   /warp target
   /delay 1s
   /loot
   /delay 3s
   /itemnotify loot2 rightmouseup
   /delay 2s
   /notify LootWnd DoneButton leftmouseup
   /cleanup
   /doevents
   /doevents flush
   /delay 4s
   /warp loc -226 3 -13
   /delay 2s
   /fade
   /delay 10s

/return


|----------------------------------------------
| Re calls Loot in the event that aggro is drawn
|----------------------------------------------
Sub event_CantLoot

   /doevents flush
   /warp loc -226 3 -13 
   /delay 2s
   /fade
   /delay 20s
   /call LootChest

/return

|----------------------------------------------
| if hit loc -226 3 -13s and fades
|----------------------------------------------
Sub event_Hit

   /warp loc -226 3 -13
   /delay 2s
   /fade
   /delay 3s
   /doevents flush

/return


|----------------------------------------------
| Died
|----------------------------------------------
Sub event_Died

   /doevents flush
   /warp loc -226 3 -13
   
/return

|----------------------------------------------
| lootit
|----------------------------------------------
Sub event_LootIt

   /doevents flush
   /call LootChest
   
/return

|----------------------------------------------
| lootit
|----------------------------------------------
Sub event_TimeToGo

   /doevents flush
   /delay 1s
   /gate
   /varset returnflag 1
   
/return

|----------------------------------------------
| Check for GM
|----------------------------------------------
Sub GMCheck

   /if (${Spawn[gm].ID}) {
      /beep
      /echo GM Alert Ending macro
      /q
   }

/return

Enjoy!!

--Zippzipp

 

[a_troll_01]

Nice little macro.

I haven't run the Queen MM in a long while but I seem to recall having to put the beat down on the chest. Have they changed that so you can now /open it?

 

[zippzipp]

yea can /open it


--zippzipp

 

[EvenLessSpam]

Nicely written
Maybe I should level a new toon just to pass the time

Red Cented..

 

[bunklord]

Isn't this the one that a lot of epople got busted on a few months back ? I tried to run it last night, kept getting stuck and wouldn't loot the shard, anyone else try this ?

 

[zippzipp]

runs the mission a few times for me then gets stuck, gonna look at it some

--zippzipp

 

[bunklord]

I get stuck the first time ... doesn't loot the shard, almost seems like I have to maually hit the button to say " yes" I want to loot this no drop item

 

[forcecrash]

/lootnodrop never

do that before you start doing the missions an it wont make you click yes to loot

 

[zippzipp]

Yea have to have nodroploot never on, i perma have it on so forgot completely about it thx, force for pointing that out

 

[trmptbuddy]

I've been fiddling with this trying to make it work for me, but I keep having issues. My first and most annoying issue isn't with the macro though; whenever my boxes go to zone into the mission after getting the task, sometimes they just can't zone in. They're at the zone in, and even trying to click around and running in and out of the zone in spot, it just has no effect. Sometimes it lets them in after a couple of minutes, and sometimes it just never lets them zone in. It also seems unrelated to who gets the mission, which box it's running on, and whether or not a macro is running.

If anyone has had this similar problem and knows how to overcome it, please let me know.

 

[Kazandar]

I was wondering would it be possible to instead of have other chars run the mission along with me just have them drop the mission instead, or would that mess up the timer on the mission? If not it would be just as easy to do it the other way, but I know just running it on one char would be faster for me since I am having family stay in the group with me to run the mac due to lack of computers.

 

[nubetoon]

I have ran this macro for the past 24 hours, very nice. What I am running into at first was a looting issue with one the queennoklooter mac. the queennok mac calls the go ahead and the other all loot at once. it was taking for ever for the others to loot kept running into someone looting already issue. so i changed the delay before the warp when the go ahead is called. Now I am running into the issue with a sword that can be looted from the chest is looted by the first looter running the queennoklooter mac. The non of the toons running the queennoklooter mac loot a crystal. This happens like once every 5 MM's. First looter loots just the sword and nothing else. Not sure if it is SOE Fing with me... I feel pretty confident about this mac so far i start it and go to bed. It usually breaks durring the MM in instance and does not loop. I am getting 3 to 5 aa's afk with it over night.


Redcent to Zippzipp

 

[Ccomp5950]

Very nice macro, some parts still look familiar and some you've changed of course.

I'm curious why you changed the /task remove to use target instead of something like:

/for g 0 to ${Group.Members}
	/varcalc g2 ${Group.Members}-${g}
	/taskremove ${Group.Member[${g2}]}
/next g

This way if you just happen to have a friend or an alt (bazaar bot?) sitting out but not in the zone they get removed as well without any targeting issues.

And when I made the macro for this if you warped onto the wall the wisps left you alone, I see you have /fade in there. Did they nerf that?

Sub KillRemains
	/varset w 1
	/varset y 1
	:BattleLooper
	/doevents
	/varset StartHP ${Me.PctHPs}
	/if (${SpawnCount[remains npc]}==0) /return
	/target remains
	/if (${Target.Distance}>16) /Warp loc -217 -423 -60 | melee distance
	/face fast nolook
	/attack on
	/delay 2s
	/if (${SpawnCount[remains npc]}==0) /return
	/if (${StartHP}>${Me.PctHPs}) /call Warper
	/goto :BattleLooper
/return

|==============================================
| SUB:  Warper
| For those nasty wisps to leave you the fuck alone warp on to
| the wall you should get an emote but 3 seconds is enough
|==============================================
sub Warper                           
	/attack off                    
	/Warp loc -234 -423 -43  
	/delay 3s
/return

My old QueenNok.mac

 

[iridini]

How long are the leech toons sitting out of the mission for before it gets a new one. Thats always the kicker.

 

[iridini]

Sorry to ask. Does this use a mission plugin to get the mission, If so may i have a link where i can DL A current one. Tried search and got alot of spam. I looked through most of it but could not find a current version.

 

[Ccomp5950]

Just looking at the macro (not using it), it looks like the leech toons are inside the MM with you while your in it and zone out with you when you zone out to go get another mission.

Once the mission objectives are completed a hard coded 22m is in the main loop prior to a new mission.

So they are out as long as you are in Nektulos running to the mission mob and until they get a MM box.

 

[Remdian]

Isn't this the one that a lot of epople got busted on a few months back ?

You are thinking of the lavastorm MMs. it's the one that got me LOL

 

[nubetoon]

seems /fade is now nerfed, tried to run mission again after the update

 

[Learningcurve]

wow had me scared, my /fade working just fine. Might want to see which plugins your using. I believe I use rwarp and piggy along with vanguard (for a feeling of safety)

 

[nubetoon]

Im problematic, with the new mq2trek i got fade to work and not crash. Now i am unable to target the shrines. i get the error "there are no spawns matching (0-100) npc shrine at loc" i checked the locs and they are right in macro. Thanks, soe this was working perfect prior to last update.

 

[rawwar]

Im problematic, with the new mq2trek i got fade to work and not crash. Now i am unable to target the shrines. i get the error "there are no spawns matching (0-100) npc shrine at loc" i checked the locs and they are right in macro. Thanks, soe this was working perfect prior to last update.

Quick question are they more then 100 away fro you?

 

[toad32]

I'm seeing the same problem nubetoon. Did you get it figured out? I get to the point where all of my toons are zoned into Shadowed Grove (again...after looting the dust and shard) and I get spammed with "There are no spawns matching: (0-100)...messages. Then the main toon gets aggro where he stands and dies.

 

[toad32]

What plugins does this macro require?

 

[Jinx]

This one nerfed ? Seems it was working until Jan.

 

[toad32]

Has anyone used this since the latest series of (TBS) patches? I'm still facing problems. I'd love to see the code if anyone has it working regularly.