Clicky Code Snippet for Your Macro

[Maskoi]

To add this code to your macro to watch and cast clickys buffs just cut and paste the following into your macro at the appropriate places.

Add this near the top of your macro above the Sub Main. You find can find spell_routines.inc in my clicky macro post here

#include spell_routines.inc

Add this to your variable declares area

|----------------------------------------------------------------------------
| SUB: Clicky Declares
|----------------------------------------------------------------------------

    /declare ClickyItemUse         int outer 1
    /declare ClickyItem[8]      string outer
    /varset ClickyItem[1]        Phosphorescent Rapier of Dazzling Light
    /varset ClickyItem[2]        Cloak of Moss
    /varset ClickyItem[3]        Intruderbane Hook
    /varset ClickyItem[4]        Scorched Silk Belt
    /varset ClickyItem[5]        Lute of the Howler
    /varset ClickyItem[6]        Forgeflame Earring
    /varset ClickyItem[7]        Vermilionite Underbead
    /varset ClickyItem[8]        NULL
    /declare MobRadius            int outer 25

Add this to the spot your want your macro to check clickys

    /call Check_Clicky

Add the subroutine to the very bottom of your macro

|----------------------------------------------------------------------------
| SUB: Check_Clicky 
|----------------------------------------------------------------------------
Sub Check_Clicky
/declare i int local
/declare TwistOff int local
/if (!${ClickyItemUse}) /return
/if (${Me.Pet.CleanName.Equal[${Me.Name}`s familiar]}) /pet get lost
/for i 1 to ${ClickyItem.Size}
        /if (${FindItemCount[${ClickyItem[${i}]}]}<=0) /next i
        /if (${FindItem[${ClickyItem[${i}]}].Spell.Stacks[0]} && !${Me.Buff[${FindItem[${ClickyItem[${i}]}].Spell}].ID} && ${NearestSpawn[NPC].Distance}>=${MobRadius}) {
            | - Turn off bard twisting
            /if (${Me.Class.ShortName.Equal[BRD]} && ${Twist}) /multiline ; /squelch /twist off ; /varset TwistOff 1
            /target myself
            /delay 3
            /call Cast "${ClickyItem[${i}]}" item
            /echo Clicking ${ClickyItem[${i}]}
        }
    /next i
    | - Turn on bard twisting again
    /if (${TwistOff}) /squelch /twist start
/return