Question - Hunter mode

[Topnet]

I'm having a problem with hunter mode. I set my character to med at 25% mana and it works fine but if he gets hit by a roamer before he has more then 25% mana he keeps trying to sit down and eventually dies. The option to med during combat is set to off.

here that part of the ini
MedOn=1
MedStart=25
MedCombat=0

Any help is greatly appreciated.

 

[ctaylor22]

Does your hunter ever target the Mob? Next time it happens try targeting yourself and see if he switches to the mob, but doesn't attack. Make sure you don't have the roaming mob on your ignore list.

 

[Razkle]

I have had the same issue this last week so I set my med to MedOn=0 as even with no stam he still murders everything he is "hunting"

 

[Maskoi]

This is a known issue i have not had time to track done yet. Currently soultion is to set camp where there are no roamers aggroing you.

 

[ctaylor22]

OK I think I found it. I pulled this from KA 7.4.1

in sub DoWeMed look for this code. It is at the bottom and is for medding if HP's are low, not Mana or Endurance. The upper part looks to be ok.

			/if (${Select[${Role},pullerpettank,puller,hunter]} && ${Me.PctHPs}<=50) {
				/echo Medding to 100% health
				/if (!${Me.Mount.ID} && !${Me.Sitting}) /sit
				:WaitFor100
                    /doevents
                    /if (${ReturnToCamp} && ${Math.Distance[${CampYLoc},${CampXLoc}]} > 10) {
                        /if (!${Me.Mount.ID} && ${Me.Sitting}) /stand
                        /call DoWeMove
                    }
					/delay 5
                    /call CheckCasting 50
                    /delay 5
                    /call WaitSubs
				/if  (${Me.PctHPs}<100) /goto :WaitFor100
				/if (!${Me.Mount.ID} && ${Me.Sitting}) /stand
			}

Now replace the above section with this.

			/if (${Select[${Role},pullerpettank,puller,hunter]} && ${Me.PctHPs}<=50) {
				/echo Medding to 100% health
				/if (!${Me.Mount.ID} && !${Me.Sitting}) /sit
				:WaitFor100
                    /doevents
                    /if (${ReturnToCamp} && ${Math.Distance[${CampYLoc},${CampXLoc}]} > 10) {
                        /if (!${Me.Mount.ID} && ${Me.Sitting}) /stand
                        /call DoWeMove
                    }
					/delay 5
                    /call CheckCasting 50
                    /delay 5
                    /call WaitSubs
					/if (!${MedCombat}) {
                        /call CheckForAdds DoWeMed
						/if (${AddsInCamp}) /return
                        /if (${AggroTargetID}) {
                            /varset Medding 0
                            /return
						}
					}	
				/if  (${Me.PctHPs}<100) /goto :WaitFor100
				/if (!${Me.Mount.ID} && ${Me.Sitting}) /stand
			}

Here is the complete Sub Routine

    Sub DoWeMed
        /if (!${MedOn} || ${AggroTargetID} && !${MedCombat}) /return
        /if (${Debug}) /echo DEBUG DoWeMed enter || ${Me.Buff[Resurrection Sickness].ID}
        /declare Med2On int local 0
        /declare MedStat1 string local ${MedStat}
        /if (!${Me.Moving}) {
            /if (${Select[${Me.Class.ShortName},BST,PAL,RNG,SHD]} && ${Me.Pct${MedStat2}}<${MedStart} && ${Me.Pct${MedStat}}>${MedStart})  {
                /varset MedStat1 ${MedStat}
                /varset MedStat ${MedStat2}
                /varset Med2On 1
            }
            /if (${Me.Pct${MedStat}}<${MedStart}) {
                /squelch /tar clear
                /if (${Attacking}) /call CombatReset
                /if (${Select[${Role},puller,pullertank,pullerpettank,hunter]}) /call BroadCast ${IRCOn} ${EQBCOn} t "PULLER-> My ${MedStat} is ${MedStart}% time to med."
                /if (${IAmABard} && ${TwistMed} && ${TwistOn}) /squelch /twist ${TwistMed}
                /varset Medding 1
            :wait_for_resume
                    /doevents
                    /if (${ReturnToCamp} && ${Math.Distance[${CampYLoc},${CampXLoc}]} > 10) {
                        /if (!${Me.Mount.ID} && ${Me.Sitting}) /stand
                        /call DoWeMove
                    }
                    /if (${Debug}) /echo DEBUG ${MedStat} ${MedStat1} ${MedStat2}
                    /delay 5
                    /call CheckCasting 50
                    /delay 5
                    /call WaitSubs
                    /if (!${MedCombat}) {
                        /call CheckForAdds DoWeMed
			/if (${AddsInCamp}) /return
                        /if (${AggroTargetID}) {
                            /if (${Med2On}) /varset MedStat ${MedStat1}
                             /varset Medding 0
                            /return
                        }
                    }
                /if (${Me.Pct${MedStat}}<100) /goto :wait_for_resume
                | /if (${Select[${Me.Class.ShortName},BST,PAL,RNG,SHD]} && ${Me.Pct${MedStat2}}<100) /goto :wait_for_resume
            :done_medding
            /if (${Med2On}) /varset MedStat ${MedStat1}
            /varset Medding 0
            /if (${Me.Sitting}) /stand
            }
	    /if (${Select[${Role},pullerpettank,puller,hunter]} && ${Me.PctHPs}<=50) {
		/echo Medding to 100% health
		/if (!${Me.Mount.ID} && !${Me.Sitting}) /sit
		:WaitFor100
                 /doevents
                 /if (${ReturnToCamp} && ${Math.Distance[${CampYLoc},${CampXLoc}]} > 10) {
                     /if (!${Me.Mount.ID} && ${Me.Sitting}) /stand
                     /call DoWeMove
                  }
		    /delay 5
                    /call CheckCasting 50
                    /delay 5
                    /call WaitSubs
		    /if (!${MedCombat}) {
                        /call CheckForAdds DoWeMed
			/if (${AddsInCamp}) /return
                        /if (${AggroTargetID}) {
                            /varset Medding 0
                            /return
			}
		    }	
		    /if  (${Me.PctHPs}<100) /goto :WaitFor100
		    /if (!${Me.Mount.ID} && ${Me.Sitting}) /stand
		}
        }
        /if (${Debug}) /echo DEBUG DoWeMed leave
    /return

 

[Topnet]

Thanks for this fix ctaylor22 and thank you Maskoi for a great macro.

 

[Maskoi]

This fix was added to most current version you can download 7.6.4.