FHalls, Get Mission and Zone in w/o Warp

[Gildon]

I was uncomfortable using warp in Nedaria's Landing so I made this script to run me to the dock, get the mission, run back to the cave, zone in, and run to the rat room.

I box a group of characters so I have code in here to detect when my bard has gotten the mission and to zone the group in after he zones in. I also use the MQ2Irc plugin to monitor my group. If you don't use the IRC plugin remove all the /i say lines or change them /gsay. You'll need MQ2MoveUtils for this to work.

In whatever macro you use, just add at the top:

#Include common.inc

And in your Sub Main do a

/call CommonDeclares

Save this file as common.inc

#event Dzquit "#*#You have entered Nedaria's Landing#*#" 
#event PoK "You have entered The Plane of Knowledge."
#event Fhalls "You have entered The Forgotten Halls."
#event Movedone "Arrived at MoveTo location"

Sub CommonDeclares
  /declare ZoneID int outer ${Zone.ID} 
  /declare moveflag int outer 0
  /declare wezoned int outer 0
  /echo Finished with Common Declares
/return

Sub KillMacro 
   /echo Macro is now shutting down... 
   /delay 1s
   /dism
   /delay 1s
   /sit
   /delay 1s
   /camp
   /delay 1s
   /endmacro 
/return 

Sub event_Dzquit
  /declare i int local
  /doevents flush
  /i say We got booted to Nedaria
  /varset wezoned 1
  /dism
  /declare bardinzone local TRUE
| If I'm not the bard, skip down to waiting for him to get the mission and zone in.
  /if (!${Me.Name.Equal[bard]}) {
  	/delay 30s
  	/goto :others
  }
  /twist stop
  /delay 1s
| Selo's song of travel is in Gem9 for me.  
  /twist 9
  /look 20
  /moveto loc 1591 -613
  /i say Moving to infront of cave passage (interior)
  /call Movetoloop
  /look 20
  /moveto loc 1555 -495
  /i say Moving to middle of cave passage
  /call Movetoloop
  /look 20
  /moveto loc 1267 -438
  /i say Moving to edge of water outside of cave
  /call Movetoloop
| Make sure I'm not crouched
  /keypress X
  /delay 1s
  /keypress X
  /look 20
  /moveto loc 293 643
  /i say Moving to middle of forest at an angle to Eldros
  /call Movetoloop
  /look 20
  /moveto loc 304 1589
  /i say Moving to Eldros
  /call Movetoloop
  /twist stop
  /delay 25s
  /target eldros
  /say Interested in visiting
| Sometimes when I land I wind up in the Duck position.  This crouches and stands back up.  
  /keypress X
  /delay 1s
  /keypress X
  /twist 9
  /look 20
  /moveto loc 293 643
  /i say Moving to middle of forest heading back to cave.
  /call Movetoloop
  /look 20
  /moveto loc 1267 -438
  /i say Moving to edge of water outside of cave
  /call Movetoloop
  /look 20
  /moveto loc 1555 -495
  /i say Moving to middle of cave passage
  /call Movetoloop
  /look 20
  
  :others
  /if (${Zone.ID}==998) /return
  /doevents
| Wait till the bard is no longer in Nedaria, this means the mission has been accepted and he's in FHalls  
  /if (!${Me.Name.Equal[bard]} && ${bardinzone}) {
  	/target bard
  	/if (!${Target.ID}) /varset bardinzone FALSE
  	/delay 5s
  	/goto :others
  }
  /moveto loc 1591 -613
  /i say Moving to infront of cave passage (interior)
  /call Movetoloop
  /delay 2s
| If you have a pet and move right over to the rock and hit U, you'll target your pet instead of the rock.
| This moves the pet out of the way.  
  /pet sit
  /look 20
  /moveto loc 1544 -665
  /echo Moving to stone
  /call Movetoloop
  /face loc 1540, -675
  /look 0
| Target the rock
  /doortarget
  /face
  /delay 5s
  /keypress u
  /delay 5s 
  /keypress u 
  /delay 5s 
  /keypress u
  /if (${Zone.ID}!=998) /goto :others
/return

Sub event_Fhalls
  /doevents flush
  /look 0
  /moveto loc -813 -25
  /i say Moving to doorway near harindi guide
  /call Movetoloop
  /moveto loc -810 43
  /i say Moving past doorway near harindi guide
  /call Movetoloop
  /moveto loc -596 44
  /i say Moving to top of stairs near rat room
  /call Movetoloop
  /if (${Me.Name.Equal[Toon1]}) {
    /moveto loc -605 128
    /i say Moving into the rat room [Toon1]
    /call Movetoloop
  }
  /if (${Me.Name.Equal[Toon2]}) {
    /moveto loc -590 179
    /i say Moving into the rat room [Toon2]
    /call Movetoloop
  }
  /if (${Me.Name.Equal[Toon3]}) {
    /moveto loc -603 140
    /i say Moving into the rat room [Toon3]
    /call Movetoloop
  }
  /if (${Me.Name.Equal[Toon4]}) {
    /moveto loc -597 160
    /i say Moving into the rat room [Toon4]
    /call Movetoloop
  }
  /if (${Me.Name.Equal[Toon5]}) {
    /moveto loc -590 140
    /i say Moving into the rat room [Toon5]
    /call Movetoloop
  }

  /delay 40s
  :Waitforall
  /if (${SpawnCount[pc]}!=5) {
  	/i say Waiting for everyone to zone in.
  	/delay 10s
  	/goto :Waitforall
  }
  /i say Back in Forgotten Halls, Starting fighting again in 60 seconds!
  /delay 60s
  /if (${Me.Name.Equal[bard]}) /twist 1 2 3 4 5
  /varset wezoned 0
/return

Sub Movetoloop
  :waitforit
  /if (${moveflag}==0) {
  	/delay 2s
|  	/echo We're in the loop waiting for arrival
  	/doevents
  	/goto :waitforit
  }
  /varset moveflag 0
/return

Sub event_Movedone
  /varset moveflag 1
  /echo Arrived at waypoint!
/return

Sub event_PoK
  /call KillMacro
/return

 

[letmein]

*bows*

OMG

 

[fatgnome]

Nice work. Recently I have started using advpath.inc. It's great. You start "recording" a path to walk and you can play it back. You can make it look really natural too. I use it to get my missions and zone back in.

 

[letmein]

fatgnome, is there a tutorial for using advpath.inc? I haven't been able to locate one.

Thanks

*edit*

NM found it on MQ2 forum

 

[ddd000]

Nice, thank you.

 

[Pugs]

Very Nice work !!!

 

[codecaster]

I do the same thing... I just recorded 4 or 5 natural looking paths to and from Eldros from the zone-in to FH and have MQ randomly pick one of the paths to travel so I never do the same thing twice. I do use warp one time once I am in the instanced zone to get to the rat room, but that's it. I figure people are getting busted for 16,000+ warps in a week... I've been warping for years and never been busted for doing it 4-5 times a day.

-CodeCaster

 

[Wilbur]

I've tried, but I can't figure out how to completely incorporate this into the Forgotten Halls Macro that uses Warp to do all of this, I keep getting nervous about using warp and I wanted to try and make it so I can run the FH macro afk but run to all the areas. Any Ideas?

 

[f0ok]

Ok when Im using the Pugs hackedup version of the bard macro, do I only add "/call CommonDeclares" into the top of the macro or into the area where the #events are called out, or beneath Sub event_dzquit to replace the /warp commands? Trying to learn this, as I alter everything to make sence of all this MQ language =)

 

[Gildon]

You would add it in like this:

Sub Main
/call CommonDeclares
|We are waiting for the hotkey to start the macro
	:waitforit
	/doevents
	/doevents
	/goto :waitforit
/return

You need it to be called when the macro first starts up so it goes in the main sub, however, it only needs to be called once to declare the variables so you do it before the loop :waitforit

 

[f0ok]

crap still cant get it to work... Its still calling the subs that are used in the main FH.mac Do i need to delete them or what?

 

[Gildon]

Comment out the #event dzquit from the other macro. That way when you zone to Nedaria, the event in my include will pick it up instead of the original event.

 

[x0cet]

Gildon would you consider posting your whole macro?

 

[Gildon]

I don't use the bard kiting macro. I have a group of 6 toons. Five of them run Autobot with some minor changes to accomodate my common.inc. The 6th is my tank that runs a custom pull/tank macro for FHalls. I'd be glad to post the tank macro if that's what you're looking for.

 

[CoderBob]

I just recorded 4 or 5 natural looking paths to and from Eldros from the zone-in to FH and have MQ randomly pick one of the paths to travel so I never do the same thing twice.

Code, or anyone else that does this, could you tell me how to get mq2 to pick varying saved paths?? I got the four different paths to the same target that i want but not sure how to get mq2 to randomly select one.

taii