Question - Quick Holy Question

[eqgeek]

I wanted to make a holy for when I'm labeled the tank but I"m not sure what the correct syntax is. Can I just do:

/if (${Me.Tank} blah blah blah) /alt act 123

 

[GPS_Soldier]

I wanted to make a holy for when I'm labeled the tank but I"m not sure what the correct syntax is. Can I just do:

/if (${Me.Tank} blah blah blah) /alt act 123

eqgeek,

I believe the correct TLO member is:
${Group.MainTank}

You can look at this link to see other TLO options.

 

[PeteSampras]

/if (${Group.MainTank.ID}==${Me.ID})
or
/if (${Group.MainTank.Name.Equal[${Me.Name}]})

 

[eqgeek]

Thanks! I only wanted to fire some discs when I'm the tank and save them for real life holy moments otherwise.

 

[eqgeek]

Will this work if I set myself to pullertank, but don't mark myself as Tank in the group?

${Melee.AggroMode}

 

[ctaylor22]

Tank, PullerTank and Hunter all turn Aggro on in mq2mele using KA.

 

[eqgeek]

Thanks... so is there a reason this won't fire when my aggro is low?

/if ${Melee.AggroMode} && ${Me.CombatState.Equal[COMBAT]} && ${Me.PctAggro}<100  && ${Cast.Ready[Summer's Gale Rk. II]}) /casting "Summer's Gale Rk. II" gem11

 

[PeteSampras]

/if (${Melee.AggroMode} && ${Me.PctAggro}<100  && ${Cast.Ready[Summer's Gale Rk. II]}) /casting "Summer's Gale Rk. II" gem11

 

[eqgeek]

Thanks... When I did /echo ${Melee.AggroMode} it returned FALSE even though I'm set to pullertank... that's why it's not firing. Any idea about that?

 

[ctaylor22]

Try looking at the settings in mq2melee and see what the Aggro flag is set to. While KA is running look at the Aggro flag

I think /melee will list current settings. If the agro flag is off(0). Then my only question is, are you using a Modified KA? Is there anywhere you have added a /melee load in KA?

Then manually set the aggro flag while KA is running and see what you get when you /echo ${Melee.AggroMode}

 

[eqgeek]

Try looking at the settings in mq2melee and see what the Aggro flag is set to. While KA is running look at the Aggro flag

I think /melee will list current settings. If the agro flag is off(0). Then my only question is, are you using a Modified KA? Is there anywhere you have added a /melee load in KA?

Then manually set the aggro flag while KA is running and see what you get when you /echo ${Melee.AggroMode}

I'm not using a modified version of KA, yet if I set myself to pullertank or tank, /echo ${Melee.AggroMode} returns FALSE. The only way I get it to work is setting it manually. I don't know why it doesn't switch it for me...

 

[ctaylor22]

Here are the 2 major locations in KA that Aggro is turned on and off.


In the beginning of KA aggro is turned off.

| -------------------------------------------------------------------------------------
| Check if required plugins are loaded and settings
| -------------------------------------------------------------------------------------
    /call CheckPlugin MQ2Cast
    /call CheckPlugin MQ2Debuffs
    /call CheckPlugin MQ2Exchange
    /call CheckPlugin MQ2Melee
    /call CheckPlugin MQ2Moveutils
    /call CheckPlugin MQ2Posse
    /call CheckPlugin MQ2Rez
    /if (${IAmABard}) /call CheckPlugin MQ2Twist
    |  Turn aggro mode off and turn on melee mode in MQ2Melee
        /squelch /melee aggro=0
        /squelch /melee melee=1
        /squelch /melee stickbreak=1
        /squelch /melee petassist=0
        /squelch /melee on
        /squelch /melee stickmode=0

Then depending on your role you can see where it is being set on or off.

   Sub CheckRoles
        /if (${Debug}) /echo DEBUG CheckRoles enter

        /if (${Role.Equal[tank]}) {
            /if (${Debug}) /echo DEBUG Looks like I am Main Tank. Wish me luck.
            /if (!${Defined[MainAssist]}) /varset MainAssist ${Me}
            /squelch /melee aggro=1
            /varset AssistAt 100
            /varset StickHow front 15
        }
        /if (${Role.Equal[puller]}) {
            /if (${DebugPull}) /echo DEBUGPULL role puller
            /if (${DebugPull}) /echo DEBUGPULL Looks like I am Puller.
            /squelch /melee aggro=0
            /varset ReturnToCamp 1
            /varset ChaseAssist 0
            /varcalc CampRadiusExceed ${MaxRadius}+200
            /if (${Pet.ID} && ${Me.Pet.Distance}<=${CampRadius}) /pet guard
        }
        /if (${Role.Equal[pullertank]}) {
            /if (${DebugPull}) /echo DEBUGPULL role pullertank
            /if (${DebugPull}) /echo DEBUGPULL Looks like I am Puller and Tank.
            /varset MainAssist ${Me}
            /squelch /melee aggro=1
            /varset AssistAt 100
            /varset StickHow front 12
            /varset ReturnToCamp 1
            /varset ChaseAssist 0
            /varcalc CampRadiusExceed ${MaxRadius}+200
            /if (${Pet.ID} && ${Me.Pet.Distance}<=${CampRadius}) /pet guard
        }
        /if (${Select[${Role},hunter]}) {
            /if (${DebugPull})  /echo DEBUGPULL role hunter
            /if (${DebugPull})  /echo DEBUGPULL Looks like I am Hunting.
            /varset MainAssist ${Me}
            /squelch /melee aggro=1
            /varset AssistAt 100
            /varset StickHow front 12
            /varcalc CampRadiusExceed ${MaxRadius}+200
            /varset ReturnToCamp 0
            /varset MobsTooClose 15
            /if (${Pet.ID}) /pet follow
        }
        /if (${Select[${Role},petassist]}) {
            /if (${DebugPull}) /echo DEBUGPULL role petassist
            /if (${DebugPull}) /echo DEBUGPULL Looks like I am assisting a pet.
            /squelch /melee aggro=0
            /varset MeleeOn 0
        }
        /if (${Select[${Role},pettank]}) {
            /if (${DebugPull}) /echo DEBUGPULL role petassist
            /if (${DebugPull}) /echo DEBUGPULL Looks like I am assisting a pet.
            /squelch /melee aggro=0
            /varset MeleeOn 0
        }
        /if (${Select[${Role},pullerpettank]}) {
            /if (${DebugPull}) /echo DEBUGPULL role pullerpettank
            /if (${DebugPull}) /echo DEBUGPULL Looks like I am pulling and my pet is tanking.
            /squelch /melee aggro=0
			/varset AssistAt 100
            /varset MeleeOn 0
			/varset PetTanking 1
			/varset PetAttackRange 125
            /varset ReturnToCamp 1
            /varset ChaseAssist 0
            /varcalc CampRadiusExceed ${MaxRadius}+200
            :PTauntOn
            /if (${Me.Pet.ID} && !${PetTauntOn}) {
                /pet taunt
                /doevents
                /if (!${PetTauntOn}) /goto :PTauntOn
            }
            /if (${Math.Distance[${Me.Pet.Y},${Me.Pet.X}:${CampYLoc},${CampXLoc}]}<=${CampRadius}) /pet guard
            /if (${Math.Distance[${Me.Pet.Y},${Me.Pet.X}:${CampYLoc},${CampXLoc}]}>=${CampRadius}) /pet follow
        }
		/if (${Role.Equal[manual]}) {
				/squelch /melee aggro=0
				/varset MeleeOn 0
				/varset ReturnToCamp 0
				/varset ChaseAssist 0
				/varset DpsOn 0
				/varset BuffsOn 0
				/if (${Defined[HealsOn]}) /varset HealsOn 0
				/if (${Defined[MezOn]}) /varset MezOn 0
		}	
        /if (${Debug}) /echo DEBUG CheckRoles leave
    /return

Checkroles is called before the main loop in KA, so not sure how what would be the problem. I would put an /echo ${Melee.AggroMode} right after the /call checkroles just to see if it is set after returning from the routine. you may want to do an /echo ${Melee.AggroMode} ${Role}.