Problem - auto pulling & puller engaging after pull issue

[rodd996]

when I place my ranger on puller, it will pull fine for a time. however after a while he dies while out pulling a mob. From what I can tell it gets stuck on a mob that isn't any longer in range or has gone behind a hill breaking line of sight causing the character to just sit there til it dies. Other issue is after pulls it will wait til 50 percent to 30 percent to engage even though under melee, assistat=95. This is a recurring issue which happens on any toon I set as puller

 

[ctaylor22]

On the late engagement, this has to do with when you return to camp and the tank picks up the mob before the mob gets into CampRadius. This is a know issue and can be partially fixed.

In the sub WaitForMob is where you want to look. the last /if statement can be changed to help in fixing the problem. The line you need to change is highlighted below.

            :WaitForMob
                /if (${Target.ID} && ${FaceTimer}==0) /face nolook
                /look 0               
                /doevents
                /if (${MercOn} && !${MercAssisting} && ${MyTargetID} && ${Mercenary.State.Equal[Active]} && ${Spawn[${MyTargetID}].Distance}<=${CampRadius}) /call MercsDoWhat
                /call MobRadar ${CampRadius}
                /if (${MobCount}>=2 || ${MobCount}==1 && ${AddsArray[1,1]}!=${MyTargetID}) {
                    /varset MyTargetID 0
                    /varset MyTargetName
                    /call CheckForAdds WaitForMob
                }
                |- Make sure pet is returning to camp with me if not!
                :BringBackThePet
                /if (${Select[${Role},pullerpettank]} && ${Me.Pet.ID} && ${Math.Distance[${Me.Pet.Y},${Me.Pet.X}:${CampYLoc},${CampXLoc}]}>${CampRadius} && ${Math.Distance[${Me.Pet.Y},${Me.Pet.X}:${Me.Y},${Me.X}]}>20) {
                    /pet back off
                    /delay 10 (${Math.Distance[${Me.Pet.Y},${Me.Pet.X}:${CampYLoc},${CampXLoc}]}<=${CampRadius})
                    /if (${Math.Distance[${Me.Pet.Y},${Me.Pet.X}:${CampYLoc},${CampXLoc}]}>${CampRadius} && ${Math.Distance[${Me.Pet.Y},${Me.Pet.X}:${Me.Y},${Me.X}]}>20) /goto :BringBackThePet
                } 
                | if target lost somehow add to ignore list and continue pulls
                /if (!${AggroTargetID} || ${WaitTimer}==0) {
                    /if (${DebugPull}) /echo DEBUGPULL WaitForMob /return no AggroTargetID
                    /varset PullTempIgnoreList ${Target.ID},${PullTempIgnoreList}
                    /squelch /alert add 1 id ${Target.ID}
                    /call PullReset
                    /return
                }
                /if (${Math.Distance[${Me.Pet.Y},${Me.Pet.X}:${Spawn[${MyTargetID}].Y},${Spawn[${MyTargetID}].X}]}<=${PetAttackRange}) /call CombatPet
                /varset FaceTimer 1s
                /if (${Spawn[${MyTargetID}].Distance}<=${MeleeDistance}) /call AggroCheck
            /if (${PetTanking} && ${Select[${Role},pullerpettank]} && ${Math.Distance[${CampYLoc},${CampXLoc}]}<=${CampRadius} && ${Spawn[${MyTargetID}].Distance}>=${MeleeDistance}) /goto :WaitForMob
            /if (!${PetTanking} && ${Spawn[${MyTargetID}].Distance}>=${CampRadius}) /goto :WaitForMob

        }

This is what I changed it to.

     /if (!${PetTanking} && ${Spawn[${MyTargetID}].Distance}>=${CampRadius} && !${Select[${Role},puller]}) /goto :WaitForMob
     /if (!${PetTanking} && ${Math.Distance[${Target.Y},${Target.X}:${Spawn[=${MainAssist}].Y},${Spawn[=${MainAssist}].X}]}>${CampRadius}) /goto :WaitForMob

What this does:

The first line does the same check for everyone that is NOT the Puller. So the puller will drop to the second line.
The second Line checks if the mob is in CampRadius of the TANK, so once the tank engages the mob know matter how far from camp the mob is the puller will engage.

This is not a perfect fix, but it works for me.

 

[TreeHuginDruid]

Ctaylor22 ... where have I seen these changes before ??? ( Oh wait.. nevermind... I know.. lol )
Issue being closed, resolution already incorporated into next kissassist major revision.