Utility dump_equipment.mac - Dumps your gear w/augs to a file. Optional weblinks. 1.0

| dump_equipment.mac :: Sym 05-14-2017
| Dumps your equipped items (with augs) to dump_equipment.mac.log.
|
| set ItemLinks to 1 to have magelo links generated for each item
|

Sub Main

    /declare ItemLinks int local 1

    /declare inv int local 0
    /declare aug int local 0
    /declare tmpLine string
   
    /mqlog --------------------------------------------------
    /mqlog Equipment for ${Me.Name} ${Me.Level} ${Me.Gender} ${Me.Race} ${Me.Class}
    /mqlog --------------------------------------------------

    /for inv 0 to 22
        /varset tmpLine
        /if (${InvSlot[${inv}].Item.ID} ) {
            /varset tmpLine ${InvSlot[${inv}].Name} -- ${InvSlot[${inv}].Item.Name}
            /if (${ItemLinks}) {
                /varset tmpLine ${tmpLine} -- http://eq.magelo.com/item/${InvSlot[${inv}].Item.ID}
            }
            /for aug 1 to 5
                /if (${Me.Inventory[${inv}].Item[${aug}].ID} ) {
                    /varset tmpLine ${tmpLine} ( ${Me.Inventory[${inv}].Item[${aug}]}
                    /if (${ItemLinks}) {
                        /if (${Me.Inventory[${inv}].Item[${aug}].ID} ) /varset tmpLine ${tmpLine} -- http://eq.magelo.com/item/${Me.Inventory[${inv}].Item[${aug}].ID}
                    }
                    /varset tmpLine ${tmpLine} )
                }              
            /next aug
        } else {
            /varset tmpLine ${InvSlot[${inv}].Name} -- EMPTY
        }
        /mqlog ${tmpLine}
    /next inv
    /mqlog --------------------------------------------------
/return