Macro Mojo

[Maskoi]

I will periodically resurrect macros from the bowels of our numerous threads and perform some mojo and juju on them.

 

[Maskoi]

Our first macro zombie is from this thread here for an alcohol tolerance skill trainer.
This macro will keep buying and drinking 1 stack of booze until you hit your desired skill level.

| alctol.mac
| Takes you to 200 Alcohol Tolerance
| Version 1.2
| Date: 04/14/2016

2 Change these 3 settings in the macro to match your needs

/varset MerchantName Bixx Bartleby
/varset Booze Brandy
/varset MaxWanted 450​

3. Stand next the alcohol vendor you chose, empty zones are best.

I was using Bixx Bartlebyin in Thurgadin​

4. Make sure you have enough plat to buy a lot of booze

5. Type /mac alctol

| alctol.mac
| Takes you to 200 Alcohol Tolerance
| Version 1.2
| Date: 04/14/2016
|
| By Bror
| Updated by Maskoi
|
| MerchantName is the name of the merchant that sells your booze
| MaxWanted is where you want to stop: Default is 450
| Booze is the alcohol you want to buy: Default is ALE
|
| Requirements:
| Must be standing next to the merchant you buying alcohol from/

#event Explode "#*#If you consumed any more drink you would explode#*#"
#event Explode "#*#You could not possibly drink any more, you would explode#*#"
#event TooDrunk "#*#You could not possibly consume more alcohol or become more intoxicated#*#"
#event SkillUp  "#*#You have become better at Alcohol Tolerance#*#"

Sub Main
	/declare OldSkill int outer ${Me.Skill[Alcohol Tolerance]}
    /declare MaxWanted int outer
    /declare MerchantName string outer i
    /declare Booze string outer
	/declare Amount		int 	outer 
	/declare DrinkCounter int outer 
	/declare MaxTime int outer

| ***********************************************
| *   Change these settings if you want.        *
| ***********************************************

        /varset MerchantName Amile Pitt
        /varset Booze Mead
        /varset MaxWanted 450


/echo Alcohol Tolerance is at ${Me.Skill[Alcohol Tolerance]}
	:Start
		/call BuyBooze
		/call Drink
		/call MaxSkill
	/goto :Start
/return

| ***********************************************
| Buy Booze                                     *
| ***********************************************
sub BuyBooze
	/if (${FindItemCount[${Booze}]} > 0) /return
	/echo Time to buy more booze
	/target ${MerchantName}
	/face
	/delay 1s
	/click right target
	/echo Waiting 5s for merchant/guildbank window to populate
    /delay 5s
	/call Buy "${Booze}" 20
	/keypress esc
	/delay 1s	
/return

| ***********************************************
| Sub Drink                      				*
| ***********************************************
sub Drink

	/for DrinkCounter 1 to 20         
		/useitem ${Booze}
		|/itemnotify pack8 rightmouseup
		/delay 1s
		/doevents
	/next DrinkCounter

/return

| ***********************************************
| sUB event too much drink                      *
| ***********************************************

Sub Event_Explode
	/echo Too full, Waiting 30 seconds.
		/delay ${WaitSober}
	/varcalc DrinkCounter ${DrinkCounter}-1
/return

| ***********************************************
| SUB event too drunk                           *
| ***********************************************

Sub Event_TooDrunk
	/declare WaitSober string local ${Math.Calc[45+${Math.Rand[70]}]}s 
	/echo Too Drunk, Waiting ${WaitSober} seconds.
	/delay ${WaitSober}
	/varcalc DrinkCounter ${DrinkCounter}-1

/return

| ***********************************************
| SUB event skillup                             *
| ***********************************************

Sub Event_SkillUp
	/varcalc MaxTime ${MaxWanted}-${Me.Skill[Alcohol Tolerance]}
	/echo Alcohol Tolerance increased >> ${Me.Skill[Alcohol Tolerance]} << 
	/delay 5
/return

| ***********************************************
| SUB Max skill check                        	*
| ***********************************************

sub MaxSkill
	/if (${Me.Skill[Alcohol Tolerance]}>=${MaxWanted}) {
		/echo Alcohol Tolerance is at or greater than ${MaxWanted}. Quiting!
        /camp
        endmacro
	}
/return

| ***********************************************
| Sub Buy                            			*
| ***********************************************

Sub Buy(string ItemToBuy, int amount)
	/declare i int local
	/echo Buying ${ItemToBuy}!
	/declare QTY int local
	/declare ListItem int local
	/varset QTY ${Math.Calc[${amount}-${FindItemCount[${ItemToBuy}]}]}
	/delay 1s
	
	/if (${FindItemCount[${ItemToBuy}]}>= ${amount}) {
		/echo Done!
		/return
	}   
	/varset ListItem ${Window[MerchantWnd].Child[ItemList].List[=${ItemToBuy},2]}
	/if (!${ListItem}) {
		/echo couldn't find ${ItemToBuy}
		/return
	} else {
		/notify MerchantWnd ItemList listselect ${ListItem}
		/delay 1s       
	} 
	/echo Buying ${ItemToBuy} Till I get ${amount} 
	:Loop
	/if (${QTY}>1) {
		/if (${QTY}>19) {
			/Shiftkey /notify merchantwnd MW_buy_Button leftmouseup
			/delay 30s ${FindItemCount[${ItemToBuy}]}>=${amount}
			/echo ${FindItemCount[${ItemToBuy}]} ${ItemToBuy} in inventory
			/varset QTY ${Math.Calc[${amount}-${FindItemCount[${ItemToBuy}]}]} 
			/delay 3
			/if (${QTY}<=0) /return
			/goto :Loop
		}
		/if (${QTY}>0 && ${QTY}<20) {
		/for i 1 to ${QTY}
		/notify merchantwnd MW_buy_Button leftmouseup
		/echo Buying ${ItemToBuy} ${i} of ${QTY}
		/varcalc QTY ${amount}-${FindItemCount[${ItemToBuy}]}
		/echo ${QTY}
		/if (${QTY}<=0) /return
		/next i
		}
	}
/return

 

[Maskoi]

A small macro written on request to summon and click for item with a mages Cauldron of Endless Goods while afk

| Maskoi's Super Cool Cauldron Summoning Clicking Macro v.1 09.25.2012
| This macro will cast a magician's Cauldron of Endless Goods and click on it for the items while afk.

Sub Main
    /plugin mq2cast
    :mainloop
        /if (${Cursor.ID}) /autoinventory
        /delay 10
        /if (${Cursor.ID}) /goto :mainloop
        /if (${Cast.Ready[Cauldron of Endless Goods]}) { 
            /casting "Cauldron of Endless Goods" -maxtries|2
            /delay 10s
            /goto :mainloop
        }
        /if (${FindItemCount[Cauldron's Endless Summoning]}) /itemnotify ${FindItem[Cauldron's Endless Summoning].InvSlot} rightmouseup 
        /delay 10s
    /goto :mainloop
/return

 

[Maskoi]

Quick macro I wrote to automate buying and opening multiple bags of a currency from the loyal vendor

Loyalty.mac by Maskoi 10/06/2012
A quick macro to buy and open various currencies from the Loyalty Vendor in PoK
Change ItemToBuy to the currency you want as you see it on the vendor
Change AmoutToBuy to the number of bags you want to buy
Stand near the vendor and type /mac loyalty

| loyalty.mac by Maskoi 10/06/2012
| A quick macro to buy and open various currencies from the Loyalty Vendor in PoK
| Change ItemToBuy to the currency you want as you see it on the vendor 
| Change AmoutToBuy to the number of bags you want to buy
| Stand near the vendor and type /mac loyalty

Sub Main

/declare ItemToBuy      string  outer   Bag of Radiant Crystals
/declare AmoutToBuy     int     outer   1

/declare ListItem       string  outer
/declare i              int     outer  

    /echo Loyalty.mac by Maskoi
    /echo I am buying ${AmoutToBuy} of ${ItemToBuy}
    /tar alerynril npc
    /delay 10 
    /nomodkey /click right target
    /delay 20

    /for i 1 to ${AmoutToBuy}
        /if (!${Window[ConfirmationDialogBox].Open}) {
            /nomodkey /click right target
            /delay 20
        }
        /varset ListItem ${Window[NewPointMerchantWnd].Child[NewPointMerchant_ItemList].List[=${ItemToBuy}]}
        /if (!${ListItem}) {
            /echo couldn't find ${ItemToBuy}
            /return
        } else {
            /notify NewPointMerchantWnd NewPointMerchant_ItemList listselect ${ListItem}
            /delay 5       
        }
        /notify NewPointMerchantWnd NewPointMerchant_PurchaseButton leftmouseup
        /delay 10
        /if (${Window[ConfirmationDialogBox].Open})  /nomodkey /notify ConfirmationDialogBox Yes_Button leftmouseup
        /delay 10
        /if (${FindItemCount[${ItemToBuy}]}>0) /shift /itemnotify ${FindItem[${ItemToBuy}].InvSlot} rightmouseup
        /delay 10
        /autoinv
    /next i

/return