DKP log updating macro

[HardOne]

This macro was written for a DKP parsing program which compares the /list and /who of a zone from EQ logs for your DKP database.

Just Modify the channel(s) and the time to your liking. (default is to /list and /who every 15 minutes)

Also Included is the /notinzone command which will provide a list of all raid members not in the zone.

The macro will auto end when you camp if you forget to end it.

DKPParse.mac

|DKPParse.mac by HardOne 
|Janurary 01, 2006 
|Last Updated: Janurary 26, 2006 
| 
|This Macro Auto-Updates your Logs for DKP parsing programs. 
|Does /list and /who commands every 15 Minutes 
|Provides Function to see who in Raid is Not in zone, by typing /notinzone 
|Added "Camp Check" to end macro if you camp. 
|Change the Name to match your Raid Channel Name. (ex. /list WeRaidGud)- 
|Change 15m, to what ever Time Frequency you want (ex. 15m = 15 Minutes)- 

#Event WhoNotInZone        "[MQ2] notinzone" 
Sub Event_WhoNotInZone(string Line) 
   /if (!${Raid.Members}) { 
      /echo /notinzone: You are not in raid. 
      /return 
   } 
    
   /echo -------------------------- 
   /echo # Raid members not in zone: 
    
   /declare i int local 0 
   /declare cnt int local 0 

   /for i 1 to ${Raid.Members} 
      /if (!${Spawn[PC ${Raid.Member[${i}].Name}].ID}) { 
         /echo # ${Raid.Member[${i}].Name} [${Raid.Member[${i}].Class.ShortName}] (${SpawnCount[pc ${Raid.Member[${i}].Class.ShortName}]} ${Raid.Member[${i}].Class.Name.Lower}s in zone) 
         /varcalc cnt ${cnt}+1 
      } 
   /next i 

   /echo # ${cnt} of ${Raid.Members} raid members not in zone 
   /echo -------------------------- 
/return 

Sub MakeRaidDumpsFunction 
   |Change Channel(s) to Suit your Raid Channels 
    /list channel1 
    /delay 1 
    /list channel2
    /delay 1 
    |The slash is here to do a normal Everquest /who
    / 
/return 

#Event   Camping            "#*#It will take you about 30 seconds to prepare your camp.#*#" 
Sub Event_Camping 
   /echo Camping - Ending macro! 
   /endmacro 
/return 

Sub Main 
   /declare MakeRaidDumpsTimer     timer outer 0 

   /squelch /alias /notinzone /echo notinzone 

   :dkploop 
      /doevents 

      |DKP log parse 
      |Change 15m to what time interval you want logs updated (15m = 15 Minutes) 
         /if (!${MakeRaidDumpsTimer} && ${Raid.Members}) { 
         /echo [${Time}] # Updating Logs for DKP. 
         /call MakeRaidDumpsFunction 
         /popup Updating Logs for DKP. 
         /echo Next Update in 15 Minutes. 
         /varset MakeRaidDumpsTimer 15m 
      } 
    
   /goto :dkploop 
/return

 

[Overlord]

Good Job Can't wait to check this out!

 

[Pugs]

Is there any to dump it to a file instead of a chat channel?

 

[Cheesymac]

turn logging on

 

[HardOne]

it just outputs to the eqlog.txt file, in your logs folder.

in game type /log on

 

[HardOne]

I have converted this macro to a plugin (Minus the /notinzone command) You can find it here: http://www.redguides.com/community/showthread.php?t=12536