Hello Everyone! This is a simple macro to max out your Alcohol Tolerance. You will need a Fisherman's Companion to use this macro. It will summon a Brell's Fishin' Pole that will let you get drunk for free! The quest for the companion is extremely simple or even obtainable in bazaar.
Rich (BB code):
|------------------------------------------------------------|
| SummonBooze.mac
|
| Last Modified by: TheDroidUrLookingFor
|
| Originally by: WizeOne
|
|------------------------------------------------------------|
#turbo
|------------------------------------------------------------|
| Includes
|------------------------------------------------------------|
|------------------------------------------------------------|
| Defines
|------------------------------------------------------------|
#define CHATMETHOD "/echo"
|#define CHATMETHOD "/i say"
|#define CHATMETHOD "/bc"
|------------------------------------------------------------|
| Events
|------------------------------------------------------------|
#Event SkillUp "You have become better at #1# (#2#)"
#event TooDrunk "You could not possibly consume more alcohol or become more intoxicated#*#"
|------------------------------------------------------------|
| Main Rountine
|------------------------------------------------------------|
Sub Main
/declare DrunkCap int outer ${Skill[Alcohol Tolerance].SkillCap}
/declare MaxSnacks int outer 20
/declare SummonAt int outer 1
/declare SummonDelayTime int outer 3
/declare Booze string outer "Summoned: Ale"
/declare BoozeItem string outer "Brell's Fishin' Pole"
/declare PreBoozeItem string outer "Fisherman's Companion"
/if (${Me.Skill[Alcohol Tolerance]} == ${DrunkCap}) {
CHATMETHOD \ayYou are a professionsal drinker! skill maxed\x
/beep
/endm
}
/if (${FindItemCount[${BoozeItem}]} == 0 && ${FindItem[${PreBoozeItem}].Name.NotEqual["NULL"]}) /useitem ${FindItem[${PreBoozeItem}]}
CHATMETHOD \ayStarting Alcohol Tolerance Trainer \ar( \ag${Me.Skill[Alcohol Tolerance]} \ar/ \ag${DrunkCap}\ar) \x
:Main_Loop
/if (${Me.Skill[Alcohol Tolerance]} == ${DrunkCap}) {
CHATMETHOD \ayYou are a professionsal drinker! skill maxed\x
/beep
/endm
}
/if (${Cursor.ID}) /autoinventory
/if (${FindItemCount[${Booze}]} <= ${SummonAt}) /call SummonBooze
/if (${Me.Drunk} < 100 && ${FindItemCount[${Booze}]} >= 1) /useitem ${FindItem[${Booze}]}
/delay 1s
/doevents
/goto :Main_Loop
/return
|------------------------------------------------------------|
| End Main Rountine
|------------------------------------------------------------|
|------------------------------------------------------------|
| Other Rountines
|------------------------------------------------------------|
Sub SummonBooze
CHATMETHOD "Starting to summon: ${Booze}!"
:Loop
/if (!${FindItem[${BoozeItem}].TimerReady} && ${FindItemCount[${Booze}]} <= ${MaxSnacks} && ${FindItem[${BoozeItem}].Name.NotEqual["NULL"]}) {
CHATMETHOD "Summoning ${Booze}!"
/useitem ${FindItem[${BoozeItem}]}
}
/delay ${SummonDelayTime}s
/autoinventory
/delay 1
/if ((${FindItemCount[${Booze}]} >= ${MaxSnacks})) /goto :END
/goto :Loop
:END
CHATMETHOD "Summoned ${MaxSnacks} of ${Booze}!"
/return
|------------------------------------------------------------|
| End Other Rountines
|------------------------------------------------------------|
|------------------------------------------------------------|
| Events
|------------------------------------------------------------|
Sub Event_TooDrunk
/declare Stumble
/varcalc Stumble 20+${Math.Rand[10]}
CHATMETHOD Too Drunk to drink right now ( waiting ${Stumble}s )
/delay ${Stumble}s
/return
Sub Event_SkillUp(SkillUpText,SkillName,int Amount)
CHATMETHOD \ay${SkillName} \awincreased - \ag${Amount} \ar/ \ag${DrunkCap} \x
/return
|------------------------------------------------------------|
| End Events
|------------------------------------------------------------|
