Combat Skills, revised

[hoosierbilly]

I have revised my macro, well, actually reworte it from scratch.
It should use basic combat skills while attacking and follow the mob if it runs.
It also helps as a trainer for lower level monk skills.
Let me know if any problems or suggestions for improvment.
I hope ya'll enjoy the macro.

|
|
|CombatSkills.mac by Hoosierbilly  
| 30 July 2007
|
|
|Purpose: To automatically use basic combat skills, ie: kick, taunt, bash, disarm...
|	Will attack the mob when it is within close range, use basic conbat skills,
|	use mend ability if health falls below 60% (if availible),
|	use feign death ability if health falls below 20% (if availible),
|	give pop-up warning if health falls below 20%.	
|
|	Warriors will use the provoke discipline one time when engaging mob.
|
|	It will also follow the mob when it tries to run away due to low health.
|
|
|Secondary Purpose: Will check and train special monk skills that are not maxed.
|
|
|Useage: Pull target to camp and activate macro when ready to attack.
|
|
|Recommendation: Create a social with the command < /mac combatskills.mac >
|	Make the social a hotbutton to use when ready to attack.
|	Wouls also make an /end button, just in case.
|
|Note: The combat abilities must be selected on your abilities "ctrl A" or combat "ctrl C" page for this to work.
|
|
|


Sub Main

	/echo Combat Skills macro is active.
	/if (!${Target.ID}) /call endmacro
	/if (${Target.ID}==${Me.ID}) /call endmacro
	/if (${Target.Distance}>50) /call wait

	/if (!${Me.Moving}) {
		/if (${Target.Distance}>15) /call MoveToTarget
		/if (${Target.Distance}<5) /call MoveBack
	}

	/if (${Me.Class.ID}==1) {
		/if (${Me.Level}>62) /disc incite
		/if (${Me.Level}>51) /disc bellow
		/if (${Me.Level}>19) /disc provoke
		/if (${Me.AbilityReady[taunt]}) /doability taunt
	}

	/if (${Target.ID}) /face nolook
	/attack on

:Loop

	/if (${Me.Class.ID}==7) /call Monk

| Monks should enter their perfered combat ability on the next line
	/if (${Me.AbilityReady[Dragon Punch]}) /doability "Dragon Punch"

	/if (${Me.AbilityReady[taunt]}) /doability taunt
	/delay 1
	/if (${Me.AbilityReady[Kick]}) /doability Kick
	/delay 1
	/if (${Me.AbilityReady[Bash]}) /doability Bash
	/delay 1
	/if (${Me.AbilityReady[Backstab]}) /doability Backstab
	/delay 1
	/if (${Me.AbilityReady[Disarm]}) /doability Disarm
	/delay 1

	/if (${Me.PctHPs}<=20) {
		/echo You are near dead - TAKE ACTION NOW!
		/popup You are near dead - TAKE ACTION NOW!
	}

	/if (${Target.Distance}>50) /call wait

	/if (!${Me.Moving}) {
		/if (${Target.ID}) /face nolook
		/if (${Target.Distance}>15) /call MoveToTarget
		/if (${Target.Distance}<5) /call MoveBack
	} 

/goto :Loop
/return
/endmacro


Sub Monk

	/if (${Me.PctHPs}<=60) /doability Mend
	/if (${Me.PctHPs}<=20) {
		/doability "Feign Death"
		/Popup You have Feign Dead due to low health...
		/endmacro
	}

	/if (${Me.Skill[Mend]}<${Skill[Mend].SkillCap}) {
	/doability Mend
	}

	/if (${Me.Skill[Flying Kick]}<${Skill[Flying Kick].SkillCap}) {
	/doability "Flying Kick"
	/return
	}

	/if (${Me.Skill[Dragon Punch]}<${Skill[Dragon Punch].SkillCap}) {
	/doability "Dragon Punch"
	/return
	}

	/if (${Me.Skill[Eagle Strike]}<${Skill[Eagle Strike].SkillCap}) {
	/doability "Eagle Strike"
	/return
	}

	/if (${Me.Skill[Tiger Claw]}<${Skill[Tiger Claw].SkillCap}) {
	/doability "Tigar Claw"
	/return
	}

	/if (${Me.Skill[Round Kick]}<${Skill[Round Kick].SkillCap}) {
	/doability "Round Kick"
	/return
	}

/return


Sub wait

:wait
	/if (${Target.Distance}>50) {
	/if (!${Target.ID}) /call endmacro
	/if (${Target.ID}==${Me.ID}) /call endmacro
	/delay 5
	/goto :wait
	}
/return

Sub MoveToTarget

:KeepMoving 
	/if (!${Target.ID}) /Call Endmacro
	/if (${Target.ID}) /face nolook
	/delay 1 
	/keypress forward hold 
	/if (${Target.Distance}>15) /goto :KeepMoving 
|Stop Moving 
	/keypress forward 
	/return 

Sub MoveBack

:Backup
	/if (!${Target.ID}) /Call Endmacro
	/if (${Target.ID}) /face nolook
	/keypress back hold
	/delay 1
	/if (${Target.Distance}<5) /goto :backup
|Stop Moving
	/keypress back
	/return

Sub endmacro

	/echo You have an invalid target - Macro ending
	/if (${Me.Combat}) /attack off
	/squelch /endmacro