LandCall_Shaman.mac

|-------------------------------------------------- 
| Name:    LandCall_Shaman.inc 
| Author:    alt228 
| Version:  0.01 
|-------------------------------------------------- 
| Automatically tells the group/raid when a spell 
|   lands on a target 
|-------------------------------------------------- 

#Event LandCall_Shaman_Turgurs "#1# yawns." 
#Event LandCall_Shaman_BoD "#1#'s body slows down." 
#Event LandCall_Shaman_CripplingSpasm "#1#'s muscles spasm uncontrollably." 

Sub Event_LandCall_Shaman_Turgurs(WholeLine, string TargetName) 

   /call LandCall_Shaman_SendMessage "${TargetName}" "<<<${TargetName}>>> slowed by Turgur's Insects" 

/return 

Sub Event_LandCall_Shaman_BoD(WholeLine, string TargetName) 

   /call LandCall_Shaman_SendMessage "${TargetName}" "<<<${TargetName}>>> slowed by Balance of Discord" 

/return 

Sub Event_LandCall_Shaman_CripplingSpasm(WholeLine, string TargetName) 

   /call LandCall_Shaman_SendMessage "${TargetName}" "<<<${TargetName}>>> has been Crippled!" 

/return 

Sub LandCall_Shaman_SendMessage(string TargetName, string MessageToSend) 

   |-------------------------------------- 
   |  if in a raid, call it to /rs 
   |  if just in a group, call it to /g 
   |    don't call anything if I'm afk! 
   |    don't call if I'm not a shaman! 
   |    don't call it if it's not a NPC! 
   |-------------------------------------- 
    
   /if ( !${Me.AFK} && ${Me.Class.Name.Equal[Shaman]} ) { 
      /declare thisSpawnID int local 
      /declare thisSpawnType string local 

      /varset thisSpawnID ${NearestSpawn[${TargetName}].ID} 
      /varset thisSpawnType ${Spawn[${thisSpawnID}].Type} 

      /if ( ${thisSpawnType.Equal[Pet]} ) { 
         /varset thisSpawnType ${Spawn[${thisSpawnID}].Master.Type} 
      } 

      /if ( ${thisSpawnType.Equal[NPC]} ) { 
       
         /if ( ${Raid.Members} > 0 ) { 
            /rs ${MessageToSend} 
         } else /if ( ${Group.Members} > 0 ) { 
            /g ${MessageToSend} 
         } 
          
      } 
   } 

/return

|-------------------------------------------------- 
| Name:    NoRage.inc 
| Author:    alt228 
| Version:  0.04 
|-------------------------------------------------- 
| Automatically turns off attack and backs pet off 
|   when a NPC becomes enraged 
|-------------------------------------------------- 

#Event NoRage_Enraged "#1# has become ENRAGED." 

Sub Event_NoRage_Enraged(WholeLine, string WhosEnraged) 

   /declare thisSpawnID int local 
   /declare thisSpawnType string local 

   /varset thisSpawnID ${NearestSpawn[${WhosEnraged}].ID} 
   /varset thisSpawnType ${Spawn[${thisSpawnID}].Type} 

   /if ( ${thisSpawnType.Equal[Pet]} ) { 
      /varset thisSpawnType ${Spawn[${thisSpawnID}].Master.Type} 
   } 

   /if ( ${thisSpawnType.Equal[NPC]} ) { 
      /echo ${WhosEnraged} enraged - no more attacking! 
      /attack off 
       
      |-------------------------------------------- 
      |  if you have a pet, make it back off too! 
      |-------------------------------------------- 
      /if ( ${Me.Pet.Name.NotEqual[NULL]} ) { 

         /pet hold 
         /pet back off 
         /pet hold 
      } 
   } 

/return