Request - See Invis macro/plugin

[lostangelintx]

As someone who invariably aggroes every mob in the zone due to see invis, is there a plugin that would flag/highlight KOS/see invis mobs on the map?
Is there a MQ2Map setting for this?

 

[Wolfborn]

I dug into this a while back and all I could find was that the ability to see through invisibility is not a known flag.
that is why MQ2Maps can't flag them.

What I found was a little macro that cycles through all mobs in the zone and reports back how many are see invis. It does not flag them in any way but could probably be made to make an INI file and then have maps read it and flag them on the map.
May work on that when I get back home.
Here is the code. I forgot who made it first so I can't give credit but. it was not me and I am not taking credit for it.

#event seeinvis "You suspect that this being can see you."

Sub Main

/declare npcno int outer
/declare aray[999] int outer
/declare sicount int outer

/squelch /mapf npc hide
/squelch /mapf npc show
/squelch /mqclear
/squelch /target clear
/squelch /mapf NPCConColor hide
/varset sicount 0

/for npcno 1 to ${SpawnCount[npc]}
	/varset aray[${npcno}] ${NearestSpawn[${npcno}, npc].ID}
/next npcno

/for npcno 1 to ${SpawnCount[npc]}
	/doevents clear
	/target id ${aray[${npcno}]}
	/delay 1s ${Target.ID}==${aray[${npcno}]}
	/consider
	/delay 7
	/doevents
	/if (${Int[${Math.Calc[${npcno}/50]}]}==${Math.Calc[${npcno}/50]}) /echo ${npcno} mobs checked...
/next npcno

/target clear
/echo There are ${sicount} see invis mobs in this zone.

/return

Sub Event_seeinvis

/echo ${npcno}: ${Spawn[${aray[${npcno}]}].Name} can see invis
/squelch /highlight ${Target.Name}
/varcalc sicount ${sicount}+1
/doevents clear

/return

-Wolf