Autobanker macro

[Arneweise]

Hello,

Here's another of my new quick and dirty macros. Wrote this yesterday to quickly move all the tradeskill loot from my inventory to the bank.
Hope it helps you as much as it does me
Cheers, AW

|*******************************************************************|
| - AutoBank.mac -                                                 *|
|                                                                  *|
| Usage:                                                           *|
|  Open the banker window, and start this macro. If there is an    *|
|  item of this kind in the bank already, it will be auto-banked.  *|
|  Useful for quickly clearing tradeskill materials from your bags.*|
|                                                                  *|
|*******************************************************************|

#turbo

Sub Main
    
    |Loop through all bags
    /declare CurrentBagNum int local
    /declare BagSlot int local
    /declare ItemName string local

    /if (!${Window[BigBankWnd].Open}) {
        /echo Open the bank window first.
        /return
    }
    
    /for CurrentBagNum 1 to 10
        /for BagSlot 1 to ${Me.Inventory[pack${CurrentBagNum}].Container}
        
            /varset ItemName ${Me.Inventory[pack${CurrentBagNum}].Item[${BagSlot}]}
            /if (!${ItemName.Equal[NULL]}) {
                /if (${FindItemBank[=${ItemName}].Name.Length}) {
                    /echo Moved ${Me.Inventory[pack${CurrentBagNum}].Item[${BagSlot}].Stack} ${ItemName} to the bank.
                    /nomodkey /shift /itemnotify in pack${CurrentBagNum} ${BagSlot} leftmouseup
                    /notify BigBankWnd BIGB_AutoButton leftmouseup
                    
                    |/delay 10s
                }
            }
            
        /next BagSlot
    
    /next CurrentBagNum
/return