Guild bank depositor

[Sym]

I was annoyed having to click and click and click to drop a crap ton of items in guild bank so I made this. It'll loop putting whatever is on your cursor to guild bank, then when nothing has been deposited for 5 seconds it'll move those items to the actual guild bank and make them publicly available. If you're not a guild banker no idea what this will do.

| Guild bank depositor
| 2012-04-26 :: Sym


Sub Main

    /declare PromoteTimeout timer 5s

    | Start loop, deposit whatever is on cursor
    :StartDeposit
        /if (${Cursor.ID}) {
            /notify GuildBankWnd GBANK_DepositButton leftmouseup
            /delay 1s !${Cursor.ID}
            /varset PromoteTimeout 5s
        }
        | If nothing has been deposited in 5 seconds move items from deposit window to guild bank
        /if (!${PromoteTimeout}) /goto :StartPromote
    /goto :StartDeposit
    
    :StartPromote
        | Nothing in deposit list? End macro
        /if (${Window[GuildBankWnd].Child[GBANK_DepositList].List[1,4].Length} == 0) /endm

        | Select first item
        /notify GuildBankWnd GBANK_DepositList listselect 1
        /delay 1s
        
        | Click put in bank button
        /notify GuildBankWnd GBANK_PromoteButton leftmouseup
        
        | Wait 2 seconds or until we have view only text in the top item list
        /delay 2s ${Window[GuildBankWnd].Child[GBANK_ItemList].List[View Only,4]}
        
        /if (${Window[GuildBankWnd].Child[GBANK_ItemList].List[View Only,4]}) {
            | Change view only to public access
            /notify GuildBankWnd GBANK_PermissionCombo listselect 4
        }
    /goto :StartPromote

/return

 

[meeskino]

this is cool stuff

 

[Maskoi]

My guild bank bot does this too but thanks for sharing nice if you just want to move crap into the bank.

http://forums.notaddicted.com/showthread.php?t=23811