Release trade skill macros? 1.0

[janktron]

anyone have 1 that will lvl up any/all tradeskills? have several characters that could use the coldain shawl on TLP, and really don't wanna lvl up all those TS manually. Thanks!

 

[wirlin]

|Jewelcraft Macro by Wirlin 4/20/15
|Requires at least 22 inventory slots.
|Also requires a little bit of attention for
|for setting the combine recipe you shouldn't have to experiment to get them though.
|they pop up as you gain skill.
|might try to automate it the same way I did the vendor lists.
|have to find the names of the tradeskill window pieces.
|
|When you get to 272 you can add these recipes to you favorites list
|Sapphire Platinum Necklace , Platinum Ruby Veil , Platinum Diamond Wedding Ring , Platinum Blue Diamond Tiara ,
|and Velium Blue Diamond Bracelet
|Order them from Low skill to High in Favorites and it will take you to 300 by itself
|
|Might need as many as 200 Velium Bars after 294... shouldn't take that many but it has.
|Easiest in Thurgadin with a bunch of Blue Diamonds or anywhere with a ton of bag space
|because it only sells when it runs out of components... having an item on the cursor with bags full throws it for a loop.
|It tries to sell the one that's on the cursor and it's in an invalid sell slot, so it can't.
|

#event OutOfStuff "#*#Sorry, but you don't have everything you need for this recipe in your general inventory.#*#"
#event OutOfStuff "There are no open slots for the held item in your inventory."
#event OutOfStuff "You may not make a purchase while you have an item on your cursor."

Sub Main
/declare Jewelry int outer
/declare Component1 string outer
/declare Component1Amt int outer
/declare Component2 string outer
/declare Component2Amt int outer
/declare ItemtoSell1 string outer

|

/varset Jewelry ${Me.Skill[Jewelry Making]}
/echo Initial Declarations Set for ${Jewelry} Skill

|/nomodkey /notify TradeskillWnd COMBW_SearchButton leftmouseup
|/notify TradeskillWnd RecipeList listselect 1

:SkillCheck
/call Recipe
/delay 1
/goto :Loop

/return


:Loop
/autoinv
/notify TradeskillWnd CombineButton leftmouseup 
/doevents
/delay 2
/notify TradeskillWnd AutoInvButton leftmouseup
/goto :SkillCheck

/return



Sub BuyMore(string BuyComponent, int Amount)
/declare i int local
/declare HowMany int local
/declare ListItem int local
/varcalc HowMany ${Amount}-${FindItemCount[${BuyComponent}]}
/delay 3
/if (${FindItemCount[${BuyComponent}]}>=${Amount}) {
	/echo Have enough ${BuyComponent} to continue.
	/return
	}
/varset ListItem ${Window[MerchantWnd].Child[ItemList].List[=${BuyComponent},2]}
/if (!${ListItem}) {
	/echo ${BuyComponent} is not on Vendor.
	/return
	} else {
	/notify MerchantWnd ItemList listselect ${ListItem}
	/delay 5
	}

/echo Buying ${HowMany} ${BuyComponent}
:BuyLoop
   /if (${HowMany}>0) {
        /if (${HowMany}>19) {
            /Shiftkey /notify MerchantWnd MW_Buy_Button leftmouseup
            /delay 5 ${FindItemCount[B${BuyComponent}]}>=${Amount}
            /echo ${FindItemCount[${BuyComponent}]}/${Amount} ${BuyComponent} in inventory
            /varcalc HowMany ${Amount}-${FindItemCount[${BuyComponent}]} 
            /if (${HowMany}<=0) /return
            /delay 5
            /if (${HowMany}>19) /goto :BuyLoop
        }
        /if (${HowMany}>0 && ${HowMany}<20) {
            /for i 1 to ${HowMany} 
                /Ctrlkey /notify MerchantWnd MW_Buy_Button leftmouseup
                /delay 1s ${FindItemCount[${BuyComponent}]}>=${Math.Calc[${FindItemCount[${BuyComponent}]}+${i}]}
                /echo Buying ${BuyComponent} ${i} of ${HowMany}
                /if (${i}>=${HowMany}) {
                    /echo ${FindItemCount[${BuyComponent}]} ${BuyComponent} in inventory
                /return
                }
            /next i           
        }
    }
/return



Sub SellStuff(string StufftoSell)

/echo Selling ${StufftoSell}
/if (${StufftoSell.Equal[NULL]}) /return

:SellLoop
/if (${FindItemCount[=${StufftoSell}]}) {
/nomodkey /itemnotify ${FindItem[=${StufftoSell}].InvSlot} leftmouseup
/if (${SelectedItem.ID}==${FindItem[=${StufftoSell}].ID}) {
/delay 1s
/nomodkey /shift /notify MerchantWnd MW_Sell_Button leftmouseup
}
/delay 1s
/goto :SellLoop
}
/echo Finished Selling ${StufftoSell}
/return

Sub Event_OutOfStuff
/echo Components used... Cleaning Packs
/call SellStuff ${ItemtoSell1}
/delay 1s
/echo Buying Components
/delay 1s
/call BuyMore ${Component1} ${Component1Amt}
/delay 1s
/call BuyMore ${Component2} ${Component2Amt}
/delay 1s
/echo Finished Buying Components
/return

Sub Recipe
/delay 1
/varset Jewelry ${Me.Skill[Jewelry Making]}
/delay 1

:Recipe1
/if (${Jewelry} > 40) /goto :Recipe2
/delay 1
/varset Component1 Topaz
/varset Component1Amt 20
/varset Component2 "Silver Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Topaz Silver Necklace"
/return

:Recipe2
/if (${Jewelry} > 85) /goto :Recipe3
/delay 1
/varset Component1 Onyx
/varset Component1Amt 20
/varset Component2 "Electrum Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Electrum Onyx Pendant"
/return

:Recipe3
/if (${Jewelry} > 110) /goto :Recipe4
/delay 1
/varset Component1 Topaz
/varset Component1Amt 20
/varset Component2 "Electrum Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Topaz Electrum Earring"
/return

:Recipe4
/if (${Jewelry} > 140) /goto :Recipe5
/delay 1
/varset Component1 Malachite
/varset Component1Amt 20
/varset Component2 "Gold Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Gold Malachite Bracelet"
/return

:Recipe5
/if (${Jewelry} > 160) /goto :Recipe6
/delay 1
/varset Component1 Onyx
/varset Component1Amt 20
/varset Component2 "Gold Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Gold Onyx Pendant"
/return

:Recipe6
/if (${Jewelry} > 180) /goto :Recipe7
/delay 1
/varset Component1 Topaz
/varset Component1Amt 20
/varset Component2 "Gold Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Golden Topaz Earring"
/return

:Recipe7
/if (${Jewelry} > 190) /goto :Recipe8
/delay 1
/varset Component1 Opal
/varset Component1Amt 20
/varset Component2 "Gold Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Golden Opal Amulet"
/return

:Recipe8
/if (${Jewelry} > 215) /goto :Recipe9
/delay 1
/varset Component1 Malachite
/varset Component1Amt 20
/varset Component2 "Platinum Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Platinum Malachite Ring"
/return

:Recipe9
/if (${Jewelry} > 239) /goto :Recipe10
/delay 1
/varset Component1 "Star Rose Quartz"
/varset Component1Amt 20
/varset Component2 "Platinum Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Rose Platinum Engagement Ring"
/return

:Recipe10
/if (${Jewelry} > 265) /goto :Recipe11
/delay 1
/varset Component1 "Fire Opal"
/varset Component1Amt 20
/varset Component2 "Platinum Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Platinum Fire Wedding Ring"
/return

:Recipe11
/if (${Jewelry} > 272) /goto :Recipe12
/delay 1
/varset Component1 Sapphire
/varset Component1Amt 20
/varset Component2 "Platinum Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Sapphire Platinum Necklace"
/notify TradeskillWnd RecipeList listselect 1
/delay 1
/return

:Recipe12
/if (${Jewelry} > 277) /goto :Recipe13
/delay 1
/varset Component1 Ruby
/varset Component1Amt 20
/varset Component2 "Platinum Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Platinum Ruby Veil"
/delay 1
/notify TradeskillWnd RecipeList listselect 2
/delay 1
/return

:Recipe13
/if (${Jewelry} > 285) /goto :Recipe14
/delay 1
/varset Component1 Diamond
/varset Component1Amt 20
/varset Component2 "Platinum Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Platinum Diamond Wedding Ring"
/delay 1
/notify TradeskillWnd RecipeList listselect 3
/delay 1
/return

:Recipe14
/if (${Jewelry} > 294) /goto :Recipe15
/delay 1
/varset Component1 Diamond
/varset Component1Amt 20
/varset Component2 "Platinum Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Platinum Blue Diamond Tiara"
/delay 1
/notify TradeskillWnd RecipeList listselect 4
/delay 1
/return

:Recipe15
/if (${Jewelry} > 299) /goto :Recipe16
/delay 1
/varset Component1 "Blue Diamond"
/varset Component1Amt 20
/varset Component2 "Velium Bar"
/varset Component2Amt 20
/varset ItemtoSell1 "Velium Blue Diamond Bracelet"
/delay 1
/notify TradeskillWnd RecipeList listselect 5
/delay 1
/return

:Recipe16
/echo Jewelry Maxxed.
/end

/return

 

[BusyBard]

anyone have 1 that will lvl up any/all tradeskills? have several characters that could use the coldain shawl on TLP, and really don't wanna lvl up all those TS manually. Thanks!

Don't be lazy. If you still need help message me in game and I'll let you know what to do the whole way. The auto-combine button is a savior but I don't think you'll be able to macro it up the whole way.

Though I did write a macro to harvest Emerald Leaves in Gfay.

 

[janktron]

Don't be lazy. If you still need help message me in game and I'll let you know what to do the whole way. The auto-combine button is a savior but I don't think you'll be able to macro it up the whole way.

Though I did write a macro to harvest Emerald Leaves in Gfay.

isnt one of the main points of any macro to be lazy?

 

[seabeerls]

this mac obsolete? i cant get it to do anything. Once it starts, it just declares my skill (197) and does nothing...i did a little edit on it so it now looks like this....
|Jewelcraft Macro by Wirlin 4/20/15
|Requires at least 22 inventory slots.
|Also requires a little bit of attention for
|for setting the combine recipe you shouldn't have to experiment to get them though.
|they pop up as you gain skill.
|might try to automate it the same way I did the vendor lists.
|have to find the names of the tradeskill window pieces.
|
|When you get to 272 you can add these recipes to you favorites list
|Sapphire Platinum Necklace , Platinum Ruby Veil , Platinum Diamond Wedding Ring , Platinum Blue Diamond Tiara ,
|and Velium Blue Diamond Bracelet
|Order them from Low skill to High in Favorites and it will take you to 300 by itself
|
|Might need as many as 200 Velium Bars after 294... shouldn't take that many but it has.
|Easiest in Thurgadin with a bunch of Blue Diamonds or anywhere with a ton of bag space
|because it only sells when it runs out of components... having an item on the cursor with bags full throws it for a loop.
|It tries to sell the one that's on the cursor and it's in an invalid sell slot, so it can't.
|

#event OutOfStuff "#*#Sorry, but you don't have everything you need for this recipe in your general inventory.#*#"
#event OutOfStuff "There are no open slots for the held item in your inventory."
#event OutOfStuff "You may not make a purchase while you have an item on your cursor."

Sub Main
/declare Jewelry int outer
/declare Component1 string outer
/declare Component1Amt int outer
/declare Component2 string outer
/declare Component2Amt int outer
/declare ItemtoSell1 string outer

|

/varset Jewelry ${Me.Skill[Jewelry Making]}
/echo Initial Declarations Set for ${Jewelry} Skill

|/nomodkey /notify TradeskillWnd COMBW_SearchButton leftmouseup
|/notify TradeskillWnd RecipeList listselect 1

:SkillCheck
/call Recipe
/delay 1
/goto :Loop

/return


:Loop
/autoinv
/notify TradeskillWnd CombineButton leftmouseup
/doevents
/delay 2
/notify TradeskillWnd AutoInvButton leftmouseup
/goto :SkillCheck

/return



Sub BuyMore(string BuyComponent, int Amount)
/declare i int local
/declare HowMany int local
/declare ListItem int local
/varcalc HowMany ${Amount}-${FindItemCount[${BuyComponent}]}
/delay 3
/if (${FindItemCount[${BuyComponent}]}>=${Amount}) {
/echo Have enough ${BuyComponent} to continue.
/return
}
/varset ListItem ${Window[MerchantWnd].Child[ItemList].List[=${BuyComponent},2]}
/if (!${ListItem}) {
/echo ${BuyComponent} is not on Vendor.
/return
} else {
/notify MerchantWnd ItemList listselect ${ListItem}
/delay 5
}

/echo Buying ${HowMany} ${BuyComponent}
:BuyLoop
/if (${HowMany}>0) {
/if (${HowMany}>19) {
/Shiftkey /notify MerchantWnd MW_Buy_Button leftmouseup
/delay 5 ${FindItemCount[B${BuyComponent}]}>=${Amount}
/echo ${FindItemCount[${BuyComponent}]}/${Amount} ${BuyComponent} in inventory
/varcalc HowMany ${Amount}-${FindItemCount[${BuyComponent}]}
/if (${HowMany}<=0) /return
/delay 5
/if (${HowMany}>19) /goto :BuyLoop
}
/if (${HowMany}>0 && ${HowMany}<20) {
/for i 1 to ${HowMany}
/Ctrlkey /notify MerchantWnd MW_Buy_Button leftmouseup
/delay 1s ${FindItemCount[${BuyComponent}]}>=${Math.Calc[${FindItemCount[${BuyComponent}]}+${i}]}
/echo Buying ${BuyComponent} ${i} of ${HowMany}
/if (${i}>=${HowMany}) {
/echo ${FindItemCount[${BuyComponent}]} ${BuyComponent} in inventory
/return
}
/next i
}
}
/return



Sub SellStuff(string StufftoSell)

/echo Selling ${StufftoSell}
/if (${StufftoSell.Equal[NULL]}) /return

:SellLoop
/if (${FindItemCount[=${StufftoSell}]}) {
/nomodkey /itemnotify ${FindItem[=${StufftoSell}].InvSlot} leftmouseup
/if (${SelectedItem.ID}==${FindItem[=${StufftoSell}].ID}) {
/delay 1s
/nomodkey /shift /notify MerchantWnd MW_Sell_Button leftmouseup
}
/delay 1s
/goto :SellLoop
}
/echo Finished Selling ${StufftoSell}
/return

Sub Event_OutOfStuff
/echo Components used... Cleaning Packs
/call SellStuff ${ItemtoSell1}
/delay 1s
/echo Buying Components
/delay 1s
/call BuyMore ${Component1} ${Component1Amt}
/delay 1s
/call BuyMore ${Component2} ${Component2Amt}
/delay 1s
/echo Finished Buying Components
/return

Sub Recipe
/delay 1
/varset Jewelry ${Me.Skill[Jewelry Making]}
/delay 1


:Recipe1
/if (${Jewelry} > 195) /goto :Recipe1
/delay 1
/varset Component1 Diamond
/varset Component1Amt 40
/varset Component2 "Platinum Bar"
/varset Component2Amt 40
/varset ItemtoSell1 "Platinum Diamond Wedding Ring"
/delay 1
/notify TradeskillWnd RecipeList listselect 3
/delay 1
/return

:Recipe2
/if (${Jewelry} > 225) /goto :Recipe2
/delay 1
/varset Component1 Diamond
/varset Component1Amt 40
/varset Component2 "Platinum Bar"
/varset Component2Amt 40
/varset ItemtoSell1 "Platinum Blue Diamond Tiara"
/delay 1
/notify TradeskillWnd RecipeList listselect 4
/delay 1
/return

:Recipe3
/if (${Jewelry} > 250) /goto :Recipe3
/delay 1
/varset Component1 "Blue Diamond"
/varset Component1Amt 40
/varset Component2 "Velium Bar"
/varset Component2Amt 40
/varset ItemtoSell1 "Velium Blue Diamond Bracelet"
/delay 1
/notify TradeskillWnd RecipeList listselect 5
/delay 1
/return

:Recipe4
/echo Jewelry Maxxed.
/end

/return





...............i just edited how many to buy and only wanted last 3 -4 recipes as i have an abundance of diamonds and BD's

 

[seabeerls]

so what i did was run to thurg and targeted the velium merchant...it didnt work. i then opened jewelcraft bag and merchant and then started macro. Still nothing

 

[Rooster]

:Recipe1
/if (${Jewelry} > 195) /goto :Recipe1

If your skill is 197, that is going to endlessly /goto recipe1 and never set recipe items/return to the rest of macro

I think you need to change all those checks to be the following recipe number


I didn't look at the rest, but you will likely see some progress/new errors

 

[seabeerls]

:Recipe1
/if (${Jewelry} > 195) /goto :Recipe1

If your skill is 197, that is going to endlessly /goto recipe1 and never set recipe items/return to the rest of macro

I think you need to change all those checks to be the following recipe number


I didn't look at the rest, but you will likely see some progress/new errors

ok good to know, but regardless, shouldn't the initial recipie1 be at least started? the mac dont end, it just sits there and nothing automates

 

[Rooster]

the logic is
label > recipe1
condition > if my jewelry skill is greater then 195, go to the label recipe1

Creating an endless loop. you could /echo ${Macro.CurLine} in game and probably see that line it is on is that line and never changes

if it's not greater then 195, it'll move down the list of the recipes you have, but then it never does anything them since if your skill isn't greater then 195, it isn't greater then any of the other values.

If you look at the original macro, you'll it was written how I described above /goto recipe# is one more then the :recipe#, Your 'little edit' has broken it, for that part at least. I have no idea about the rest

 

[seabeerls]

thank you sir, you are correct....so i just got rid of that particular number and just did top skill gain recipie...works like a champ.....