Tradeskill macro (combines only)

#event OutOfStuff "Sorry, but you don't have everything you need for this recipe in your general inventory." 
 
Sub Main 
:Loop 
 
:ClearCursor 
/if (${Cursor.ID}) { 
/autoinventory 
/goto :ClearCursor 
} 
 
/nomodkey /notify TradeSkillWnd CombineButton leftmouseup
/doevents 
/goto :Loop 
/return 
 
Sub Event_OutOfStuff 
/nomodkey /notify TradeSkillWnd CloseButton leftmouseup
/endmacro 
/return

EXAMPLE:

this is where mine is


E:\My Documents\EQ\macroquest\ReleaseST

Macros go in 

E:\My Documents\EQ\macroquest\ReleaseST\macros

| combine.mac : A Simple Combine macro 
| Author      : Chill 
| Version     : v1.1 25-May-2004 4:00PM EST 
| Useage      : /macro combine [combines] -- have tradeskill window open with recipie highlighted. 
|               /target yourself to pause the macro, target anything else (or nothing) to resume. 
| Description : This macro will do the selected recipie until you run out of components or reach 
                [combines], pausing whenever you are targeted, and report success/fail rates when done. 

#event done "Sorry, but you don't have everything you need for this recipe in your general inventory." 
#event success "You have fashioned the items together to create something new!" 
#event failure "You lacked the skills to fashion the items together." 

Sub Main(int max) 

/declare wins int outer 0 
/declare fails int outer 0 
/declare total int outer 0 
/declare rate float outer 0 

   :Loop 
   /if (${Target.ID}==${Me.ID}) { 
     /delay 60m ${Target.ID}!=${Me.ID} 
   } 
   /if (${Cursor.ID}) { 
      /autoinventory 
      /goto :Loop 
   } 
   /if (${Defined[max]} && ${total} >= ${max}) /call Event_done 
   /notify TradeSkillWnd CombineButton leftmouseup
   /delay 2s ${Cursor.ID} 
   /doevents 
   /goto :Loop 
/return 

Sub Event_done 
   /varcalc rate 100*${wins}/${total} 
   /echo (${wins}) of (${total}) combines succeeded (${rate}%). 
   /if (${fails}) { 
      /varcalc rate 100*${fails}/${total} 
      /echo (${fails}) of (${total}) combines failed (${rate}%). 
   } 
   /endmacro 
/return 

Sub Event_success 
   /varcalc wins ${wins}+1 
   /varcalc total ${total}+1 
/return 

Sub Event_failure 
   /varcalc fails ${fails}+1 
   /varcalc total ${total}+1 
/return