TrapTrainer.mac

[EvenLessSpam]

Okay this is a simple script I made for a friend, not really hard to make, and you could also just use MQ2Melee for it, however..

This macro Senses for traps (duh), when found the trap is targeted and then it'll just keep sensing and, hopefully, skilling, and it also does some simple statistics.

Blue con traps works the best it seems. Velketor and Ssra have blue con (60) traps I know, I know of a green con (45) in ToFS..

Just "/echo status" while running it to get statistics..

#Turbo 30
#Event Status       "[MQ2] status"
#Event Sense        "You sense a trap in this direction."
#Event NoSense      "You do not Sense any traps."
#Event Certain      "You are certain that #1# is trapped."
#Event Uncertain    "You are unable to determine if #1# is trapped."
#Event Skillup      "You have become better at Sense Traps! (#1#)"

Sub Main
    /declare Attempts   int     outer   0
    /declare Sense      int     outer   0
    /declare NoSense    int     outer   0
    /declare Certain    int     outer   0
    /declare Uncertain  int     outer   0
    /declare Skillup    int     outer   0

    :loop
        /doevents
        /if (${Me.AbilityReady["Sense Traps"]}) {
            /varcalc Attempts ${Attempts}+1
            /doability "Sense Traps"
        }
    /goto :loop
/return

Sub Event_Status(string Line)
    /if (!${Attempts}) {
        /echo Let's make some attempts before checking the status.
        /return
    }
    /echo TrapTrainer Status:
    /echo Run Time: ${Math.Calc[${Macro.RunTime}/60].Int}m ${Math.Calc[${Macro.RunTime}%60].Int}s
    /echo ${Attempts} Attempts.
    /echo ${Sense} (${Math.Calc[${Sense}/(${Attempts}/100)]}) x "You sense a trap in this direction.".
    /echo ${NoSense} (${Math.Calc[${NoSense}/(${Attempts}/100)]}) x "You do not Sense any traps.".
    /echo ${Certain} (${Math.Calc[${Certain}/(${Attempts}/100)]}) x "You are certain that #1# is trapped.".
    /echo ${Uncertain} (${Math.Calc[${Uncertain}/(${Attempts}/100)]}) x "You are unable to determine if #1# is trapped.".
    /echo ${Skillup} (${Math.Calc[${Skillup}/(${Attempts}/100)]}) x "You have become better at Sense Traps! (#1#)".
/return

Sub Event_Sense(string Line)
    /varcalc Sense ${Sense}+1
    /target npc race "Stone Ring"
/return

Sub Event_NoSense(string Line)
    /varcalc NoSense ${NoSense}+1
/return

Sub Event_Certain(string Line, string Trap)
    /varcalc Certain ${Certain}+1
/return

Sub Event_Uncertain(string Line, string Trap)
    /varcalc Uncertain ${Uncertain}+1
/return

Sub Event_Skillup(string Line, int SkillPts)
    /varcalc Skillup ${Skillup}+1
/return