Bug - Burn won't trigger after zoning

[Synk]

I think this is 100% reproducable if you have burn setup to trigger on a text phrase. It's not a problem I think if it just auto triggers on any named. It happens for all of my chars (I have 18 total).

Here is an example of my burn section. To call a burn I use a macro that has /bcga //echo burnin in it. It's pretty unreliable unless I've reloaded my macro recently and have not zoned.

[Burn]BurnText=burnin
BurnAllNamed=0
Burn1=Call of Xuzl
Burn2=Arcane Whisper
Burn3=Silent Casting
Burn4=Improved Twincast
Burn5=Focus of Arcanum
Burn6=Fundament: Second Spire of Arcanum
Burn7=Fury of the Gods
Burn8=Frenzied Devastation
Burn9=Selrach's Frostfire Robe
Burn10=Arcane Destruction
Burn11=Arcane Fury
Burn12=Mana Burn
Burn13=Twincast
Burn14=NULL
Burn15=NULL
UseTribute=0
BurnCOn=0
BurnSize=15

- - - Updated - - -

Well, I started digging around in the Kiss11 macro and found a bind for the burn routine

Line 181: #bind Burn /burn

I just tested it out and looks like it works like a champ. If this is planned to stay in, burntext can be removed from the ini I think, worked really good!

- - - Updated - - -

Ok update here, even using the /burn bind this is still happening. After zoning the bind will no longer trigger the burn, I have to reload my macro. Reproducable 100% of the time.

 

[kaen01]

/if (${IAmDead} || ${Me.Hovering} || ${CampZone}!=${Zone.ID} || ${BurnText.Equal[null]} || !${BurnText.Length}) {

this seems to be your problem

if you have had campzone set, and you zone those two places wont be the same, i bet if you remove *|| ${CampZone}!=${Zone.ID}* from that if you wont have your problem

 

[Synk]

That's interesting kaen01 thanks, maybe the camphere bind doesn't reset the camp zone?

I can't quiet follow the camphere logic in the macro but a quick look shows that the only time the CampZone variable is set is when the macro is loaded where the declare is, I don't see any other resetting of it anywhere unless I'm missing something.

If so I need to figure out how I add a /varset CampZone ${Zone.ID} to the /camphere bind ... but the bind just calls a toggle of a variable now, I don't follow where that triggers a reset of the camp.

/squelch /alias /camphere       /togglevariable ReturnToCamp

I could only find the camp location being changed in two places and I think this subroutine is likely where I need to add the CampZone update for it to update my CampZone var anytime I call a /camphere.

Can anyone confirm?

SUB: Bind_ToggleVariable  Check whenever the player is changing any variable via /echo| -------------------------------------------------------------------------------------
    Sub Bind_ToggleVariable(string Command, string Command2, string Command3)
        /if (${Debug}) /echo ${Command} ${Defined[${Command}]} ${Command2} ${Command3}
        /declare i int local
        /declare OnOff local
        | Toggle Variables & Set Variables
        /if (${Defined[${Command}]}) {
            /if (${Debug}) /echo ${Command}:${${Command}} ${Defined[${Command}]} ${Command2} ${Command3}
            /if (${Select[${Command2},0,1,on,off]}) {
                /if (${Select[${Command2},0,off]}) {
                    /varset ${Command} 0
                    /varset OnOff Off
                    /if (${Debug}) /echo ${OnOff} 1
                } else /if (${Select[${Command2},1,on]}) {
                    /varset ${Command} 1
                    /varset OnOff On
                    /if (${Debug}) /echo ${OnOff} 2
                } 
            } else /if (${${Command}}) {
                /varset ${Command} 0
                /varset OnOff Off
                /if (${Debug}) /echo ${OnOff} 3
                /if (!${ChaseAssist} && ${Stick.Active})  /squelch /stick off
            } else {
                /varset ${Command} 1
                /varset OnOff On
                /if (${Debug}) /echo ${OnOff} 4
            }
            /if (${Command.Equal[ChaseAssist]}) {
                /if (${OnOff.Equal[on]}) {
                    /if (${Command3.NotEqual[null]} && ${Command3.Length}>0 && ${WhoToChase.NotEqual[${Command3}]}) {
                        /varset WhoToChase ${Command3}
                        /echo I Will Now Chase ${WhoToChase}
                    }
                    /if (${ReturnToCamp}) /varset ReturnToCamp 0
                } else {
                    /if (${Stick.Active}) /squelch /stick off
                }
            }
            | Turn on return to camp & set new y,x coord
            /if (${Command.Equal[ReturnToCamp]} && ${OnOff.Equal[on]}) {
                /varset CampXLoc ${Me.X}
                /varset CampYLoc ${Me.Y}
                /varset CampZLoc ${Me.FloorZ}
                /varset LookForward ${Me.Heading.DegreesCCW}
                | Turn off ChaseAssit if on
                /if (${ChaseAssist}) {
                    /varset ChaseAssist 0
                    /if (${Stick.Active}) /squelch /stick off
                    /echo >> ChaseAssist Off
                }
                /echo >> New camp set ${Me.Y}, ${Me.X}
            }
            /if (${Command.Find[Debug]}) {
                /if (${EverQuest.CurrentUI.NotEqual[Default]}) {
                    /echo You are using a Custom UI. Please switch to Default UI before Posting.
                }
            }
            /if (${Command.Equal[AutoRezAll]}) {
                /if (${OnOff.Equal[off]}) {
                    /varset CorpseRezCheck null
                    /echo No longer Rezing Everyone.
                } else {
                    /echo Now Rezing Everyone.
                }
            }
            /if (${Debug}) /echo ${Command} ${Command2} ${Command3}
            /echo >> Setting: (${Command}) to (${If[${Select[${OnOff},on,1]}>0,On,Off]})
        } else /if (${Command.Equal[conditions]}) {
            /if (${Command2.Equal[all]}) {
                /if (${Select[${Command3},1,on]}) {
                    /varset ConditionsOn 1
                    /varset GoMCOn 1
                    /varset DPSCOn 1
                    /varset HealsCOn 1
                    /varset BurnCOn 1
                    /varset BuffsCOn 1
                } else {
                    /varset ConditionsOn 0
                    /varset GoMCOn 0
                    /varset DPSCOn 0
                    /varset HealsCOn 0
                    /varset BurnCOn 0
                    /varset BuffsCOn 0
                }
                /echo >> Setting: (${Command}) ${Command2} to (${If[${Select[${Command3},on,1]}>0,On,Off]})
            } else /if (${Select[${Command2},on,off,1,0]}>0) {
                /if (${Select[${Command2},1,on]}) {
                    /varset ConditionsOn 1
                } else {
                    /varset ConditionsOn 0
                }
                /echo >> Setting: (ConditionsOn) to (${If[${ConditionsOn},On,Off]})
            } else {
                /if (${Select[${Command3},1,on]}) {
                    /varset OnOff 1
                } else {
                    /varset OnOff 0
                }
                /if (${Command2.Equal[gom]}) {
                    /varset GoMCOn ${OnOff}
                } else /if (${Command2.Equal[dps]}) {
                    /varset DPSCOn ${OnOff}
                } else /if (${Command2.Equal[heals]}) {
                    /varset HealsCOn ${OnOff}
                } else /if (${Command2.Equal[burn]}) {
                    /varset BurnCOn ${OnOff}
                } else /if (${Command2.Equal[buffs]}) {
                    /varset BuffsCOn ${OnOff}
                } 
                /echo >> Setting: (${Command}) ${Command2} to (${OnOff})
            }
        } else /if (${Command.Equal[waithere]}) {
            /varset ChaseAssist 0
            /varset ReturnToCamp 0
            /if (${Stick.Active}) /squelch /stick off
        }
    /return

- - - Updated - - -

I tested this today and confirmed, CampZone is not updated unless the macro is reloaded, so that's the problem. Still need feedback on how I can reset this variable properly in the macro.

I tried pausing, unpausing, and doing a /camphere off /camphere on ... CampZone variable never updated, which I suspected it wouldnt based on my findings last night in the macro but just wanted to confirm.

 

[kaen01]

Maskoi or ctaylor22 you got any inputs?

 

[Maskoi]

in Bind_ToggleVariable
find

| Turn on return to camp & set new y,x coord
            /if (${Command.Equal[ReturnToCamp]} && ${OnOff.Equal[on]}) {
                /varset CampXLoc ${Me.X}
                /varset CampYLoc ${Me.Y}
                /varset CampZLoc ${Me.FloorZ}
                /varset LookForward ${Me.Heading.DegreesCCW}
                | Turn off ChaseAssit if on
                /if (${ChaseAssist}) {
                    /varset ChaseAssist 0
                    /if (${Stick.Active}) /squelch /stick off
                    /echo >> ChaseAssist Off
                }
                /echo >> New camp set ${Me.Y}, ${Me.X}
            }

add this line /if (${CampZone}!=${Zone.ID}) /varset CampZone ${Zone.ID

| Turn on return to camp & set new y,x coord
            /if (${Command.Equal[ReturnToCamp]} && ${OnOff.Equal[on]}) {
                /varset CampXLoc ${Me.X}
                /varset CampYLoc ${Me.Y}
                /varset CampZLoc ${Me.FloorZ}
                /varset LookForward ${Me.Heading.DegreesCCW}
                | Turn off ChaseAssit if on
                /if (${ChaseAssist}) {
                    /varset ChaseAssist 0
                    /if (${Stick.Active}) /squelch /stick off
                    /echo >> ChaseAssist Off
                }
                /if (${CampZone}!=${Zone.ID}) /varset CampZone ${Zone.ID}
                /echo >> New camp set ${Me.Y}, ${Me.X}
            }

Now when you do a /camphere in new zone it will pick up the new zone.
Redcented for finding the bug

 

[Synk]

Perfect! Thanks Maskoi, I've added the new line, I'll confirm back here to verify it's working.