Request - A marco to give coins to a NPC

[Sinn69]

anyone have a macro to give 3 pp coins to a NPC over and over to say 1500 pp is given?

 

[playj]

Here's a snippet from a macro that I use to give ALL my plat and gold to another PC.

You would have to loop this and insert Platinum selection (otherwise it would give ALL plat) and delete gold section to suit for your purposes

	/target InsertNameOFwhatever
	/delay 25 ${Target.ID}
	/if (!${Window[InventoryWindow]}) /keypress inventory
	/delay 25 ${Window[InventoryWindow]}
	
	/notify InventoryWindow IW_Money0 leftmouseup
	/delay 25 ${Window[QuantityWnd]}
	/notify QuantityWnd QTYW_Accept_Button leftmouseup
	/delay 25 !${Window[QuantityWnd]}
	/click left target
	/delay 25 ${Window[GiveWnd]}
	/notify GiveWnd GVW_Give_Button leftmouseup
	/delay 45 ${Window[TradeWnd]}
	/echo ooh trade up now
	/notify InventoryWindow IW_Money1 leftmouseup
	/delay 25 ${Window[QuantityWnd]}
	/notify QuantityWnd QTYW_Accept_Button leftmouseup
	/delay 25 !${Window[QuantityWnd]}
	/click left target
	/delay 25
	/notify TradeWnd TRDW_Trade_Button leftmouseup

To write such macros you have to spend some time hunting around with /windows open command
Then you have to make sense of /window inventorywindow which has 442 child windows...

 

[1everdude]

I've had this in my macros folder for awhile, don't honestly remember where it came from but it should work for your purpose. Just run /mac handin "pp" 3

|------------------------------------------------------------
| Name: Handin.mac
|------------------------------------------------------------
| Author: TheWarden (helped by DKAA)
|------------------------------------------------------------
| Example Uses:
|  /macro handin.mac "gp" 2 destroy
|   - Hands in 2 gold and destroys items you get.
|
|  /macro handin.mac "Batwings" 3
|   - Hands in 3 Batwings and keeps the items you get.
|------------------------------------------------------------

#Event TooFar "#*#You are too far away from #*#"
#Event NotWanted "#*#I have no need for this #*#"
#Event NoItems "#*#Invalid item slot #*#"
#Event NoItems "#*#Could not send notification to #*#"


Sub Main(string TheItem, int TheAmount, string DoDestroy)

|------------------------------------------------------------
| Declaring some stuff.
|------------------------------------------------------------
  /declare Loopcount int local
  /declare Timeout timer local


|------------------------------------------------------------
| A bunch of /if statements to start us out.
|------------------------------------------------------------
  /if (!${Defined[TheItem]} || !${Defined[TheAmount]}) {
    /call Syntax
  }
  /if (${TheAmount} == 0) {
    /echo Rethink the amount, buddy. Ending macro.
    /endmacro
  }

:Start
  /if (!${Target.ID}) {
    /echo You have no target. Ending macro.
    /endmacro
  }
  /if (!${Window[InventoryWindow]}) {
    /keypress inventory
    /delay 5
  }
  /if (${Cursor.ID}) {
    /autoinv
    /delay 5
  }

|------------------------------------------------------------
| Determining the item.
|------------------------------------------------------------
 /for Loopcount 1 to ${TheAmount}
  /if (${TheItem.Equal[pp]}) {
    /if (${Me.Platinum} < ${TheAmount}) {
     /echo Not enough plat. Ending macro.
     /keypress esc
     /keypress esc
     /endmacro
    }
    /ctrl /notify InventoryWindow IW_Money0 leftmouseup
  } else /if (${TheItem.Equal[gp]}) {
    /if (${Me.Gold} < ${TheAmount}) {
     /echo Not enough gold. Ending macro.
     /keypress esc
     /keypress esc
     /endmacro
    }
    /ctrl /notify InventoryWindow IW_Money1 leftmouseup
  } else /if (${TheItem.Equal[sp]}) {
    /if (${Me.Silver} < ${TheAmount}) {
     /echo Not enough silver. Ending macro.
     /keypress esc
     /keypress esc
     /endmacro
    }
    /ctrl /notify InventoryWindow IW_Money2 leftmouseup
  } else /if (${TheItem.Equal[cp]}) {
    /if (${Me.Copper} < ${TheAmount}) {
     /echo Not enough copper. Ending macro.
     /keypress esc
     /keypress esc
     /endmacro
    }
    /ctrl /notify InventoryWindow IW_Money3 leftmouseup
  } else {
    /ctrl /itemnotify ${FindItem[${TheItem}].InvSlot} leftmouseup
  }
  /doevents
  /delay 5
  /click left target
  /doevents

:GiveWnd
  /if (!${Window[GiveWnd].Open}) {
    /goto :GiveWnd
  }
  /next Loopcount
  /notify GiveWnd GVW_Give_Button leftmouseup
  /doevents
  /delay 5

:ClearCursor
  /if (${Cursor.ID}) {
    /if (${Defined[DoDestroy]} && ${DoDestroy.Equal[destroy]}) {
     /destroy
    } else {
     /autoinv
    } 
  /delay 5
  /goto :ClearCursor
  }
  /goto :Start

:Lag
  /echo Macro lagged out. Ending macro.
  /endmacro


|------------------------------------------------------------
| Sub: Syntax
|------------------------------------------------------------
Sub Syntax
  /echo You fucked up! Check the macro instructions. Ending macro.
  /endmacro

|------------------------------------------------------------
| Event: NotWanted
|------------------------------------------------------------
Sub Event_TooFar
  /echo NPC is too far away, get closer. Ending macro.
  /autoinv
  /autoinv
  /keypress esc
  /endmacro

|------------------------------------------------------------
| Event: NotWanted
|------------------------------------------------------------
Sub Event_NotWanted
  /echo NPC doesn't want this item. Ending macro.
  /autoinv
  /autoinv
  /keypress esc
  /endmacro

|------------------------------------------------------------
| Event: NoItems
|------------------------------------------------------------
Sub Event_NoItems
  /echo Ran out of items. Ending macro.
  /keypress esc
  /endmacro

DISCLAIMER: I didn't write the above code, I don't remember where I got it, I haven't used it in a few months, I claim no responsibility if it destroys everything in your inventory, deletes your character, and nukes Russia.