Problem - Mash not working on Rogue AA's

[Cupcake]

The Mash command is not working on rogue AA's for some reason.

Twisted Shank|98|Mash
Absorbing Agent|98|Mash

Neither working...

 

[ctaylor22]

There is an update to fix this, just waiting for Lizzard boy to post the changes.

But till then just change the highlighted line.

    Sub MashButtons(TarID)
        /declare i int local
        /declare MashThis string local
        /for i 1 to ${MashArray.Size}
            /doevents
            /varset MashThis ${MashArray[${i}].Arg[1,|]}
            /if (${MashThis.Length}==0 || ${MashThis.Equal[null]}) /return 
            /if (!${ConditionsOn} || !${DPSCOn} || ${If[${MashCond[${i}]},1,0]}) {
                /if (${FindItem[=${MashThis}].ID} && ${Me.ItemReady[${MashThis}]}) {
                    /useitem "${MashThis}"
                    /echo ## Mashing >> ${MashThis} <<
                } else /if (${Me.AltAbility[${MashThis}]} && ${Me.AltAbilityReady[${MashThis}]} && ${Me.AltAbility[${MashThis}].Type}!=5 && ${MashThis.NotEqual[twincast]})  { 
                    /alt act ${Me.AltAbility[${MashThis}].ID}
                    /echo ## Mashing >> ${MashThis} <<
                } else /if (${Me.CombatAbility[${MashThis}]} && !${Me.CombatAbilityTimer[${MashThis}]} && ${Me.CombatAbilityReady[${MashThis}]} && ${Spell[${MashThis}].EnduranceCost}<${Me.Endurance}) {
                    /disc ${Me.CombatAbility[${Me.CombatAbility[${MashThis}]}].ID}
                    /echo ## Mashing >> ${MashThis} <<
                } else /if (${Me.Ability[${MashThis}]} && ${Me.AbilityReady[${MashThis}]}) {
                    /doability "${MashThis}"
                    /echo ## Mashing >> ${MashThis} <<
                }
                /delay 3
            }
        /next i
    /return 0