Consider.mac

[EvenLessSpam]

This is untested since I just put it together, so use at your own risk (I'm double posting this, both here and in requests section).

The reason I've chosen to use 3 Alert lists is that those lists will remain after running this macro, and you'll easily be able to do a "/mapshow npc alert 5" or similar and quickly have all spawns that can see you shown on the map.

Edit: I just noticed I named the Consider sub wrong Fixed.

|**
 * Consider.mac
 *  by EvenLessSpam
**|

#Event Consider "#1# scowls at you, ready to attack -- #2#"
#Event Consider "#1# glares at you threateningly -- #2#"
#Event Consider "#1# glowers at you dubiously -- #2#"
#Event Consider "#1# looks your way apprehensively -- #2#"
#Event Consider "#1# regards you indifferently -- #2#"
#Event Consider "#1# judges you amiably -- #2#"
#Event Consider "#1# kindly considers you -- #2#"
#Event Consider "#1# looks upon you warmly -- #2#"
#Event Consider "#1# regards you as an ally -- #2#"

Sub Main(int Radius)
    /declare Considered     bool    outer   false
    /declare ConAlert       int     outer   4
    /declare SeeAlert       int     outer   5
    /declare KoSAlert       int     outer   6
    /declare SpawnSearch    string  local   npc${If[${Defined[Radius]}, radius ${Radius},]} noalert ${ConAlert}
    /alert clear ${ConAlert}
    /alert clear ${SeeAlert}
    /alert clear ${KoSAlert}
    :Loop
        :WaitTarget
            /squelch target ${SpawnSearch}
            /delay 1
        /if (!${Target.ID}) /goto :WaitTarget
        /varset Considered false
        /consider
        :WaitConsider
            /delay 1
            /doevents Consider
        /if (!${Considered}) /goto :WaitConsider
        /delay 5
    /if (${SpawnCount[${SpawnSearch}]}) /goto :Loop
/return

Sub Event_Consider(string Line, string NPC, string Difficulty)
    | Gray          You could probably win this fight.
    | Green?        You would probably win this fight..it's not certain though.
    | Light blue    looks kind of dangerous.
    | Dark blue     it appears to be quite formidable.
    |               he appears to be quite formidable.
    |               she appears to be quite formidable.
    | White         looks like quite a gamble.
    | Red           what would you like your tombstone to say?
    /alert add ${ConAlert} npc id ${Target.ID}
    /if (!${Line.Find[regards you indifferently]}) {
        /alert add ${SeeAlert} npc id ${Target.ID}
        /echo ${Target.CleanName} (${Target.ID}) can see you.
        /popup ${Target.CleanName} (${Target.ID}) can see you.
        /if (${Line.Find[scowls at you, ready to attack]}) {
            /alert add ${KoSAlert} npc id ${Target.ID}
            /echo ${Target.CleanName} (${Target.ID}) is KoS!
            /popup ${Target.CleanName} (${Target.ID}) is KoS!
        }
    }
    /varset Considered true
/return

 

[someoneorsomething]

Nice ELS I like how you get it to not recon. question tho if the mob is named the same will it not retarget? Im thinking that each spawn should have a _01, _02 ect. And has any tried it yet. want to see the lag produced lol.

 

[Ccomp5950]

It uses the Spawn.ID name doesn't matter in that case.