Kick off request (1 Viewer)

[hoosierbilly]

I would like to add a feature to the YAFM (included below) that will check for the kick off request window. When detected it will end the macro and accept the kick off or prehaps better to reject the kick off and simple camp out of the game. I leave for Iraq in two days and need the code segment for testing within about 24 hours of this post. Any help is greatly apprcieted.

YAFM needing modified:

|yafm.mac 
| 
|Yet Another Forage Macro 
| 
|Ini File: yafm.ini 
| 
| 0 = destroy 
| x = keep at most x of this item 
| 
|New foraged items are added to the ini file automatically and are kept by default. 


|||||||||||||||||||| 
| Main 
|||||||||||||||||||| 

#Event Camping	"#*#It will take you about 30 seconds to prepare your camp.#*#"

sub Main 
	/echo forage macro started

    /declare DefaultMaxSave int outer 

    /varset DefaultMaxSave ${Ini[yafm.ini,Default,MaxSave,${NotFound}]} 
    /if (${DefaultMaxSave}==${NotFound}) { 
       /ini "yafm.ini" "Default" "MaxSave" "100" 
        /varset DefaultMaxSave 100 
    } 

   /delay 1 

   | Verify that we have the ability to forage. 
|   /if (!${Me.Mount.Equal[Null]}) /goto :Exit
   /if (${Me.Skill[Forage]}==0) /goto :Exit

   :Forage 

   | If we can forage then do so. 

   /if (${Me.AbilityReady[Forage]}) { 
      | Stand up.  Can't forage while sitting. 
      /if (${Me.State.NotEqual[STAND]}) { 
         /stand 
         /delay 5 
      } 
	/doability forage 
   } 

   | If we successfully foraged something then take care of it. 
   /if (${Cursor.ID}) { 
      /call HandleItem 
   } 

   /doevents
   /goto :Forage 

:Exit 
/echo You cannot forage, silly person! 
/return 

|||||||||||||||||||| 
| HandleItem 
|||||||||||||||||||| 
sub HandleItem 

   /declare ItemSetting int local 
   /declare NotFound int local 
   /declare ItemsHave int local 

   /varset NotFound -1 

   :LootIt 

   | Look up this item in yafm.ini 
   /varset ItemSetting ${Ini[yafm.ini,ForageList,${Cursor.Name},${NotFound}]} 
   /delay 5 

   | If the item isn't in the .ini file then add it. 
   /if (${ItemSetting}==${NotFound}) { 
       /ini "yafm.ini" "ForageList" "${Cursor.Name}" "${DefaultMaxSave}" 
       /varset ItemSetting ${DefaultMaxSave} 
   } 

   /varset ItemsHave ${FindItemCount[=${Cursor.Name}]}  
   | If we're keeping this item then stash it in our bags. 
   | Otherwise, just destroy it. 
   /if (${ItemSetting}>${ItemsHave}) { 
     /echo Keeping "${Cursor.Name}" only ${ItemsHave} of ${ItemSetting} on hand 
     /autoinventory 
        } else { 
     /echo Destroying "${Cursor.Name}" already have ${ItemsHave} of ${ItemSetting}
     /destroy 
   } 

   /delay 5 
   /if (${Cursor.ID}) /goto :LootIt 

/return

Sub Event_Camping
	/echo Camping - Ending macro!
	/endmacro
/return

 

[Alatyami]

"kick off request window" is this a new window? Or is this a idle time kick off window? It's been awhile since I last stayed on a lengthy about of time.

 

[triba1fusion]

It's a semi new window.. if you are online.. and get dc'd .. you can go back to the server screen, select log in.. it'll give you the standard message that.. there is already a character logged in on this account, but a new button to kick this character from the server.

If someone is actually on the account, a window will pop up on the character that is logged in stating something like, someone is trying to log in to this account, would you like to stay connected or let them log in. I forgot what the exact wording is, but its something like that.

 

[Alatyami]

Ah I did see that .... now I remember .. that is a nice button, especially when you are testing and CTD.

 

[spyderz68]

Is there a reason you don't want to just select the option in your options window for "Accept Kick Requests" ?

If you want to check the option inside your macro you can do this.

/if (!${Window[OptionsGeneralPage].Child[OGP_AutoAcceptKickRequests].Checked}) /nomodkey /notify OptionsGeneralPage OGP_AutoAcceptKickRequests leftmouseup

 

[hoosierbilly]

Thank you Spyderz68.

My intention is to reject the kick off request and camp out of the game so the macro will end.

Accepting the kick off request in the options window automaticly leaves the macro running.

 

[spyderz68]

I believe that there is a message that goes into the chat window when the kick request is placed. I don't remember the exact text but will look at it when the servers come up. All you would have to do is add a new line for it as an event to end your macro. Since the macro already has an event for camping all you would have to do is add this.

#Event Camping "#*#Whatever the Kick Request Text is#*#"