Request - Into the Hills - Click to Campfire

[kcrobk]

I have been running this macro successfully for several weeks now and it is amazing. I've made a few tweaks and added some downshits and mq2rez so whenever my bard dies at camp and is rezzed he reloads the macro and gets right back to work.

The problem is when he doesn't die in camp, when he is out in the instance pulling. This only happens every 4-5 runs, but is my roadblock to complete afk'ness (besides an occasional crash on loading into the instance).

I've got my bard dropping a campfire successfully every instance and my SK will attempt to summon his corpse if he dies. The problem is I cannot figure out how to get my bard to automatically click his fellowship token after he dies. If I do it manually everything works beautifully. I've tried adding a subroutine based off the KISS sub CampfireBack, but I'm just learning how all of this works and I can't figure out how to get the macro to wait until my bard respawns and then execute the code to click the token. If anyone has any ideas I would be infinitely grateful!

Rob

 

[Infinite Monkeys]

I would think you would want to do a zone check, I'm assuming you're bound in PoK or guild lobby, and if he is that zone for more than a couple minutes to then click the token. You might be able to adapt mq2autocamp to work for that, it starts a timer when you die and if you're not rezed in X time it'll camp you out, just need to get it to hit the token instead of camping.

 

[geEQ]

i posted this downshit for my bard/puller someplace else. The danger is if you are chilling in Guild lobby or PoK, it will try to click to campfire, so you have to turn it off when you are not running the dead2.mac.

downflag2=1
downshit2=/if (${Select[${Zone.ShortName},guildlobby,poknowledge]} && (!${Me.Buff[Revival Sickness].ID} && ${CampZone} != ${Zone.ID}) && (${Me.Fellowship.Campfire}) && (!${Me.Moving}) && (${FindItem[Fellowship Registration Insignia].TimerReady} == 0)) /multiline ; /squelch ; /nomodkey ; /itemnotify ${FindItem[Fellowship Registration Insignia].InvSlot} rightmouseup

I think the command is /downflag2 off. I may be wrong there.

 

[g_kinz]

Check in kissassist macro. It's able to drop camps and click the item to gate back so I'm sure the line of code you need may be in there. Wish I was better at coding and could help ya

 

[william12]

I have been running this macro successfully for several weeks now and it is amazing. I've made a few tweaks and added some downshits and mq2rez so whenever my bard dies at camp and is rezzed he reloads the macro and gets right back to work.

The problem is when he doesn't die in camp, when he is out in the instance pulling. This only happens every 4-5 runs, but is my roadblock to complete afk'ness (besides an occasional crash on loading into the instance).

I've got my bard dropping a campfire successfully every instance and my SK will attempt to summon his corpse if he dies. The problem is I cannot figure out how to get my bard to automatically click his fellowship token after he dies. If I do it manually everything works beautifully. I've tried adding a subroutine based off the KISS sub CampfireBack, but I'm just learning how all of this works and I can't figure out how to get the macro to wait until my bard respawns and then execute the code to click the token. If anyone has any ideas I would be infinitely grateful!

Rob

You have to use /if (${Me.Dead}) /dothis

The code you want is for it to click the button to go to your bind and not rez. After that you put a delay (to give you time to zone). The code to click the campfire can be done using that down shit or if you have mq2cast loaded /casting "Fellowship Registration Insignia"

Should work. or /useitem "Fellowship Registration Insignia" pretty sure both work just #include spell_routines.inc in the dead2.mac If you do all of this from the dead2.mac you dont have to worry about it when not running the macro. Downshit is nice but i would not go that route.

I tested /casting "Fellowship Registration Insignia" in game and it works. (i have mq2cast) loaded as a plugin it will not work without that.

From wait4rez.inc

/if (${Window[RespawnWnd].Open}) {
/nomodkey /notify RespawnWnd RW_OptionsList listselect 2
/delay 1s
/nomodkey /notify RespawnWnd RW_SelectButton leftmouseup
/delay 2s
}

You want it to select option 1

/nomodkey /notify RespawnWnd RW_OptionsList listselect 1

So something like this

/if (${Me.Dead})  {
/if (${Window[RespawnWnd].Open}) {
    /nomodkey /notify RespawnWnd RW_OptionsList listselect 1 
    /delay 1s
    /nomodkey /notify RespawnWnd RW_SelectButton leftmouseup
    /delay 2s 
 }
// you need time to zone right ?
/delay 180s
/if (${Zone.ID}==344) /casting "Fellowship Registration Insignia"
/delay 180s
/mac dead2
}

344 = Guild Lobby.

This would respawn at your bind click campfire and restart the macro.

What I would do is bind my bard at the npc and just have him zone in that way. It would skip the entire campfire issue.

 

[ctaylor22]

Edit Kissassist and do a find on "sub campfireback"(without the quotes). The code you are looking for is in there.

 

[william12]

|-----------------------------------------------------------------------------
| SUB: Campfire back to camp
| ----------------------------------------------------------------------------
    Sub CampfireBack
        /if (!${ClickBacktoCamp} || ${CampfireClickTimer} || ${Me.Hovering}) /return
        /varset CampfireClickTimer 1m
        | Am I Dead?
        /if (${Me.Buff[Revival Sickness].ID} && ${CampZone} != ${Zone.ID}) /varset IAmDead 1
        /if (${IAmDead}) {
            | Does Campfire Exist?
            /if (!${Me.Fellowship.Campfire}) {
                /echo There is no campfire up.
                /return
            }
            | Am I & the campfire in the same zone?
            /if (${Select[${Me.Fellowship.CampfireZone},${Zone.Name}]}) {
                /echo I am confused because I'm in the same zone as my campfire. I need an adult.
                /return
            }
            /if (${FindItem[Fellowship Registration Insignia].TimerReady} == 0) {
                /echo Time to get back to work. Clicking Fellowship Insignia.
                /delay 15
                /squelch /nomodkey /itemnotify ${FindItem[Fellowship Registration Insignia].InvSlot} rightmouseup
            }
        }
    /return

So he doesnt have to look

 

[kcrobk]

Awesome! I added the downshit really fast and have it up. I will try a more permanent solution in the macro when I get some time in a couple of days. Thanks so much for your replies, we have such an awesome community here!

 

[william12]

Pretty much made this full AFK. Using kiss for a campfire doesn't work because kiss wont destroy the campfire because it thinks its in the same zone as you but its not.

So I have kiss make the campfire and I have dead2.mac destroy it after every mission. I added

Sub destroycampfire
        /windowstate FellowshipWnd open
        /delay 5
        /nomodkey /notify FellowshipWnd FP_Subwindows tabselect 2
            /nomodkey /notify FellowshipWnd FP_DestroyCampsite leftmouseup
            /delay 5s ${Window[ConfirmationDialogBox].Open}
            /if (${Window[ConfirmationDialogBox].Open}) {
                /nomodkey /notify ConfirmationDialogBox Yes_Button leftmouseup
            }
            /delay 5s !${Me.Fellowship.Campfire}
        }
/return

and changed Sub ReturnToGribble to

Sub ReturnToGribble
  /delay 90s ${Me.CombatState.NotEqual[COMBAT]}
  /delay 180s !${Me.XTarget}||${Me.XTarget[1].PctHPs}>99 
  /delay 15s
  /if (${Me.Fellowship.Campfire}) /call destroycampfire
  /beep
  /bca //end
  | My Tank automatically aggro's things with in range - just turning him off to make sure he doesn't do anything silly :)
  /bct ${TankName} //end
  /delay 2s
  /bca //moveto loc 436.9 -282.3
  /bca //tar Gribble
  /tar Gribble
  /delay 5s
  /delay 20s ${SpawnCount[PC]}==${SpawnCount[PC radius 40]}
  /keypress H
  /delay 5s
  /bca //say back
  /kickplayers task
  /delay 5s ${Window[ConfirmationDialogBox].Open}
  /nomodkey /notify ConfirmationDialogBox Yes_Button leftmouseup
  /delay 10s
  /say back
  /delay 120s ${Zone.ShortName.Equal[deadhills]}
  /delay 30s
  /varset CampNum 1
  /varset ReturnGribble 0
  /mac dead2
/return

Only thing you need to do is add a downshit to your SK to summon corpse of the bard after he zones in.

I also added this to the end of the macro

Sub Dead
/if (${Me.Dead})  {
/if (${Window[RespawnWnd].Open}) {
    /nomodkey /notify RespawnWnd RW_OptionsList listselect 1 
    /delay 1s
    /nomodkey /notify RespawnWnd RW_SelectButton leftmouseup
    /delay 2s 
 }
/delay 180s
/if (${Me.Fellowship.Campfire} && ${Zone.ID}==344) /casting "Fellowship Registration Insignia"
/delay 180s
/mac dead2
}
/return

And put in checks for if im dead. Find :killmob and change it to

:killmob
  /if (${Me.Dead}) /call Dead

So far its working flawlessly.

I also changed all spots where it cast selo's to

    /if (!${Me.Buff[Selo's Sonata].ID}) /alt activate 3704

This will slow down how fast it consumes mana. My bard would be low on mana after 2-3 missions. The only negative is once in awhile selo's will fade mid pull. I was thinking i could just put selos in a downshit.

 

[ctaylor22]

I also changed all spots where it cast selo's to


Code:
/if (!${Me.Buff[Selo's Sonata].ID}) /alt activate 3704This will slow down how fast it consumes mana. My bard would be low on mana after 2-3 missions. The only negative is once in awhile selo's will fade mid pull. I was thinking i could just put selos in a downshit.

I don't know much about bards, but I believe they can cast while moving. There are a few things you could try with Selo's fading mid pull. If the bard can cast selo's while moving, you could build in an event to watch for when it fades, and just recast. Another way would be to check the duration left on the buff ${Me.Buff[Selo's Sonata].Duration} before leaving camp, and recast if you think it will fade durring the pull. Just remember Duration is the number of Ticks left till it fades.

 

[william12]

I don't know much about bards, but I believe they can cast while moving. There are a few things you could try with Selo's fading mid pull. If the bard can cast selo's while moving, you could build in an event to watch for when it fades, and just recast. Another way would be to check the duration left on the buff ${Me.Buff[Selo's Sonata].Duration} before leaving camp, and recast if you think it will fade durring the pull. Just remember Duration is the number of Ticks left till it fades.

10 is under 1m. This is what i changed them all to.

/if (!${Me.Buff[Selo's Sonata].ID}) /alt activate 3704
/if (${Me.Buff[Selo's Sonata].ID} && ${Me.Buff[Selo's Sonata].Duration}<10) /alt activate 3704

 

[geEQ]

A simple solution is to /sit before getting the task and /sit while waiting for readies. This may help get the mana full at the start of each HA.

 

[william12]

A simple solution is to /sit before getting the task and /sit while waiting for readies. This may help get the mana full at the start of each HA.

There is code in the macro to med if you get too low. You could do /sit though.

 

[geEQ]

One problem I have noticed during afk sessions is the named will be looped on a never ending pull because the tank has himself targeted. I noticed one such loop going for about 45 minutes before I noticed it. to help that out, I added the following line after the broadcast about Fading Bloodsucker:

/bc Fading Bloodsucker as he is with an Add - ${Me.XTarget}
/bct ${TankName} //keypress esc

Maybe other folks can continue adding their own tweaks in this post as well.

 

[william12]

One problem I have noticed during afk sessions is the named will be looped on a never ending pull because the tank has himself targeted. I noticed one such loop going for about 45 minutes before I noticed it. to help that out, I added the following line after the broadcast about Fading Bloodsucker:

/bc Fading Bloodsucker as he is with an Add - ${Me.XTarget}
/bct ${TankName} //keypress esc

Maybe other folks can continue adding their own tweaks in this post as well.

Ya I noticed that as well. I'm bored I added a createcampfire sub so kiss doesnt have to create the campfire the bard will create and destroy it all himself now.

 

[geEQ]

Yeah, I do it after the clickie buffs section.

| Load up some clickie buffs on toons.
  /bcaa //useitem 3
  /delay 6
  /bcaa //useitem 6
  /delay 6
  /bcaa //useitem 20
  /delay 6
  /bcaa //useitem 11
  /delay 6
  /bcaa //useitem 15
  /delay 6
  
|  Set Campfire
	/windowstate FellowshipWnd open
    /delay 5
    /nomodkey /notify FellowshipWnd FP_Subwindows tabselect 2
    /nomodkey /notify FellowshipWnd FP_DestroyCampsite leftmouseup
        /delay 5s
        /if (${Window[ConfirmationDialogBox].Open}) {
                /nomodkey /notify ConfirmationDialogBox Yes_Button leftmouseup
        }
         /delay 5s
    /delay 1s
    /nomodkey /notify FellowshipWnd FP_RefreshList leftmouseup
    /delay 1s        
    /nomodkey /notify FellowshipWnd FP_CampsiteKitList listselect 1
    /delay 1s
    /nomodkey /notify FellowshipWnd FP_CreateCampsite leftmouseup
    /delay 5s
    /windowstate FellowshipWnd close  
  /return

 

[william12]

I did it before it tells the tank to move to loc.