Crystane's just for fun section.

[Crystane]

Heya all,

first of all this is really..... no REALLY slow exp, dont do it hehe.
Why I post it, because I got asked polite, if am able to write such, and yes I am. Actually I didnt think it would be that easy. Thx for all the info provided by jstbilly.

How to get started:
-Go to South Ro and to the beach in the east.
-Start it.

This is a kinda fire and forget macro, it shuts down if it encounters any problems.

Know problems: Some mobs run into zoneline to North Ro hehe.

Enjoy Crystane.

|The Great Caiman 1.0 by Crystane for www.redguides.com
|Requires plugin mq2moveutils.dll
|Requires Expansion PoR / gives 1.5% AA exp per turn
|The Author recommends an Enduring Breath item while doing this task.

#turbo 20
#include spell_routines.inc 
#include move.inc

#Chat say
#Event Assigned "You have been assigned the task 'The Great Caiman Issue'."
#Event KillFinish "Your task 'The Great Caiman Issue' has been updated."
#Event TaskFinish "You have cleared the beach for Dimbwicket have helped the great city of Freeport!"
#Event CaimanKill "You have slain#*#caiman!"
#Event Toofaraway "Your target is too far away, get closer!"

Sub Main

/declare Taskrequestcounter int outer 0
/declare Taskactive outer FALSE
/declare Killsdone outer FALSE
/declare UpdateCounter int outer 0
/declare KillCounter int outer 0
/declare ToofarawayCount int outer
/declare n int outer

:GetTaskloop
/cleanup
/call MoveToLoc 2478 -2657
/target ${NearestSpawn[Dimbwicket NPC]}
/if (${NearestSpawn[Dimbwicket NPC].Distance}>50) {
	/echo Dimbwicket is not where he is supposed to be, ending this.
	/end
}
/stick 15
/delay 1s
/stick off
/h
:notyet
/varcalc Taskrequestcounter ${Taskrequestcounter}+1
/if (${Taskrequestcounter}>3) {
	/echo Too many failed requests. Ending this.
	/end
}
/say clear the beach
/delay 2s ${Window[TaskWnd].Open}
/if (${Window[TaskWnd].Open}) {
	/doevents Assigned
	/if (!${Taskactive}) {
		/goto :notyet
	} else {
		/varset Taskrequestcounter 0
	}
	/cleanup
} else {
	/goto :notyet
}
:Killloop
/if (${SpawnCount[Caiman NPC]}>0) {
	/call KillCaiman
	/doevents KillFinish
} else {
	/call KillCroco
}
/for n 1 to 16
/doevents KillFinish
/next n
/doevents CaimanKill
/if (!${Killsdone}) /goto :Killloop
/cleanup
/call MoveToLoc 2478 -2657
/target ${NearestSpawn[Dimbwicket NPC]}
/stick 15
/delay 1s
/stick off
/hail
/delay 20s
/delay 2m ${NearestSpawn[Dimbwicket NPC].Distance}<50
/call Reset
/goto :GetTaskloop
/return

sub KillCaiman
/call MoveToLoc ${NearestSpawn[caiman NPC].Y} ${NearestSpawn[caiman NPC].X}
/target ${NearestSpawn[caiman NPC]}
/stick 10
/attack on
/declare i int local
/declare j int local
/for i 1 to 12
/delay 10s !${Target.ID} || ${Target.Type.Equal[PC]} || !${Target.Name.Find[caiman]}
/for j 1 to 15
/doevents Toofaraway
/next j
/next i
/cleanup
/return

sub KillCroco
/call MoveToLoc ${NearestSpawn[crocodile NPC].Y} ${NearestSpawn[crocodile NPC].X}
/target ${NearestSpawn[crocodile NPC]}
/stick 10
/attack on
/declare i int local
/declare j int local
/for i 1 to 12
/delay 10s !${Target.ID} || ${Target.Type.Equal[PC]} || !${Target.Name.Find[crocodile]}
/for j 1 to 15
/doevents Toofaraway
/next j
/next i
/cleanup
/return

sub Reset
/doevents flush
/varset Taskrequestcounter 0 
/varset Taskactive FALSE
/varset Killsdone FALSE
/varset UpdateCounter 0
/varset KillCounter 0
/varset ToofarawayCount 0
/return

sub Event_Assigned
/varset Taskactive TRUE
/return

sub Event_KillFinish
/varcalc UpdateCounter ${UpdateCounter}+1
/echo Updatecount: ${UpdateCounter}
/if (${UpdateCounter}>=15) /varset Killsdone TRUE
/return

sub Event_CaimanKill
/if (${Taskactive}) /varcalc KillCounter ${KillCounter}+1
/echo KillCounter: ${KillCounter}
/if (${KillCounter}>=15) /varset Killsdone TRUE
/return

Sub Event_Toofaraway
/varcalc ToofarawayCount ${ToofarawayCount}+1
/if (${ToofarawayCount}>15) {
	/varset ToofarawayCount 0
	/squelch /target clear
}
/return

 

[Crystane]

Hey Jstbilly,

minor fix added, check it out.