EvenLessSpam
Active member
- Joined
- Oct 31, 2005
- RedCents
- 91¢
The title says it all, if not then the commens in the code below does 
Rich (BB code):
|**
* Performer.mac - by EvenLessSpam
*
* Version: 1.0.4
*
* Changes:
* 1.0.0
* - Initial release.
*
* 1.0.1
* - Changed some delays and some coding.
*
* 1.0.2
* - Added Reponds and NPC into variables which can be used in a hotbutton.
*
* 1.0.3
* - Good/bad performance tracking.. Type "/echo stats" (without the "quotes"
* while macro is running to show who have failed and how many times.
*
* 1.0.4
* - Fixed the performance tracking.
*
* Description:
* Not much to say except that you can use this script to either help you with
* clues and hints during the performer event (/echo info, sounds) and. Or it
* can be set up to be semi-automatic or even fully automatic.
*
* It has 7 settings, which is explained in the Main Subroutine. Settings 1-3
* is merely informative, where as settings 4-7 are a mix between fully
* automatic and being informative.
*
* You can also set whether the audio trigger is a /beep or a pre-defined
* /sound (from MQ2CustomSound) with the AudioTrigger variable.
*
* Since the macro uses global (outer) variables, those variables can be
* accessed from within EverQuest, as long as MQ2 is loaded and this macro is
* running. This makes it possible to make it semi-automatic by following these
* simple steps:
* - Set this macro to either 2 or 3 (audio event, or audio event and text).
* - Create two (2) new hotbutton (social) in EverQuest.
* - Hotbutton 1: Name it "PTar" or whatever else you wish.
* - Set Line 1: /target npc "${TriggerNPC}"
* - Set Line 2: /face
* - Hotbutton 2: Name it "PSay" or whatever else you wish.
* - Set Line 1: /say ${TriggerRespond}
*
* Now whenever you hear the triggersound/beep, just press your "PTar" button,
* run to the NPC you have targeted then press your "PSay" button. Voila!
**|
#Turbo 10
#Event FailStats "[MQ2] stat#*#"
#Event Flawless "Your performance is flawless. The skeletal musician nods their head approvingly."
#Event Failed "The Performer says 'Come on, #1#, stay with us. I'm counting on you to help perform this medley. No more mistakes!'"
#Event Aelfric_0 "Aelfric recites a line of his song and beckons for you to approach him and sing the next line."
#Event Aelfric_1 "Touched tenderly."
#Event Aelfric_2 "Where will you be?"
#Event Aelfric_3 "Dreaming with me."
#Event Aelfric_4 "Please,"
#Event Aelfric_5 "everybody, hear the music."
#Event Britton_0 "Britton recites a line of her song and beckons for you to approach her and sing the next line."
#Event Britton_1 "When she and I split ways,"
#Event Britton_2 "it felt like the end of my days."
#Event Britton_3 "Until I suddenly,"
#Event Britton_4 "suddenly realized"
#Event Britton_5 "this life was better off alone."
#Event Britton_6 "Solitude was the best gift you ever gave me."
#Event Randal_0 "Randal recites a line of his song and beckons for you to approach him and sing the next line."
#Event Randal_1 "Ol' Nilipus hailed from Misty Thicket."
#Event Randal_2 "Where'er he smelled Jumjum he'd pick it."
#Event Randal_3 "The halflings grew cross"
#Event Randal_4 "when their profits were lost,"
#Event Randal_5 "screamin', 'Where is that brownie? I'll kick it!'"
#Event Seth_0 "Seth recites a line of his song and beckons for you to approach him and sing the next line."
#Event Seth_1 "Another night, in eternal darkness."
#Event Seth_2 "Time bleeds like a wound that's lost all meaning."
#Event Seth_3 "It's a long winter in the swirling chaotic void."
#Event Seth_4 "This is my torture,"
#Event Seth_5 "my pain and suffering!"
#Event Seth_6 "Pinch me, O' Death. . ."
Sub Main
|--- TriggerAction --------------------------------------------------------|
| What should be done when an event is triggered? These are the options: |
| 1 = /echo the line to say. |
| 2 = Audio event. (audio events not complete). |
| 3 = 1 + 2 |
| 4 = /target, /stick and /say (auto-mode) |
| 5 = 1 + 4 |
| 6 = 2 + 4 |
| 7 = 1 + 2 + 4 |
|--------------------------------------------------------------------------|
/declare TriggerAction int outer 3
|--- AudioTrigger ---------------------------------------------------------|
| Set to "beep" (without the "quotes") to use the default /beep command, |
| or set to the name of the sound (as you have defined it in your |
| MQ2CustomSound.ini . Note that if you don't have MQ2CustomSound loaded |
| the macro will default to /beep. |
|--------------------------------------------------------------------------|
/declare AudioTrigger string outer Error
/declare TriggerNPC string outer
/declare TriggerRespond string outer
/declare Flawless int outer 0
/declare Failed[54,2] string outer NA
/if (${TriggerAction} >= 4 && ${TriggerAction} <= 7) {
/if (!${Plugin[mq2moveutils].Name.Equal[mq2moveutils]}) /plugin MQ2MoveUtils noauto
/if (!${Plugin[mq2moveutils].Name.Equal[mq2moveutils]}) {
/echo MQ2MoveUtils isn't loaded, and couldn't load the plugin automatically.
/echo Please obtain a working copy of MQ2MoveUtils.dll and run the macro again "/macro ${Macro.Name}", or set the TriggerAction to either 1, 2 or 3.
/endmacro
}
}
:Loop
/doevents
/goto :Loop
/return
Sub PerformVerse
/if (${TriggerAction} == 1 || ${TriggerAction} == 3 || ${TriggerAction} == 5 || ${TriggerAction} == 7) /echo (${TriggerNPC}) ${TriggerRespond}
/if (${TriggerAction} == 2 || ${TriggerAction} == 3 || ${TriggerAction} == 6 || ${TriggerAction} == 7) {
/if (${Plugin[mq2customsound].Name.Equal[mq2customsound]} && ${AudioTrigger.NotEqual[beep]}) {
/sound ${AudioTrigger}
} else {
/beep
}
}
/if (${TriggerAction} >= 4 && ${TriggerAction} <= 7) {
/delay ${Math.Calc[${Math.Rand[3]+1}]}s
/target npc "${TriggerNPC}"
/stick
/delay ${Math.Calc[${Math.Rand[3]+1}]}s
/say ${TriggerRespond}
}
/return
Sub Event_Flawless
/varcalc Flawless ${Flawless}+1
/popup ${If[${Flawless}>1,Another ,]}FLAWLESS performance! (${Flawless})
/return
Sub Event_Failed(string Line, string Actor)
/declare i int local 0
/for i 1 to ${Failed.Size}
/if (${Failed[${i},1].Equal[NA]}) {
/varset Failed[${i},1] ${Actor}
/varset Failed[${i},2] 1
/goto :break
}
/if (${Failed[${i},1].Equal[${Actor}]}) {
/varcalc Failed[${i},2] ${Failed[${i},2]}+1
/goto :break
}
/next i
:break
/popup ${Failed[${i},1]} made a MISTAKE!${If[${Failed[${i},2]} > 1, (${Int[${Failed[${i},2]}]} TIMES NOW!),]}
/return
Sub Event_FailStats
/declare i int local 0
/declare Fails int local 0
/for i 1 to ${Failed.Size}
/if (${Failed[${i},1].Equal[NA]}) /goto :break
/if (${Failed[${i},2]}) {
/echo ${Failed[${i},1]} have failed ${Int[${Failed[${i},2]}]} times.
/varcalc Fails ${Fails}+${Failed[${i},2]}
}
/next i
:break
/echo Total (personal) flawless: ${Flawless}
/echo Total fails: ${Fails}
/return
Sub Event_Aelfric_1
/varset TriggerNPC Aelfric the Flautist
/varset TriggerRespond Where will you be?
/call PerformVerse
/return
Sub Event_Aelfric_2
/varset TriggerNPC Aelfric the Flautist
/varset TriggerRespond Dreaming with me
/call PerformVerse
/return
Sub Event_Aelfric_3
/varset TriggerNPC Aelfric the Flautist
/varset TriggerRespond Please,
/call PerformVerse
/return
Sub Event_Aelfric_4
/varset TriggerNPC Aelfric the Flautist
/varset TriggerRespond everybody, hear the music.
/call PerformVerse
/return
Sub Event_Aelfric_5
/varset TriggerNPC Aelfric the Flautist
/varset TriggerRespond Touched tenderly
/call PerformVerse
/return
Sub Event_Britton_1
/varset TriggerNPC Britton Harmony
/varset TriggerRespond it felt like the end of my days.
/call PerformVerse
/return
Sub Event_Britton_2
/varset TriggerNPC Britton Harmony
/varset TriggerRespond Until I suddenly,
/call PerformVerse
/return
Sub Event_Britton_3
/varset TriggerNPC Britton Harmony
/varset TriggerRespond suddenly realized
/call PerformVerse
/return
Sub Event_Britton_4
/varset TriggerNPC Britton Harmony
/varset TriggerRespond this life was better off alone.
/call PerformVerse
/return
Sub Event_Britton_5
/varset TriggerNPC Britton Harmony
/varset TriggerRespond Solitude was the best gift you ever gave me.
/call PerformVerse
/return
Sub Event_Britton_6
/varset TriggerNPC Britton Harmony
/varset TriggerRespond When she and I split ways,
/call PerformVerse
/return
Sub Event_Randal_1
/varset TriggerNPC Randal Reedsea
/varset TriggerRespond Where'er he smelled Jumjum he'd pick it.
/call PerformVerse
/return
Sub Event_Randal_2
/varset TriggerNPC Randal Reedsea
/varset TriggerRespond The halflings grew cross.
/call PerformVerse
/return
Sub Event_Randal_3
/varset TriggerNPC Randal Reedsea
/varset TriggerRespond when their profits were lost,
/call PerformVerse
/return
Sub Event_Randal_4
/varset TriggerNPC Randal Reedsea
/varset TriggerRespond screamin', where is that brownie? I'll kick it!
/call PerformVerse
/return
Sub Event_Randal_5
/varset TriggerNPC Randal Reedsea
/varset TriggerRespond Ol' Nilipus hailed from Misty Thicket.
/call PerformVerse
/return
Sub Event_Seth_1
/varset TriggerNPC Seth Kimble
/varset TriggerRespond Time bleeds like a wound that's lost all meaning.
/call PerformVerse
/return
Sub Event_Seth_2
/varset TriggerNPC Seth Kimble
/varset TriggerRespond It's a long winter in the swirling chaotic void
/call PerformVerse
/return
Sub Event_Seth_3
/varset TriggerNPC Seth Kimble
/varset TriggerRespond This is my torture,
/call PerformVerse
/return
Sub Event_Seth_4
/varset TriggerNPC Seth Kimble
/varset TriggerRespond my pain and suffering!
/call PerformVerse
/return
Sub Event_Seth_5
/varset TriggerNPC Seth Kimble
/varset TriggerRespond Pinch me, O' Death. . .
/call PerformVerse
/return
Sub Event_Seth_6
/varset TriggerNPC Seth Kimble
/varset TriggerRespond Another night, in eternal darkness.
/call PerformVerse
/return
Last edited:
