Bind Wound for SHM - No Down Time

[Incognito]

|** ****************************************************************************** **
Bind Wound Macro by Incognito 2016. This can be modified to use whatever unresistable
Skill/AA/Spell you may have. I have used the SHM AA Cannibalization. I wrote this macro
because using an old one I found used direct damage to decrease HP to facilitate
binding. I found however that I resisted my own DD with such brevity that I would
innately recover the dmg done from whenever the last successful cast was. I wanted
to incorporate the unresistable canni line, and I wanted to decrease HP inside the 
bind loop. I found that by using canni I only lost a couple of seconds of binding
and I never recovered enough HP to have to stop and DD down again. The result was
triple if not quadriple the skillups. I went from 20 or 30 skillups a night to over
100. I also wanted to incorporate an echo of skillups to avoid digging through old
scroll or having to manually check skills. Finally, I despise GoTo statements; 
friends don't let friends use GoTo.
** ****************************************************************************** **|

#include Spell_Routines.inc


#event Ran_Out	"You can't bandage without bandages,#*#"
#Event SkillUp  "You have become better at Bind,#*#"


Sub Main
   /declare DebugFlag int outer 0 |Set to > 0 (aka 1) to send routine alerts to MQWin

   /while (${Me.Skill[Bind Wound]} < ${Me.SkillCap[Bind Wound]}) {
	/if (${DebugFlag} > 0) /echo Main Loop
	/if (${Me.PctMana}<90) /call MedUp |Might have run out of mana DDing yourself, especially if you beau·coup resist
	/if (${Me.PctHPs}>50) /call LowerHP |DD down to a decent bind range
	/call BindYourself |I suppose you could bind someone/somethign else *shrug* you write it
   }

   :OnExit | **This label is internal to MQ2, no flaming, no see no GoTo do ya?**
	|This only fires if you max your skill, by flowing out of above loop
	|I've yet to see fire with a manual (or automated from inside) /end or /endmac
	/echo Macro Ended - Your Bind Wound Skill is: ${Me.Skill[Bind Wound]} out of ${Me.SkillCap[Bind Wound]}

/return

| ** Only subroutines reside below, main flow resides above

Sub MedUp
   /if (${DebugFlag} > 0) /echo Med Sub |SHM using canni variance shouldn't be low on mana
   /if (${Me.Mount.ID}) /dismount |mounts regen HP and we are trying to keep our HP down for binding
   /if (!${Me.Sitting} && ${Me.PctMana}<90) /sit
   /while (${Me.PctMana}<90) {
	
	|Let the med happen mon - could always check to see if you have clarity pot and effect is on...
	/doevents
	/delay 5s
   }
   /stand |stand regardless, it doesn't toggle like /sit does

/return

Sub LowerHP
   |Modify this for your own class skills and abilities
   |SHM should hover between approx 30% and 50% HP throughout macro
   /if (${DebugFlag} > 0) /echo Lowing HP
   /tar myself
   /while (${Me.PctHPs}>50) {
	|SHM eat yourself!
	/if (${Me.AltAbilityReady[Cannibalization]}) {
		|Due to timers, this will only fire once this iteration
		/alt act 47
		/delay 5s
	}
	/if (${Me.PctHPs}>30) {
		/call cast "Ancestral Hearkening Rk. II"
		/delay 5s 
	}
	/doevents
	/delay 5s
	|AA hastening and quickening shortens Ancestral reuse - otherwise another iteration will fire it
   }

/return

Sub BindYourself
   /if (${DebugFlag} > 0) /echo Binding
   /tar myself
   /doability "Bind Wound"
   /doevents
   /delay 15s
/return

Sub Event_Ran_Out
	/Echo You have run out of bandages, go buy more!
	/end
/return

Sub Event_SkillUp
	|Could do a popup, but they fade quickly and this is AFK country
	/echo Your Bind Wound Skill is now: (${Me.Skill[Bind Wound]})
/return