turn in macro (1 Viewer)

[flargendingle]

im not sure how simple or hard this might be, but how bout a turn in macro for this. http://eqtraders.com/articles/article_page.php?article=q237&menustr=120020000000 i dont need the toon to move or anything, just want to walk up, hit /mac whatever , and come back later with all turnins done. this would save everyone so much time, and not everyone may know you can turn lower quality skins/pelts to high quality. the link to EQTraders should have all info needed.

Thanks in advance.

 

[flargendingle]

bump

 

[Siddin]

Just made, have fun!

| Simply use /mac turnin itemname. ie /mac turnin bone chips, or mac turnin something here with a name w/ up to 7 words.
Sub Main 
/declare TurnIn String outer
/declare count int local 


    /if (!${Defined[Param1]}) {
	/varset TurnIn ${Param0}
    } else /if (!${Defined[Param2]}) {
      /varset TurnIn ${Param0} ${Param1}
    } else /if (!${Defined[Param3]}) {
      /varset TurnIn ${Param0} ${Param1} ${Param2}
    } else /if (!${Defined[Param4]}) {
      /varset TurnIn ${Param0} ${Param1} ${Param2} ${Param3}
    } else /if (!${Defined[Param5]}) {
      /varset TurnIn ${Param0} ${Param1} ${Param2} ${Param3} ${Param4}
    } else /if (!${Defined[Param6]}) {
      /varset TurnIn ${Param0} ${Param1} ${Param2} ${Param3} ${Param4} ${Param5}
    } else  {
      /varset TurnIn ${Param0} ${Param1} ${Param2} ${Param3} ${Param4} ${Param5} ${Param6}
    }
/echo turning in ${FindItemCount[=${TurnIn}]} ${TurnIn}
:Loop 

/if (!${FindItem[=${TurnIn}].InvSlot}) { 
  /echo Go get more stuff! We be done! 
  /endmacro 
} 

/for count 1 to 4 
   /ctrlkey /itemnotify ${FindItem[=${TurnIn}].InvSlot} leftmouseup 
  /delay 2s ${Cursor.ID} 
   /if (!${FindItem[=${TurnIn}].InvSlot}) /goto :Done 
      /delay 4 
   /if (${count}==1) { 
      /click left target 
      /click left target 
      /delay 2s !${Cursor.ID} 
     } 
   /if (${count}==2) { 
      /notify GiveWnd GVW_MyItemSlot1 leftmouseup 
        /delay 2s !${Cursor.ID} 
     } 
   /if (${count}==3) { 
      /notify GiveWnd GVW_MyItemSlot2 leftmouseup 
  /delay 2s !${Cursor.ID} 
     } 
   /if (${count}==4) { 
            /notify GiveWnd GVW_MyItemSlot3 leftmouseup 
  /delay 2s !${Cursor.ID} 
     } 
/next count 
/delay 4 
/notify GiveWnd GVW_Give_Button leftmouseup 
/delay 4 

:cursorclear 
/delay 4 
/autoinventory
/if (${Cursor.ID}) /goto :cursorclear 
/goto :Loop 

:Done 
  /delay 4 
  /notify GiveWnd GVW_Give_Button leftmouseup 
  /endmacro

 

[flargendingle]

thanks so much! works like a champ!

 

[hoosierbilly]

Nice Lil macro, how hard would it be to make it work when selling stacks of something to vender?

 

[bigsnafu]

Being the kind of person that doesn't like to type much (aka lazy) I have updated the turnin macro to give all of the items that are on the cursor to the npc that is targeted.

give.mac

| Simply use /mac give with the item you want to turn in on the cursor and the npc you want to turn into targeted.

Sub Main 

/declare TurnIn String outer
/declare count int local 

/varset TurnIn ${Cursor.Name}
/autoinv

/face fast

/echo turning in ${FindItemCount[=${TurnIn}]} ${TurnIn}
:Loop 

/if (!${FindItem[=${TurnIn}].InvSlot}) { 
  /echo Go get more stuff! We be done! 
  /endmacro 
} 

/for count 1 to 4 
   /ctrlkey /itemnotify ${FindItem[=${TurnIn}].InvSlot} leftmouseup 
   /delay 2s ${Cursor.ID} 
   /if (${count}==1) { 
      /click left target 
      /click left target 
      /delay 2s !${Cursor.ID} 
     } 
   /if (${count}==2) { 
      /notify GiveWnd GVW_MyItemSlot1 leftmouseup 
        /delay 2s !${Cursor.ID} 
     } 
   /if (${count}==3) { 
      /notify GiveWnd GVW_MyItemSlot2 leftmouseup 
  /delay 2s !${Cursor.ID} 
     } 
   /if (${count}==4) { 
            /notify GiveWnd GVW_MyItemSlot3 leftmouseup 
  /delay 2s !${Cursor.ID} 
     } 
   /if (!${FindItem[=${TurnIn}].InvSlot}) /goto :Done 
/next count 
/delay 4 
/notify GiveWnd GVW_Give_Button leftmouseup 
/delay 4 

:cursorclear 
/delay 4 
/autoinventory
/if (${Cursor.ID}) /goto :cursorclear 
/goto :Loop 

:Done 
  /delay 4 
  /notify GiveWnd GVW_Give_Button leftmouseup 
  /endmacro

-bigsnaf